From 0ba5bd57189250c6bc82f7af56f2a974e3b62ea5 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Tue, 15 Sep 2020 22:30:26 +0200
Subject: x11-misc/3ddesktop: Fix building with sys-devel/clang

Package-Manager: Portage-3.0.7, Repoman-3.0.1
Closes: https://bugs.gentoo.org/742671
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 x11-misc/3ddesktop/3ddesktop-0.2.9-r1.ebuild       |  5 +-
 x11-misc/3ddesktop/3ddesktop-0.2.9-r2.ebuild       | 58 ++++++++++++++++++++++
 .../files/3ddesktop-0.2.9-Options_Options.patch    | 11 ++++
 3 files changed, 72 insertions(+), 2 deletions(-)
 create mode 100644 x11-misc/3ddesktop/3ddesktop-0.2.9-r2.ebuild
 create mode 100644 x11-misc/3ddesktop/files/3ddesktop-0.2.9-Options_Options.patch

(limited to 'x11-misc/3ddesktop')

diff --git a/x11-misc/3ddesktop/3ddesktop-0.2.9-r1.ebuild b/x11-misc/3ddesktop/3ddesktop-0.2.9-r1.ebuild
index 9751760d13b8..1a17ff0dc9bd 100644
--- a/x11-misc/3ddesktop/3ddesktop-0.2.9-r1.ebuild
+++ b/x11-misc/3ddesktop/3ddesktop-0.2.9-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=5
@@ -35,7 +35,8 @@ src_prepare() {
 		"${FILESDIR}"/${P}-gcc4.patch \
 		"${FILESDIR}"/${P}-asneeded.patch \
 		"${FILESDIR}"/${P}-missing-include.patch \
-		"${FILESDIR}"/${P}-gl_init.patch
+		"${FILESDIR}"/${P}-gl_init.patch \
+		"${FILESDIR}"/${P}-Options_Options.patch
 
 	eautoreconf
 }
diff --git a/x11-misc/3ddesktop/3ddesktop-0.2.9-r2.ebuild b/x11-misc/3ddesktop/3ddesktop-0.2.9-r2.ebuild
new file mode 100644
index 000000000000..199878c516f1
--- /dev/null
+++ b/x11-misc/3ddesktop/3ddesktop-0.2.9-r2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="OpenGL virtual desktop switching"
+HOMEPAGE="https://sourceforge.net/projects/desk3d/"
+SRC_URI="mirror://sourceforge/desk3d/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="
+	>=media-libs/freetype-2
+	media-libs/freeglut
+	media-libs/imlib2[X]
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXmu
+	x11-libs/libXt
+	x11-libs/libXxf86vm
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+DOCS=( AUTHORS TODO ChangeLog README README.windowmanagers )
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc4.patch
+	"${FILESDIR}"/${P}-asneeded.patch
+	"${FILESDIR}"/${P}-missing-include.patch
+	"${FILESDIR}"/${P}-gl_init.patch
+	"${FILESDIR}"/${P}-Options_Options.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+pkg_postinst() {
+	echo
+	elog "This ebuild installed a configuration file called /etc/3ddesktop.conf"
+	elog "The default configuration makes a screenshot of the virtual desktops"
+	elog "every X seconds. This is non-optimal behavior."
+	elog
+	elog "To enable a more intelligent way of updating the virtual desktops,"
+	elog "execute the following:"
+	elog
+	elog "  echo \"AutoAcquire 0\" >> /etc/3ddesktop.conf"
+	elog
+	elog "This will cause 3ddesktop to update the virtual desktop snapshots"
+	elog "only when a 3d desktop switch is required."
+}
diff --git a/x11-misc/3ddesktop/files/3ddesktop-0.2.9-Options_Options.patch b/x11-misc/3ddesktop/files/3ddesktop-0.2.9-Options_Options.patch
new file mode 100644
index 000000000000..00e8b8c1ee53
--- /dev/null
+++ b/x11-misc/3ddesktop/files/3ddesktop-0.2.9-Options_Options.patch
@@ -0,0 +1,11 @@
+--- a/config.cpp
++++ b/config.cpp
+@@ -64,7 +64,7 @@
+ }
+ 
+ 
+-Options::Options(char *n = NULL) 
++Options::Options(char *n) 
+ {
+ 
+     if (n)
-- 
cgit v1.2.3-65-gdbad