From 5e7f278645b382c3791c703f29cad85a9916be1e Mon Sep 17 00:00:00 2001
From: Conrad Kostecki <conrad@kostecki.com>
Date: Wed, 18 Sep 2019 20:11:25 +0200
Subject: net-misc/networkmanager-wireguard: add a snapshot version

Since currently only 9999 exists, and last update is from 2018, it makes
sense to add a snapshot version, which can get keywords.

Also bumped to EAPI=7 and taking ownership by myself.

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Conrad Kostecki <conrad@kostecki.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 net-misc/networkmanager-wireguard/Manifest         |  1 +
 net-misc/networkmanager-wireguard/metadata.xml     | 16 +++++-
 .../networkmanager-wireguard-0_pre20181128.ebuild  | 61 ++++++++++++++++++++++
 3 files changed, 77 insertions(+), 1 deletion(-)
 create mode 100644 net-misc/networkmanager-wireguard/Manifest
 create mode 100644 net-misc/networkmanager-wireguard/networkmanager-wireguard-0_pre20181128.ebuild

(limited to 'net-misc')

diff --git a/net-misc/networkmanager-wireguard/Manifest b/net-misc/networkmanager-wireguard/Manifest
new file mode 100644
index 000000000000..2f57e78aba4c
--- /dev/null
+++ b/net-misc/networkmanager-wireguard/Manifest
@@ -0,0 +1 @@
+DIST networkmanager-wireguard-0_pre20181128.tar.gz 233338 BLAKE2B 46695c640cb6599efef2e90bacf1ec924303689bdc45cf5cbf5c1bc807ea7ee708015592881b23e38dcf51a5c32b04aefd994aec09010ab9790522b8aee4f371 SHA512 4a2b97c88f20c8eb6bfe495204eb0d751a85120a3043b90f3475913ec1242905c49cba7c179974cf360137ee3828a0d1794b09998fe5e90bdf47b718b059f8d1
diff --git a/net-misc/networkmanager-wireguard/metadata.xml b/net-misc/networkmanager-wireguard/metadata.xml
index 6f49eba8f496..b75e9c8ab9fe 100644
--- a/net-misc/networkmanager-wireguard/metadata.xml
+++ b/net-misc/networkmanager-wireguard/metadata.xml
@@ -1,5 +1,19 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<!-- maintainer-needed -->
+	<maintainer type="person">
+		<email>ck+gentoo@bl4ckb0x.de</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription>
+		This project is a VPN Plugin for NetworkManager that handles client-side WireGuard connections.
+		It is based on the OpenVPN Plugin and was started as a Bachelor's Thesis at SBA Research.
+	</longdescription>
+	<use>
+		<flag name="glib">Enable libnm-glib compatibility.</flag>
+	</use>
 </pkgmetadata>
diff --git a/net-misc/networkmanager-wireguard/networkmanager-wireguard-0_pre20181128.ebuild b/net-misc/networkmanager-wireguard/networkmanager-wireguard-0_pre20181128.ebuild
new file mode 100644
index 000000000000..0769e9ac9da7
--- /dev/null
+++ b/net-misc/networkmanager-wireguard/networkmanager-wireguard-0_pre20181128.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+EGIT_COMMIT="61646ade26750c52626a44b025cb1b165681c662"
+MY_PN="${PN/network/network-}"
+
+DESCRIPTION="NetworkManager WireGuard plugin"
+HOMEPAGE="https://github.com/max-moser/network-manager-wireguard"
+SRC_URI="https://github.com/max-moser/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+glib +gtk +nls"
+
+RDEPEND="
+	net-misc/networkmanager
+	net-vpn/wireguard
+	glib? ( dev-libs/glib )
+	gtk? (
+		app-crypt/libsecret
+		gnome-extra/nm-applet
+		x11-libs/gtk+:3
+	)
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${EGIT_COMMIT}"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-lto
+		--disable-more-warnings
+		--disable-static
+		$(use_with glib	libnm-glib)
+		$(use_with gtk gnome)
+		$(use_enable nls)
+		--with-dist-version="Gentoo"
+	)
+
+	econf "${myeconfargs[@]}"
+}
-- 
cgit v1.2.3-65-gdbad