From c0a145c569b658ac97b0addecdee386768d4bb16 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Sun, 9 Oct 2016 14:44:16 +0200
Subject: sci-biology/hmmer: Version bump to 3.1_beta2

* EAPI=6
* Make perl shebangs portable
* Install headers into 'hmmer3' subdir

Package-Manager: portage-2.3.1
---
 sci-biology/hmmer/hmmer-3.1_beta2.ebuild | 49 ++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 sci-biology/hmmer/hmmer-3.1_beta2.ebuild

(limited to 'sci-biology/hmmer/hmmer-3.1_beta2.ebuild')

diff --git a/sci-biology/hmmer/hmmer-3.1_beta2.ebuild b/sci-biology/hmmer/hmmer-3.1_beta2.ebuild
new file mode 100644
index 000000000000..d893cb3a3b84
--- /dev/null
+++ b/sci-biology/hmmer/hmmer-3.1_beta2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MY_PV="${PV/_beta/b}"
+
+DESCRIPTION="Sequence analysis using profile hidden Markov models"
+HOMEPAGE="http://hmmer.org/"
+SRC_URI="http://eddylab.org/software/${PN}3/${MY_PV}/hmmer-${MY_PV}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="altivec cpu_flags_x86_sse gsl mpi test +threads"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+
+RDEPEND="
+	mpi? ( virtual/mpi )
+	gsl? ( sci-libs/gsl:= )"
+DEPEND="${RDEPEND}
+	test? ( dev-lang/perl )"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+PATCHES=(
+	"${FILESDIR}/${PN}-3.1_beta2-fix-perl-shebangs.patch"
+	"${FILESDIR}/${PN}-3.1_beta2-fix-header-install-path.patch"
+)
+
+src_configure() {
+	# make build verbose, bug 429308
+	export V=1
+
+	econf \
+		--disable-pic \
+		$(use_enable altivec vmx) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable mpi) \
+		$(use_enable threads) \
+		$(use_with gsl)
+}
+
+src_install() {
+	default
+	dodoc Userguide.pdf
+
+	insinto /usr/share/${PN}
+	doins -r tutorial
+}
-- 
cgit v1.2.3-65-gdbad