From fc22f0517496ce9634ccf67e8ea0ab62095f113c Mon Sep 17 00:00:00 2001
From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Tue, 3 Nov 2020 14:28:30 +0100
Subject: net-misc/nextcloud-client: 3.0.3 bump

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
---
 net-misc/nextcloud-client/Manifest                 |  1 +
 .../nextcloud-client/nextcloud-client-3.0.3.ebuild | 90 ++++++++++++++++++++++
 2 files changed, 91 insertions(+)
 create mode 100644 net-misc/nextcloud-client/nextcloud-client-3.0.3.ebuild

(limited to 'net-misc')

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index ebfb24e7cd31..f6731340c4b6 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,2 +1,3 @@
 DIST nextcloud-client-2.6.5.tar.gz 19134736 BLAKE2B 12defed7dc9a23622d49228c2e78586533f51d1cfd6209e263a0a8b94d307028b1afa76004768432a2bee68140602da003ef10133cd166fd3443a0a45ccccabc SHA512 fcb8ac368e064f9e9ffdc014faabb4f308045d2b047e1011e17bf2e54fa61f462f529eb48e5ec2aa638df8d9720bd7b88acef9b26aa3ba2b90e8977b3be45462
 DIST nextcloud-client-3.0.2.tar.gz 19114545 BLAKE2B a6aa041708d110fbdca082476e65ccc8fec189948aa64020a27beabe2d7b3df474ae3313b5aef0e15f3498cf974cf414eb4934417cea206b021e4e212351a088 SHA512 188f878457baba14f01ca6c0f83100bcc64feaf5e3da86903d59d8b7c553c89f88252c1410cd153952950f91429af680b1901f3f9de951bfd06a06c176d44e7d
+DIST nextcloud-client-3.0.3.tar.gz 19202718 BLAKE2B b5e09be514ede6e323e9624df38aad10969c0fdae7bc7baaeb9da4628dfa1c44a4fb6b5f6b4b83ff92b0eedbbe1ffbcf54da43d5e71923979b8649db54b05d7c SHA512 aa9e9897dae74919f11817f8aad139378a2a26df6663f3c9ee9c9e1d229b537daa9e9ed9f3ba292f8e299017f7ef5d863257a26858af159e7e76c7247d7c244d
diff --git a/net-misc/nextcloud-client/nextcloud-client-3.0.3.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.0.3.ebuild
new file mode 100644
index 000000000000..a3dd780f6e5f
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-3.0.3.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin libressl nautilus test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	!libressl? ( >=dev-libs/openssl-1.1.0:0= )
+	libressl? ( >=dev-libs/libressl-3.1:0= )
+	nautilus? ( dev-python/nautilus-python )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/desktop-${PV/_/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=yes
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad