From 73281ba3a184dc071d6e52ec032ba0dd9960b44e Mon Sep 17 00:00:00 2001
From: Mike Gilbert <floppym@gentoo.org>
Date: Tue, 31 Dec 2019 12:25:11 -0500
Subject: net-misc/freerdp: new snapshot

Closes: https://bugs.gentoo.org/677802
Closes: https://bugs.gentoo.org/703612
Package-Manager: Portage-2.3.84_p2, Repoman-2.3.20_p24
Signed-off-by: Mike Gilbert <floppym@gentoo.org>
---
 net-misc/freerdp/Manifest                       |   1 +
 net-misc/freerdp/freerdp-2.0.0_rc4_p1129.ebuild | 122 ++++++++++++++++++++++++
 net-misc/freerdp/freerdp-9999.ebuild            |   2 +-
 3 files changed, 124 insertions(+), 1 deletion(-)
 create mode 100644 net-misc/freerdp/freerdp-2.0.0_rc4_p1129.ebuild

(limited to 'net-misc/freerdp')

diff --git a/net-misc/freerdp/Manifest b/net-misc/freerdp/Manifest
index fd0ee55a1337..b40e22cbbdbc 100644
--- a/net-misc/freerdp/Manifest
+++ b/net-misc/freerdp/Manifest
@@ -1,2 +1,3 @@
 DIST freerdp-2.0.0-rc4-fix-NTLM-AvPair-lists.patch 20553 BLAKE2B 17ba83ba2dc05f2179df3aa8805877e15b353d4c6bbe88fa0553f7412baf85849a834032143ebd22ff3d27dd12ffdfddfc802868e10ca2718145a58378940ec4 SHA512 b3b548e98422362f63aedfefca399e4008a4b571e6cd786603418c5a3d1c4d832d5148ddee2f62d6bc1259c66020ee01ced6357d72333f49fc34a1059f4f804e
 DIST freerdp-2.0.0-rc4.tar.gz 6662044 BLAKE2B 50bc72336841e421b8fd89ce4f2be6a0b1a9f052933c4cd5bad33261689e6a6b54bc5563fb1ace8cc7a2271990c0ff4c7fe239243f5d75140af497ee6ff9bcd6 SHA512 63cf89aecc6d7ac55db8c7aca60f4ba29cfa54ad70d0fa87fdab011cd16500a3d184659119cd08b7596b7236346db3b61b46282c5325d7f0ca6da09b42d0df20
+DIST freerdp-2.0.0_rc4_p1129.tar.gz 6774330 BLAKE2B 728a4d0f0d7ee4a6cf8a7d0d4ed6f2e0f13a76ceb1c16e7cb48ad0f3d6b6f36194839129bd57e73e02d2a6ae89a83d9d571f515ab2f46cb26f611424dd5b23b5 SHA512 407b06ca7607e01d52b7b89337dbcd5dc15633de197ea91443825672963cbb6d966a187dee022afb5f9979e8d08577ee62b681f37419e5b986f9c2f5e8a3e285
diff --git a/net-misc/freerdp/freerdp-2.0.0_rc4_p1129.ebuild b/net-misc/freerdp/freerdp-2.0.0_rc4_p1129.ebuild
new file mode 100644
index 000000000000..4ef50289d0b5
--- /dev/null
+++ b/net-misc/freerdp/freerdp-2.0.0_rc4_p1129.ebuild
@@ -0,0 +1,122 @@
+# Copyright 2011-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [[ ${PV} != 9999 ]]; then
+	COMMIT="483d09b760bea529972afad9b6f6c7a89dcffd40"
+	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/FreeRDP-${COMMIT}"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0/2"
+IUSE="alsa +client cpu_flags_arm_neon cups debug doc +ffmpeg gstreamer jpeg libav libressl openh264 pulseaudio server smartcard systemd test usb wayland X xinerama xv"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	sys-libs/zlib:0
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	client? (
+		usb? (
+			virtual/libudev:0=
+			sys-apps/util-linux:0=
+			dev-libs/dbus-glib:0=
+			virtual/libusb:1=
+		)
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			xinerama? ( x11-libs/libXinerama )
+			xv? ( x11-libs/libXv )
+		)
+	)
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	!ffmpeg? (
+		x11-libs/cairo:0=
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg:0 )
+	openh264? ( media-libs/openh264 )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	client? ( X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) ) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DCHANNEL_URBDRC=$(usex usb ON OFF)
+		-DWITH_ALSA=$(usex alsa ON OFF)
+		-DWITH_CCACHE=OFF
+		-DWITH_CLIENT=$(usex client ON OFF)
+		-DWITH_CUPS=$(usex cups ON OFF)
+		-DWITH_DEBUG_ALL=$(usex debug ON OFF)
+		-DWITH_MANPAGES=$(usex doc ON OFF)
+		-DWITH_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_SWSCALE=$(usex ffmpeg ON OFF)
+		-DWITH_CAIRO=$(usex ffmpeg OFF ON)
+		-DWITH_DSP_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_GSTREAMER_1_0=$(usex gstreamer ON OFF)
+		-DWITH_JPEG=$(usex jpeg ON OFF)
+		-DWITH_NEON=$(usex cpu_flags_arm_neon ON OFF)
+		-DWITH_OPENH264=$(usex openh264 ON OFF)
+		-DWITH_PULSE=$(usex pulseaudio ON OFF)
+		-DWITH_SERVER=$(usex server ON OFF)
+		-DWITH_PCSC=$(usex smartcard ON OFF)
+		-DWITH_LIBSYSTEMD=$(usex systemd ON OFF)
+		-DWITH_X11=$(usex X ON OFF)
+		-DWITH_XINERAMA=$(usex xinerama ON OFF)
+		-DWITH_XV=$(usex xv ON OFF)
+		-DWITH_WAYLAND=$(usex wayland ON OFF)
+	)
+	cmake_src_configure
+}
diff --git a/net-misc/freerdp/freerdp-9999.ebuild b/net-misc/freerdp/freerdp-9999.ebuild
index 9eb56f0748d4..1ca075a5d92c 100644
--- a/net-misc/freerdp/freerdp-9999.ebuild
+++ b/net-misc/freerdp/freerdp-9999.ebuild
@@ -9,7 +9,7 @@ if [[ ${PV} != 9999 ]]; then
 	MY_P=${P/_/-}
 	S="${WORKDIR}/${MY_P}"
 	SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz"
-	KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
 else
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
-- 
cgit v1.2.3-65-gdbad