From 59b905fefa279bf5c72cecbf2f2b7516cb4cbadc Mon Sep 17 00:00:00 2001
From: Ian Delaney <idella4@gentoo.org>
Date: Mon, 26 Oct 2015 21:37:07 +0800
Subject: www-client/qutebrowser: revbump to -0.4.1-r1

change in install location of icons by inherit of gnome2-utils and
'doicon -s', cross tested by 'wraeth', ack to hasufell for
suggested improvements. leave -0.4.1 ebuild for now.

Package-Manager: portage-2.2.23
---
 www-client/qutebrowser/qutebrowser-0.4.1-r1.ebuild | 75 ++++++++++++++++++++++
 1 file changed, 75 insertions(+)
 create mode 100644 www-client/qutebrowser/qutebrowser-0.4.1-r1.ebuild

(limited to 'www-client/qutebrowser')

diff --git a/www-client/qutebrowser/qutebrowser-0.4.1-r1.ebuild b/www-client/qutebrowser/qutebrowser-0.4.1-r1.ebuild
new file mode 100644
index 000000000000..6e4744da5712
--- /dev/null
+++ b/www-client/qutebrowser/qutebrowser-0.4.1-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python3_4 )
+
+inherit gnome2-utils distutils-r1 eutils fdo-mime
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/The-Compiler/qutebrowser.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/The-Compiler/qutebrowser/releases/download/v${PV}/qutebrowser-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A keyboard-driven, vim-like browser based on PyQt5 and QtWebKit"
+HOMEPAGE="https://github.com/The-Compiler/qutebrowser"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="gstreamer test"
+
+COMMON_DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${COMMON_DEPEND}
+	app-text/asciidoc
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-python/jinja-2.7.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0.2[${PYTHON_USEDEP}]
+	>=dev-python/pypeg2-2.15.1[${PYTHON_USEDEP}]
+	dev-python/PyQt5[${PYTHON_USEDEP},gui,network,printsupport,webkit,widgets]
+	dev-python/sip[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.11[${PYTHON_USEDEP}]
+	gstreamer? ( dev-qt/qtwebkit:5[gstreamer] )
+"
+
+RESTRICT="test"
+
+python_compile_all() {
+	if [[ ${PV} == "9999" ]]; then
+		"${PYTHON}" scripts/asciidoc2html.py || die "Failed generating docs"
+	fi
+
+	a2x -f manpage doc/${PN}.1.asciidoc || die "Failed generating man page"
+}
+
+python_test() {
+	py.test tests || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	doman doc/${PN}.1
+	dodoc {CHANGELOG,CONTRIBUTING,FAQ,README}.asciidoc
+
+	domenu ${PN}.desktop
+	doicon -s scalable icons/${PN}.svg
+
+	distutils-r1_python_install_all
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
-- 
cgit v1.2.3-65-gdbad