From 2a585c1f85093f5a6f79a26bcb91b33c0e64eb81 Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Tue, 6 Jun 2017 22:53:00 +1000
Subject: sys-auth/elogind: version bump 229.4

Gentoo-bug: 620976
Package-Manager: Portage-2.3.5, Repoman-2.3.2
---
 sys-auth/elogind/Manifest             |  1 +
 sys-auth/elogind/elogind-229.4.ebuild | 84 +++++++++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)
 create mode 100644 sys-auth/elogind/elogind-229.4.ebuild

(limited to 'sys-auth/elogind')

diff --git a/sys-auth/elogind/Manifest b/sys-auth/elogind/Manifest
index f6f3c9a16407..8480503c7bdf 100644
--- a/sys-auth/elogind/Manifest
+++ b/sys-auth/elogind/Manifest
@@ -1 +1,2 @@
 DIST elogind-229.3.tar.gz 757313 SHA256 8506145e6071a637aec91276e19cd932b3d9cd297c8e833f7b08b8d53fd7a1d7 SHA512 5449f6b8ca1cb14d91681de1273819e193c88f6ec22b790cfe2c9d9d6e0d37bfc3b707a650d14471e0cb3a577289f725e1a47d22a14db2154a2c0552ecde32ca WHIRLPOOL e71fc14453017a570c3c2766b42fb444e41b2a703689e745ea3a01bd915fdab896b4bd3f229f74d438d48b8383a0b590c456b9269a739e9bf7b8d60441fbb33c
+DIST elogind-229.4.tar.gz 757388 SHA256 a34012b087d1da4a5c23ab66a3debe34a4dc01cf61fd4ba91a28a9579aafa2ed SHA512 d26a1297755ca262b9ac5b85d8c4e8f706d5eccdc69d9de312297812bafc20eeb5180824fb85d6f6c9cdfe4966ca1acc4ce62902c6b8816e4e8fb244aa4b9518 WHIRLPOOL 6e9a1a97ce317d3ae562663b1cac5115507487694aed3bd16e500f2c4b295a8735705b2e1c24c1ddf10c00a0eb1d2c444a6bdbb154b1e20c6e7210fdbfa95f8f
diff --git a/sys-auth/elogind/elogind-229.4.ebuild b/sys-auth/elogind/elogind-229.4.ebuild
new file mode 100644
index 000000000000..a5912caf290c
--- /dev/null
+++ b/sys-auth/elogind/elogind-229.4.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools linux-info pam udev
+
+DESCRIPTION="The systemd project's logind, extracted to a standalone package"
+HOMEPAGE="https://github.com/elogind/elogind"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC0-1.0 LGPL-2.1+ public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="acl debug pam policykit selinux"
+
+RDEPEND="
+	sys-apps/util-linux
+	sys-libs/libcap
+	virtual/libudev:=
+	acl? ( sys-apps/acl )
+	pam? ( virtual/pam )
+	selinux? ( sys-libs/libselinux )
+	!sys-apps/systemd
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xml-dtd:4.5
+	app-text/docbook-xsl-stylesheets
+	dev-util/gperf
+	dev-util/intltool
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+PDEPEND="
+	sys-apps/dbus
+	policykit? ( sys-auth/polkit )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-226.4-docs.patch" )
+
+pkg_setup() {
+	local CONFIG_CHECK="~CGROUPS ~EPOLL ~INOTIFY_USER ~SECURITY_SMACK
+		~SIGNALFD ~TIMERFD"
+
+	if use kernel_linux; then
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf # Makefile.am patched by "${FILESDIR}/${P}-docs.patch"
+}
+
+src_configure() {
+	econf \
+		--with-pamlibdir=$(getpam_mod_dir) \
+		--with-udevrulesdir="$(get_udevdir)"/rules.d \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--with-rootlibdir="${EPREFIX}"/$(get_libdir) \
+		--enable-smack \
+		--disable-kdbus \
+		$(use_enable debug debug elogind) \
+		$(use_enable acl) \
+		$(use_enable pam) \
+		$(use_enable selinux)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	newinitd "${FILESDIR}"/${PN}.init ${PN}
+	newconfd "${FILESDIR}"/${PN}.conf ${PN}
+}
+
+pkg_postinst() {
+	if [ "$(rc-config list default | grep elogind)" = "" ]; then
+		ewarn "To enable the elogind daemon, elogind must be"
+		ewarn "added to the default runlevel:"
+		ewarn "# rc-update add elogind default"
+	fi
+}
-- 
cgit v1.2.3-18-g5258