From 50d57f188535544ba5dde67c1bddc9298b2dd765 Mon Sep 17 00:00:00 2001
From: Gilles Dartiguelongue <eva@gentoo.org>
Date: Thu, 7 Jan 2016 23:25:40 +0100
Subject: x11-libs/libxklavier: let dosym fail if it has to, bug #551198

Bump to EAPI=5, set subslot value, pin slot on dependencies,
handle gtk-doc per project Gnome policies, move doc installation
to src_install since it needs to exist due to prune_libtool_files.

Package-Manager: portage-2.2.26
---
 x11-libs/libxklavier/libxklavier-5.3-r1.ebuild | 51 ++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 x11-libs/libxklavier/libxklavier-5.3-r1.ebuild

(limited to 'x11-libs/libxklavier')

diff --git a/x11-libs/libxklavier/libxklavier-5.3-r1.ebuild b/x11-libs/libxklavier/libxklavier-5.3-r1.ebuild
new file mode 100644
index 000000000000..9238da803c75
--- /dev/null
+++ b/x11-libs/libxklavier/libxklavier-5.3-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils gnome.org libtool
+
+DESCRIPTION="A library for the X Keyboard Extension (high-level API)"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/LibXklavier"
+
+LICENSE="LGPL-2"
+SLOT="0/16"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+introspection"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.16:2
+	dev-libs/libxml2:2
+	x11-apps/xkbcomp
+	x11-libs/libX11
+	>=x11-libs/libXi-1.1.3
+	x11-libs/libxkbfile
+	>=x11-misc/xkeyboard-config-2.4.1-r3
+	introspection? ( >=dev-libs/gobject-introspection-1.30:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.4
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--disable-gtk-doc \
+		$(use_enable introspection) \
+		--with-xkb-base="${EPREFIX}"/usr/share/X11/xkb \
+		--with-xkb-bin-base="${EPREFIX}"/usr/bin
+}
+
+src_install() {
+	default
+	dodoc AUTHORS ChangeLog CREDITS NEWS README
+	prune_libtool_files
+}
-- 
cgit v1.2.3-65-gdbad