From e1978be7e390b24a4edbccb0db659e6ba7532f34 Mon Sep 17 00:00:00 2001
From: Marek Szuba <marecki@gentoo.org>
Date: Sun, 6 Sep 2020 22:38:16 +0200
Subject: sys-auth/yubico-piv-tool: make p11-kit aware of libykcs11

Closes: https://bugs.gentoo.org/701058
Signed-off-by: Marek Szuba <marecki@gentoo.org>
---
 .../yubico-piv-tool-2.1.1-r1.ebuild                | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 sys-auth/yubico-piv-tool/yubico-piv-tool-2.1.1-r1.ebuild

(limited to 'sys-auth')

diff --git a/sys-auth/yubico-piv-tool/yubico-piv-tool-2.1.1-r1.ebuild b/sys-auth/yubico-piv-tool/yubico-piv-tool-2.1.1-r1.ebuild
new file mode 100644
index 000000000000..8065e7bafa77
--- /dev/null
+++ b/sys-auth/yubico-piv-tool/yubico-piv-tool-2.1.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Command line tool for the YubiKey PIV application"
+SRC_URI="https://github.com/Yubico/yubico-piv-tool/archive/yubico-piv-tool-${PV}.tar.gz"
+HOMEPAGE="https://developers.yubico.com/yubico-piv-tool/ https://github.com/Yubico/yubico-piv-tool"
+
+LICENSE="BSD-2"
+SLOT="0/1"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:0=[-bindist]
+	sys-apps/pcsc-lite
+"
+DEPEND="${RDEPEND}
+	dev-util/gengetopt
+	sys-apps/help2man
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.1.1-install-man-page.patch
+	"${FILESDIR}"/${PN}-2.1.1-tests-optional.patch
+)
+
+S="${WORKDIR}/${PN}-${P}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_STATIC_LIB=OFF
+		-DBUILD_TESTING=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	echo "module: ${EPREFIX}/usr/$(get_libdir)/libykcs11.so" > ${PN}.module \
+		|| die "Failed to generate p11-kit module configuration"
+	insinto /usr/share/p11-kit/modules
+	doins ${PN}.module
+}
-- 
cgit v1.2.3-65-gdbad