From 079d4f2b6783d80eb862d593b7aa1cd22431e74e Mon Sep 17 00:00:00 2001
From: Marek Szuba <marecki@gentoo.org>
Date: Wed, 23 Dec 2020 15:14:17 +0000
Subject: www-apps/cgit: migrate to lua-single.eclass

Compatibility as per the upstream README. Implementation name is passed
directly to the build scripts so trivial to migrate.

Both the latest release and the live ebuild.

Closes: https://bugs.gentoo.org/752870
Signed-off-by: Marek Szuba <marecki@gentoo.org>
---
 www-apps/cgit/cgit-1.2.3-r100.ebuild | 100 +++++++++++++++++++++++++++++++++++
 www-apps/cgit/cgit-9999.ebuild       |  18 +++----
 2 files changed, 107 insertions(+), 11 deletions(-)
 create mode 100644 www-apps/cgit/cgit-1.2.3-r100.ebuild

(limited to 'www-apps')

diff --git a/www-apps/cgit/cgit-1.2.3-r100.ebuild b/www-apps/cgit/cgit-1.2.3-r100.ebuild
new file mode 100644
index 000000000000..08c24550c1b8
--- /dev/null
+++ b/www-apps/cgit/cgit-1.2.3-r100.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..2} luajit )
+WEBAPP_MANUAL_SLOT="yes"
+
+inherit lua-single toolchain-funcs webapp
+
+[[ -z "${CGIT_CACHEDIR}" ]] && CGIT_CACHEDIR="/var/cache/${PN}/"
+
+GIT_V="2.25.1"
+
+DESCRIPTION="a fast web-interface for git repositories"
+HOMEPAGE="https://git.zx2c4.com/cgit/about"
+SRC_URI="https://www.kernel.org/pub/software/scm/git/git-${GIT_V}.tar.xz
+	https://git.zx2c4.com/cgit/snapshot/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc +highlight libressl +lua test"
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/cgit
+	acct-user/cgit
+	dev-vcs/git
+	highlight? ( || ( dev-python/pygments app-text/highlight ) )
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	lua? ( ${LUA_DEPS} )
+	sys-libs/zlib
+	virtual/httpd-cgi
+"
+# ebuilds without WEBAPP_MANUAL_SLOT="yes" are broken
+DEPEND="${RDEPEND}
+	doc? ( app-text/docbook-xsl-stylesheets
+		>=app-text/asciidoc-8.5.1 )
+"
+
+pkg_setup() {
+	webapp_pkg_setup
+	use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+	rmdir git || die
+	mv "${WORKDIR}"/git-"${GIT_V}" git || die
+
+	echo "prefix = ${EPREFIX}/usr" >> cgit.conf
+	echo "libdir = ${EPREFIX}/usr/$(get_libdir)" >> cgit.conf
+	echo "CGIT_SCRIPT_PATH = ${MY_CGIBINDIR}" >> cgit.conf
+	echo "CGIT_DATA_PATH = ${MY_HTDOCSDIR}" >> cgit.conf
+	echo "CACHE_ROOT = ${CGIT_CACHEDIR}" >> cgit.conf
+	echo "DESTDIR = ${D}" >> cgit.conf
+	if use lua; then
+		echo "LUA_PKGCONFIG = ${ELUA}" >> cgit.conf
+	else
+		echo "NO_LUA = 1" >> cgit.conf
+	fi
+
+	eapply_user
+}
+
+src_compile() {
+	emake V=1 AR="$(tc-getAR)" CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+	use doc && emake V=1 doc-man
+}
+
+src_install() {
+	webapp_src_preinst
+
+	emake V=1 AR="$(tc-getAR)" CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" install
+
+	insinto /etc
+	doins "${FILESDIR}"/cgitrc
+
+	dodoc README
+	use doc && doman cgitrc.5
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+	webapp_src_install
+
+	keepdir "${CGIT_CACHEDIR}"
+	fowners ${PN}:${PN} "${CGIT_CACHEDIR}"
+	fperms 700 "${CGIT_CACHEDIR}"
+}
+
+src_test() {
+	emake V=1 AR="$(tc-getAR)" CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" test
+}
+
+pkg_postinst() {
+	webapp_pkg_postinst
+	ewarn "If you intend to run cgit using web server's user"
+	ewarn "you should change ${CGIT_CACHEDIR} permissions."
+}
diff --git a/www-apps/cgit/cgit-9999.ebuild b/www-apps/cgit/cgit-9999.ebuild
index 4b617428b6e8..8975d5eebd66 100644
--- a/www-apps/cgit/cgit-9999.ebuild
+++ b/www-apps/cgit/cgit-9999.ebuild
@@ -3,9 +3,10 @@
 
 EAPI=7
 
+LUA_COMPAT=( lua5-{1..2} luajit )
 WEBAPP_MANUAL_SLOT="yes"
 
-inherit git-r3 toolchain-funcs webapp
+inherit git-r3 lua-single toolchain-funcs webapp
 
 [[ -z "${CGIT_CACHEDIR}" ]] && CGIT_CACHEDIR="/var/cache/${PN}/"
 
@@ -17,7 +18,8 @@ EGIT_REPO_URI="https://git.zx2c4.com/cgit"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="doc +highlight libressl +lua +luajit test"
+IUSE="doc +highlight libressl +lua test"
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
 RESTRICT="!test? ( test )"
 
 RDEPEND="
@@ -27,10 +29,7 @@ RDEPEND="
 	highlight? ( || ( dev-python/pygments app-text/highlight ) )
 	!libressl? ( dev-libs/openssl:0= )
 	libressl? ( dev-libs/libressl:0= )
-	lua? (
-		luajit? ( dev-lang/luajit )
-		!luajit? ( dev-lang/lua:0 )
-	)
+	lua? ( ${LUA_DEPS} )
 	sys-libs/zlib
 	virtual/httpd-cgi
 "
@@ -42,6 +41,7 @@ DEPEND="${RDEPEND}
 
 pkg_setup() {
 	webapp_pkg_setup
+	use lua && lua-single_pkg_setup
 }
 
 src_prepare() {
@@ -52,11 +52,7 @@ src_prepare() {
 	echo "CACHE_ROOT = ${CGIT_CACHEDIR}" >> cgit.conf
 	echo "DESTDIR = ${D}" >> cgit.conf
 	if use lua; then
-		if use luajit; then
-			echo "LUA_PKGCONFIG = luajit" >> cgit.conf
-		else
-			echo "LUA_PKGCONFIG = lua" >> cgit.conf
-		fi
+		echo "LUA_PKGCONFIG = ${ELUA}" >> cgit.conf
 	else
 		echo "NO_LUA = 1" >> cgit.conf
 	fi
-- 
cgit v1.2.3-65-gdbad