From 90e432ac16ad7a9556b884d3c95724ff89ce3642 Mon Sep 17 00:00:00 2001
From: Ionen Wolkens <ionen@gentoo.org>
Date: Tue, 9 Nov 2021 06:50:51 -0500
Subject: net-misc/yt-dlp: remove some non-essential deps / use optfeature

Closes: https://bugs.gentoo.org/822156
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 net-misc/yt-dlp/yt-dlp-2021.10.22-r2.ebuild | 58 -----------------------------
 net-misc/yt-dlp/yt-dlp-2021.10.22-r3.ebuild | 58 +++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+), 58 deletions(-)
 delete mode 100644 net-misc/yt-dlp/yt-dlp-2021.10.22-r2.ebuild
 create mode 100644 net-misc/yt-dlp/yt-dlp-2021.10.22-r3.ebuild

(limited to 'net-misc/yt-dlp')

diff --git a/net-misc/yt-dlp/yt-dlp-2021.10.22-r2.ebuild b/net-misc/yt-dlp/yt-dlp-2021.10.22-r2.ebuild
deleted file mode 100644
index 794ec7cccd59..000000000000
--- a/net-misc/yt-dlp/yt-dlp-2021.10.22-r2.ebuild
+++ /dev/null
@@ -1,58 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-inherit bash-completion-r1 distutils-r1
-
-DESCRIPTION="youtube-dl fork with additional features and fixes"
-HOMEPAGE="https://github.com/yt-dlp/yt-dlp"
-SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"
-
-LICENSE="Unlicense"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~riscv ~x86"
-
-RDEPEND="
-	dev-python/keyring[${PYTHON_USEDEP}]
-	dev-python/pycryptodome[${PYTHON_USEDEP}]
-	dev-python/websockets[${PYTHON_USEDEP}]
-	media-libs/mutagen[${PYTHON_USEDEP}]
-	media-video/ffmpeg
-	!net-misc/youtube-dl"
-
-distutils_enable_tests pytest
-
-python_test() {
-	epytest -m 'not download'
-}
-
-python_install_all() {
-	dodoc README.md Changelog.md supportedsites.md
-	doman yt-dlp.1
-
-	dobashcomp completions/bash/yt-dlp
-
-	insinto /usr/share/fish/vendor_completions.d
-	doins completions/fish/yt-dlp.fish
-
-	insinto /usr/share/zsh/site-functions
-	doins completions/zsh/_yt-dlp
-
-	rm -r "${ED}"/usr/share/doc/yt_dlp || die
-
-	newbin - youtube-dl <<-EOF
-		#!/usr/bin/env sh
-		exec yt-dlp --compat-options youtube-dl "\${@}"
-	EOF
-}
-
-pkg_postinst() {
-	if [[ ! ${REPLACING_VERSIONS} ]] ||
-		ver_test ${REPLACING_VERSIONS} -lt 2021.10.22-r2; then
-		elog 'A wrapper using "yt-dlp --compat-options youtube-dl" was installed'
-		elog 'as "youtube-dl". This is strictly for compatibility and it is'
-		elog 'recommended to use "yt-dlp" directly, it may be removed in the future.'
-	fi
-}
diff --git a/net-misc/yt-dlp/yt-dlp-2021.10.22-r3.ebuild b/net-misc/yt-dlp/yt-dlp-2021.10.22-r3.ebuild
new file mode 100644
index 000000000000..1aa701367fef
--- /dev/null
+++ b/net-misc/yt-dlp/yt-dlp-2021.10.22-r3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit bash-completion-r1 distutils-r1 optfeature
+
+DESCRIPTION="youtube-dl fork with additional features and fixes"
+HOMEPAGE="https://github.com/yt-dlp/yt-dlp"
+SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~riscv ~x86"
+
+RDEPEND="
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	!net-misc/youtube-dl"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -m 'not download'
+}
+
+python_install_all() {
+	dodoc README.md Changelog.md supportedsites.md
+	doman yt-dlp.1
+
+	dobashcomp completions/bash/yt-dlp
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins completions/fish/yt-dlp.fish
+
+	insinto /usr/share/zsh/site-functions
+	doins completions/zsh/_yt-dlp
+
+	rm -r "${ED}"/usr/share/doc/yt_dlp || die
+
+	newbin - youtube-dl <<-EOF
+		#!/usr/bin/env sh
+		exec yt-dlp --compat-options youtube-dl "\${@}"
+	EOF
+}
+
+pkg_postinst() {
+	optfeature "various features (merging tracks, streamed content)" media-video/ffmpeg
+	has_version media-video/atomicparsley || # allow fallback but don't advertise
+		optfeature "embedding metadata thumbnails in MP4/M4A files" media-libs/mutagen
+
+	if [[ ! ${REPLACING_VERSIONS} ]] ||
+		ver_test ${REPLACING_VERSIONS} -lt 2021.10.22-r2; then
+		elog 'A wrapper using "yt-dlp --compat-options youtube-dl" was installed'
+		elog 'as "youtube-dl". This is strictly for compatibility and it is'
+		elog 'recommended to use "yt-dlp" directly, it may be removed in the future.'
+	fi
+}
-- 
cgit v1.2.3-65-gdbad