From 0de04f9324dd2b15888a38325b573ae2d3f92dd1 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sat, 8 Feb 2020 08:01:16 +0100
Subject: x11-terms/guake: Switch to PYTHON_MULTI_USEDEP API
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 x11-terms/guake/guake-3.3.2-r1.ebuild | 62 +++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 x11-terms/guake/guake-3.3.2-r1.ebuild

(limited to 'x11-terms/guake/guake-3.3.2-r1.ebuild')

diff --git a/x11-terms/guake/guake-3.3.2-r1.ebuild b/x11-terms/guake/guake-3.3.2-r1.ebuild
new file mode 100644
index 000000000000..1426b793e688
--- /dev/null
+++ b/x11-terms/guake/guake-3.3.2-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_6 )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 gnome2-utils xdg-utils
+
+DESCRIPTION="Drop-down terminal for GNOME"
+HOMEPAGE="https://github.com/Guake/guake https://pypi.org/project/Guake"
+SRC_URI="mirror://pypi/G/${PN^}/${P^}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 arm x86"
+IUSE="utempter"
+
+RDEPEND="
+	dev-libs/keybinder:3
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
+		dev-python/pbr[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+	')
+	x11-libs/libnotify
+	x11-libs/vte:2.91
+	utempter? ( sys-libs/libutempter )
+"
+DEPEND="
+	${RDEPEND}
+	gnome-base/gsettings-desktop-schemas
+	sys-devel/gettext
+	sys-devel/make
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.3.2-paths.patch
+)
+S=${WORKDIR}/${P^}
+
+python_compile_all() {
+	emake prepare-install prefix=/usr
+	emake generate-paths prefix=/usr DATA_DIR='$(datadir)/guake' DEV_SCHEMA_DIR='$(gsettingsschemadir)'
+	default
+}
+
+python_install_all() {
+	emake install-schemas install-locale prefix=/usr DESTDIR="${D}"
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3-65-gdbad