From f9441c4d4d0254c0a84b1a462f245409f1b2a329 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Sat, 2 Jul 2016 19:06:11 +0200
Subject: net-libs/gnome-online-accounts: Version bump

Package-Manager: portage-2.3.0_rc1
---
 net-libs/gnome-online-accounts/Manifest            |  1 +
 .../gnome-online-accounts-3.20.1.ebuild            | 90 ++++++++++++++++++++++
 2 files changed, 91 insertions(+)
 create mode 100644 net-libs/gnome-online-accounts/gnome-online-accounts-3.20.1.ebuild

(limited to 'net-libs')

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index 0ef0a0db34f9..d6e13de5d429 100644
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1 +1,2 @@
 DIST gnome-online-accounts-3.18.4.tar.xz 1384756 SHA256 9f23460aa6b1d8a63a8f3e979cba791cc88b5e07116f07da59fdcea09d79c74d SHA512 1d78d8720d3547e782a9c9b1fee5ec794c8a0ec56d94f690adc1cce9d4f20da07b85a7c6e657b591153db667b3580d8900217e789144ac2e40eb963a7ac8d1a8 WHIRLPOOL 5459b9670c555a331c1c89583abd81836b8da2369355a97784fa370473341c49d5543d88870c49a8f47afd72a11feb27e3bfdb081b10fce8eb1a057eab279d02
+DIST gnome-online-accounts-3.20.1.tar.xz 1482736 SHA256 c37aebc1e12f31f5516d33a354181e4d202a07da4f7d3a95b0da8cf0028c0c93 SHA512 e6c34553c3a2c6a930c96227dab832b11350d0a4f76ac1b96d418694c0593b83fefa9579ae131489a7dae34d9b59d602e9447e9eea3b6e3f9b02660e9e783b15 WHIRLPOOL 1c609480790e47fbdf8917a8eaa37e4a9fb89cb99dd96622f3a4ea2baa49731a5856e8dced4e2a4d4476880ad794945f48be4976acbe8ffc9bb067db1ff8b2a6
diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.20.1.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.20.1.ebuild
new file mode 100644
index 000000000000..f47859a5c676
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.20.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+IUSE="debug gnome +introspection kerberos" # telepathy"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# pango used in goaeditablelabel
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+	>=dev-libs/glib-2.35:2
+	>=app-crypt/libsecret-0.5
+	>=dev-libs/json-glib-0.16
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	net-libs/rest:0.7
+	net-libs/telepathy-glib
+	>=net-libs/webkit-gtk-2.7.2:4
+	>=x11-libs/gtk+-3.19.12:3
+	x11-libs/pango
+
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+	kerberos? (
+		app-crypt/gcr:0=
+		app-crypt/mit-krb5 )
+"
+#	telepathy? ( net-libs/telepathy-glib )
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	dev-libs/libxslt
+	>=dev-util/gtk-doc-am-1.3
+	>=dev-util/gdbus-codegen-2.30.0
+	>=dev-util/intltool-0.50.1
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+# eautoreconf needs gobject-introspection-common, gnome-common
+
+# Due to sub-configure
+QA_CONFIGURE_OPTIONS=".*"
+
+src_prepare() {
+	gnome2_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/FB/Windows Live secrets
+	# telepathy optional support is really a badly one, bug #494456
+	gnome2_src_configure \
+		--disable-static \
+		--enable-backend \
+		--enable-documentation \
+		--enable-exchange \
+		--enable-facebook \
+		--enable-flickr \
+		--enable-foursquare \
+		--enable-imap-smtp \
+		--enable-lastfm \
+		--enable-media-server \
+		--enable-owncloud \
+		--enable-pocket \
+		--enable-telepathy \
+		--enable-windows-live \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable kerberos)
+		#$(use_enable telepathy)
+	# gudev & cheese from sub-configure is overriden
+	# by top level configure, and disabled so leave it like that
+}
-- 
cgit v1.2.3-18-g5258