From ceb8405e2422b24627a1badfdad48bcb1ec4cd39 Mon Sep 17 00:00:00 2001
From: Eray Aslan <eras@gentoo.org>
Date: Tue, 25 Sep 2018 08:28:46 +0300
Subject: net-mail/mailbase: EAPI7: ROOT does not end in /

Closes: https://bugs.gentoo.org/666942
Package-Manager: Portage-2.3.50, Repoman-2.3.11
---
 net-mail/mailbase/mailbase-1.5.ebuild | 67 +++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 net-mail/mailbase/mailbase-1.5.ebuild

(limited to 'net-mail/mailbase')

diff --git a/net-mail/mailbase/mailbase-1.5.ebuild b/net-mail/mailbase/mailbase-1.5.ebuild
new file mode 100644
index 000000000000..898d804dc88a
--- /dev/null
+++ b/net-mail/mailbase/mailbase-1.5.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit pam user
+
+DESCRIPTION="MTA layout package"
+SRC_URI=""
+HOMEPAGE="https://www.gentoo.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="pam"
+
+RDEPEND="pam? ( virtual/pam )"
+
+S=${WORKDIR}
+
+pkg_setup() {
+	enewgroup mail 12
+	enewuser mail 8 -1 /var/spool/mail mail
+	enewuser postmaster 14 -1 /var/spool/mail
+}
+
+src_install() {
+	dodir /etc/mail
+	insinto /etc/mail
+	doins "${FILESDIR}"/aliases
+	insinto /etc
+	doins "${FILESDIR}"/mailcap
+	doman "${FILESDIR}"/mailcap.5
+
+	keepdir /var/spool/mail
+	fowners root:mail /var/spool/mail
+	fperms 03775 /var/spool/mail
+	dosym spool/mail /var/mail
+
+	newpamd "${FILESDIR}"/common-pamd-include pop
+	newpamd "${FILESDIR}"/common-pamd-include imap
+	if use pam ; then
+		local p
+		for p in pop3 pop3s pops ; do
+			dosym pop /etc/pam.d/${p}
+		done
+		for p in imap4 imap4s imaps ; do
+			dosym imap /etc/pam.d/${p}
+		done
+	fi
+}
+
+get_permissions_oct() {
+	if [[ ${USERLAND} = GNU ]] ; then
+		stat -c%a "${ROOT}$1"
+	elif [[ ${USERLAND} = BSD ]] ; then
+		stat -f%p "${ROOT}$1" | cut -c 3-
+	fi
+}
+
+pkg_postinst() {
+	# bug 614396
+	if [[ "$(get_permissions_oct /var/spool/mail)" != "3775" ]] ; then
+		einfo  "Fixing ${ROOT}/var/spool/mail/ permissions"
+		chown root:mail "${ROOT}/var/spool/mail/"
+		chmod 03775 "${ROOT}/var/spool/mail/"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad