From f069fe61dd4e937c86d7b45690c03b152267c846 Mon Sep 17 00:00:00 2001
From: Sven Eden <yamakuzure@gmx.net>
Date: Thu, 29 Jun 2017 22:38:32 +1000
Subject: sys-auth/elogind: version bump 231.3

Gentoo-bug: 623020
Package-Manager: Portage-2.3.6, Repoman-2.3.2
---
 sys-auth/elogind/Manifest             |  1 +
 sys-auth/elogind/elogind-231.3.ebuild | 84 +++++++++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)
 create mode 100644 sys-auth/elogind/elogind-231.3.ebuild

(limited to 'sys-auth/elogind')

diff --git a/sys-auth/elogind/Manifest b/sys-auth/elogind/Manifest
index f5ed53f35ba3..126df4316423 100644
--- a/sys-auth/elogind/Manifest
+++ b/sys-auth/elogind/Manifest
@@ -1 +1,2 @@
 DIST elogind-229.6.tar.gz 765900 SHA256 19f08dba36509b3c5baf1f35d9ac1f5b473b550c081f63fa64ffbe8862ede7aa SHA512 a1bf2937ad2f8d351cd5a0ca5c1c73e85746d14e0a252befa3ed0d396e782df0fde34c49101931189cd56404b59709a7e5ae5beceaac6f30151b50fb32d26ae0 WHIRLPOOL 24d6315d4568b18df4eaa42410f2744b31ab935dd6a7fb0281e4fe2b2e953e411d462db829cbde786c338e823823998e13a9af287252440642499dfe8aca1b1c
+DIST elogind-231.3.tar.gz 812510 SHA256 dff5fd882e1ff963c6407ace6618fb220fe48e9cfda48282eecd45b1eabef666 SHA512 824fd60727f798f3601bb43aed6304a44bf22d3907d395f44f8f48f861ba87c1dd707882ef88dfcffc3d92cc9291daf0e1245b02a397eabe59a6e17ecb5e59b9 WHIRLPOOL 6a8125ab983cfb006f54582aa5c5dfd3a1b22ceacdc5a1f9171f1663182ed0444079857b621c37b541014aadbaa55c54177fed335cd9b0563a2d3b1191667877
diff --git a/sys-auth/elogind/elogind-231.3.ebuild b/sys-auth/elogind/elogind-231.3.ebuild
new file mode 100644
index 000000000000..fb722cd1ce66
--- /dev/null
+++ b/sys-auth/elogind/elogind-231.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools linux-info pam udev
+
+DESCRIPTION="The systemd project's logind, extracted to a standalone package"
+HOMEPAGE="https://github.com/elogind/elogind"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC0-1.0 LGPL-2.1+ public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="acl debug pam policykit selinux"
+
+RDEPEND="
+	sys-apps/util-linux
+	sys-libs/libcap
+	virtual/libudev:=
+	acl? ( sys-apps/acl )
+	pam? ( virtual/pam )
+	selinux? ( sys-libs/libselinux )
+	!sys-apps/systemd
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xml-dtd:4.5
+	app-text/docbook-xsl-stylesheets
+	dev-util/gperf
+	dev-util/intltool
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+PDEPEND="
+	sys-apps/dbus
+	policykit? ( sys-auth/polkit )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-226.4-docs.patch" )
+
+pkg_setup() {
+	local CONFIG_CHECK="~CGROUPS ~EPOLL ~INOTIFY_USER ~SECURITY_SMACK
+		~SIGNALFD ~TIMERFD"
+
+	if use kernel_linux; then
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf # Makefile.am patched by "${FILESDIR}/${P}-docs.patch"
+}
+
+src_configure() {
+	econf \
+		--with-pamlibdir=$(getpam_mod_dir) \
+		--with-udevrulesdir="$(get_udevdir)"/rules.d \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--with-rootlibdir="${EPREFIX}"/$(get_libdir) \
+		--enable-smack \
+		--with-cgroup-controller=openrc \
+		$(use_enable debug debug elogind) \
+		$(use_enable acl) \
+		$(use_enable pam) \
+		$(use_enable selinux)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	newinitd "${FILESDIR}"/${PN}.init ${PN}
+	newconfd "${FILESDIR}"/${PN}.conf ${PN}
+}
+
+pkg_postinst() {
+	if [ "$(rc-config list boot | grep elogind)" = "" ]; then
+		ewarn "To enable the elogind daemon, elogind must be"
+		ewarn "added to the boot runlevel:"
+		ewarn "# rc-update add elogind boot"
+	fi
+}
-- 
cgit v1.2.3-18-g5258