From 24ae329698064ce20a201244cd64435ed66da72b Mon Sep 17 00:00:00 2001
From: Ben Kohler <bkohler@gentoo.org>
Date: Fri, 9 Jul 2021 08:01:05 -0500
Subject: net-misc/remmina: bump to 1.4.20

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler@gentoo.org>
---
 net-misc/remmina/Manifest              |  1 +
 net-misc/remmina/remmina-1.4.20.ebuild | 99 ++++++++++++++++++++++++++++++++++
 2 files changed, 100 insertions(+)
 create mode 100644 net-misc/remmina/remmina-1.4.20.ebuild

(limited to 'net-misc')

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index 4819d3b60702..9d8c0e72aa50 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -3,3 +3,4 @@ DIST Remmina-v1.4.16.tar.gz 2615347 BLAKE2B 5cff71d94bf66dd0116be739646c33a601a8
 DIST Remmina-v1.4.17.tar.gz 2618015 BLAKE2B 2b4fbc6cd80dba7d73d8ce7cb5627b6fb67c0cc0c76f124da629f2ebee2c5d0542c3e6b626cdc19630f49f1227fada7e5344ff2f49eeabbc8709c50f5d1f58eb SHA512 e833a4c602ce68354b6d65ea0d7e32c19a242bb72d5fcfd558106b6f53d9397b278472070bc53579185ebbc8fb2ea88718e05f05fdb743df5b46051eb3423d78
 DIST Remmina-v1.4.18.tar.gz 2578470 BLAKE2B 341352b6661a640cf99c5ca6a79f3f1a77cbd0a6027e4bd4a6360f2ed17e1a5abb58ca8a8638988842efb7218072e5cb4a3e56e0f35b7c06f9094c0e00d72689 SHA512 98f14caf39afd8531ce1af2e5f9addc1c68fa12eb66845f0436eec623e8bdbdd75ec14c59544e6e6414b2e4c522ac2b8213fd30561a902768d805ceb1d768f69
 DIST Remmina-v1.4.19.tar.gz 2452278 BLAKE2B 7f5ef0f0a13a73eb4893c4a49f6f97eb0141e3c385306503e63f81efdb5d85453ba9d5f030e6e73502c8ad314d701422e4e03d2ce9e69c5fb8003f01a08a5a42 SHA512 c07cee297aee28e772e39bc600144f946f6f315b6e48077c2f756125e51b1e82bc0cee39b9e81ba4568608b14bfd9c7dfc633240eb64245bdeeb537bc812dc6a
+DIST Remmina-v1.4.20.tar.gz 2489535 BLAKE2B 8d557dfc8629572d3fc930aea85e62fdc6294521c4997e1d211b8aac385f1bab3a13f082cff7f40e3add839d3922b4884736a9a50eb3e043df4c6314d3e456c5 SHA512 27a4bfbcb77f1cebe527bdcdd78f1dedb703c888c9452bdac7162e18e7eee0bf2e49143f3a3f98d451d4c1cf7cd6b9f89ae9fb67755930501e4f08e08d311892
diff --git a/net-misc/remmina/remmina-1.4.20.ebuild b/net-misc/remmina/remmina-1.4.20.ebuild
new file mode 100644
index 000000000000..33fd67a9140e
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.20.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake optfeature xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="crypt cups examples gnome-keyring gvnc kwallet nls spice ssh rdp telemetry telepathy vnc webkit zeroconf"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libappindicator:3
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	dev-libs/wayland
+	net-libs/libsoup
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	crypt? ( dev-libs/libgcrypt:0= )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	gnome-keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=OFF
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_NEWS=$(usex telemetry)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
-- 
cgit v1.2.3-65-gdbad