From 20d00ba21beda537e98348488795adb2dbc98985 Mon Sep 17 00:00:00 2001
From: Mike Gilbert <floppym@gentoo.org>
Date: Wed, 9 May 2018 19:41:30 -0400
Subject: www-plugins/chrome-binary-plugins: automated update (67.0.3396.40,
 68.0.3423.2)

Package-Manager: Portage-2.3.36, Repoman-2.3.9_p193
---
 .../chrome-binary-plugins-68.0.3423.2_alpha.ebuild | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 www-plugins/chrome-binary-plugins/chrome-binary-plugins-68.0.3423.2_alpha.ebuild

(limited to 'www-plugins/chrome-binary-plugins/chrome-binary-plugins-68.0.3423.2_alpha.ebuild')

diff --git a/www-plugins/chrome-binary-plugins/chrome-binary-plugins-68.0.3423.2_alpha.ebuild b/www-plugins/chrome-binary-plugins/chrome-binary-plugins-68.0.3423.2_alpha.ebuild
new file mode 100644
index 000000000000..f2cb5723b3da
--- /dev/null
+++ b/www-plugins/chrome-binary-plugins/chrome-binary-plugins-68.0.3423.2_alpha.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit multilib unpacker
+
+DESCRIPTION="Binary plugins from Google Chrome for use in Chromium"
+HOMEPAGE="https://www.google.com/chrome"
+
+case ${PV} in
+	*_alpha*)
+		SLOT="unstable"
+		CHROMEDIR="opt/google/chrome-${SLOT}"
+		MY_PV=${PV%_alpha}-1
+		;;
+	*_beta*)
+		SLOT="beta"
+		CHROMEDIR="opt/google/chrome-${SLOT}"
+		MY_PV=${PV%_beta}-1
+		;;
+	*)
+		SLOT="stable"
+		CHROMEDIR="opt/google/chrome"
+		MY_PV=${PV}-1
+		;;
+esac
+
+MY_PN="google-chrome-${SLOT}"
+MY_P="${MY_PN}_${MY_PV}"
+
+SRC_URI="https://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_amd64.deb"
+KEYWORDS="-* ~amd64"
+
+LICENSE="google-chrome"
+IUSE="+widevine"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="widevine? ( !<www-client/chromium-57[widevine(-)] )"
+
+for x in 0 beta stable unstable; do
+	if [[ ${SLOT} != ${x} ]]; then
+		RDEPEND+=" !${CATEGORY}/${PN}:${x}"
+	fi
+done
+
+S="${WORKDIR}/${CHROMEDIR}"
+QA_PREBUILT="*"
+
+pkg_nofetch() {
+	eerror "Please wait 24 hours and sync your portage tree before reporting fetch failures."
+}
+
+src_install() {
+	insinto /usr/$(get_libdir)/chromium
+	if use widevine; then
+		doins libwidevinecdm.so
+		dosym ../chromium/libwidevinecdm.so /usr/$(get_libdir)/chromium-browser/libwidevinecdm.so
+	fi
+}
-- 
cgit v1.2.3-65-gdbad