From 803171e57279ee7b2dd3390eb125f0194ba0b130 Mon Sep 17 00:00:00 2001
From: Thomas Deutschmann <whissi@gentoo.org>
Date: Sun, 8 Mar 2020 02:31:14 +0100
Subject: www-apps/trac: bump to v1.2.5

Closes: https://bugs.gentoo.org/676924
Bug: https://bugs.gentoo.org/711754
Package-Manager: Portage-2.3.91, Repoman-2.3.20
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>
---
 www-apps/trac/Manifest          |   1 +
 www-apps/trac/trac-1.2.5.ebuild | 114 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 115 insertions(+)
 create mode 100644 www-apps/trac/trac-1.2.5.ebuild

(limited to 'www-apps')

diff --git a/www-apps/trac/Manifest b/www-apps/trac/Manifest
index 79bc4f0b4939..f69fc949cc00 100644
--- a/www-apps/trac/Manifest
+++ b/www-apps/trac/Manifest
@@ -1,2 +1,3 @@
 DIST Trac-1.0.9.tar.gz 3642845 BLAKE2B de0a6fdfc59c5c3f1e795a7e0a006e724491d1d084c9fefcc35185a40430e06ed781c94cf9190d394b943064fd87a34a6fffea7f57c3d4b55b591a6aab5a83ad SHA512 af429db720049ab344ce3c3b430dcf0ab7530013f59ccd2334633de9babc3f31b14829b9b5aa48aa05f614ca72d1d557953c58bbfb93faae2267afeac72e6304
 DIST Trac-1.2.1.tar.gz 6212917 BLAKE2B 6445ec515b295d0fdd3a75e93da853d136f19083b6e87cbe9c856e2502d217c433bfd7f885d8ff45556882e8c99a7d6e966761027f72e32e675278ee83a67eb6 SHA512 0ee008ce0d890873eb6db7eca60e362760c4a4857dd74bda67c30e566dcb5bd64ccd6d5e7317da904e8dcfb7d4a017004d3bb794dd405936c94803b2fcc4829f
+DIST Trac-1.2.5.tar.gz 5333965 BLAKE2B 51a58773fc037db66b748abddc4905738f2766c3aef87913cb2acd66cc6fcff14be288322ed1bc92435a7a7ab8de6020259a3363459ef1363518cdacf1ac4c0e SHA512 ee8faa6950f5148fe8adca9381f3228dc9f198457b2c44fad8331ca87a1e3ab15906b25c7b01fa8face4e93a366fdf12c27843198db6a9642481820e7456a76c
diff --git a/www-apps/trac/trac-1.2.5.ebuild b/www-apps/trac/trac-1.2.5.ebuild
new file mode 100644
index 000000000000..0b32c0ad7066
--- /dev/null
+++ b/www-apps/trac/trac-1.2.5.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE='sqlite?'
+
+DISTUTILS_SINGLE_IMPL=Yes
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1 eutils user webapp
+
+MY_PV=${PV/_p/.post}
+MY_P=Trac-${MY_PV}
+
+DESCRIPTION="Enhanced wiki and issue tracking system for software development projects"
+HOMEPAGE="https://trac.edgewall.com/ https://pypi.org/project/Trac/"
+SRC_URI="https://download.edgewall.org/trac/Trac-${MY_PV}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="cgi fastcgi i18n +highlight +restructuredtext mysql postgres +sqlite subversion"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/setuptools[${PYTHON_MULTI_USEDEP}]
+		dev-python/genshi[${PYTHON_MULTI_USEDEP}]
+		dev-python/pytz[${PYTHON_MULTI_USEDEP}]
+		i18n? ( >=dev-python/Babel-0.9.5[${PYTHON_MULTI_USEDEP}] )
+		highlight? (
+			|| (
+				dev-python/pygments[${PYTHON_MULTI_USEDEP}]
+				app-text/silvercity
+				app-text/pytextile
+				app-text/enscript
+			)
+		)
+		restructuredtext? ( dev-python/docutils[${PYTHON_MULTI_USEDEP}] )
+		mysql? ( dev-python/mysql-python[${PYTHON_MULTI_USEDEP}] )
+		postgres? ( >=dev-python/psycopg-2[${PYTHON_MULTI_USEDEP}] )
+		sqlite? ( >=dev-db/sqlite-3.3.4:3 )
+		subversion? ( dev-vcs/subversion[python,${PYTHON_MULTI_USEDEP}] )
+	')
+	"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+# Tests depend on twill, a broken package
+RESTRICT="test"
+
+WEBAPP_MANUAL_SLOT="yes"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	webapp_pkg_setup
+
+	enewgroup tracd
+	enewuser tracd -1 -1 -1 tracd
+}
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	distutils-r1_src_test
+}
+
+python_test() {
+	PYTHONPATH=. "${PYTHON}" trac/test.py || die "Tests fail with ${EPYTHON}"
+}
+
+python_test_all() {
+	if use i18n; then
+		make check
+	fi
+}
+
+# the default src_compile just calls setup.py build
+# currently, this switches i18n catalog compilation based on presence of Babel
+
+src_install() {
+	webapp_src_preinst
+	distutils-r1_src_install
+
+	# project environments might go in here
+	keepdir /var/lib/trac
+
+	# Use this as the egg-cache for tracd
+	dodir /var/lib/trac/egg-cache
+	keepdir /var/lib/trac/egg-cache
+	fowners tracd:tracd /var/lib/trac/egg-cache
+
+	# documentation
+	dodoc -r contrib
+
+	# tracd init script
+	newconfd "${FILESDIR}"/tracd.confd tracd
+	newinitd "${FILESDIR}"/tracd.initd tracd
+
+	for lang in en; do
+		webapp_postinst_txt ${lang} "${FILESDIR}"/postinst-${lang}.txt
+		webapp_postupgrade_txt ${lang} "${FILESDIR}"/postupgrade-${lang}.txt
+	done
+
+	webapp_src_install
+}
+
+pkg_postinst() {
+	webapp_pkg_postinst
+}
-- 
cgit v1.2.3-65-gdbad