From 57d412a4e9843b7bbef232b04819540abab0577b Mon Sep 17 00:00:00 2001
From: Tim Harder <radhermit@gentoo.org>
Date: Mon, 18 Nov 2019 15:34:40 -0700
Subject: x11-wm/herbstluftwm: fix BDEPEND

Signed-off-by: Tim Harder <radhermit@gentoo.org>
---
 x11-wm/herbstluftwm/herbstluftwm-0.7.2-r1.ebuild | 66 ++++++++++++++++++++++++
 x11-wm/herbstluftwm/herbstluftwm-9999.ebuild     | 12 ++---
 2 files changed, 71 insertions(+), 7 deletions(-)
 create mode 100644 x11-wm/herbstluftwm/herbstluftwm-0.7.2-r1.ebuild

(limited to 'x11-wm')

diff --git a/x11-wm/herbstluftwm/herbstluftwm-0.7.2-r1.ebuild b/x11-wm/herbstluftwm/herbstluftwm-0.7.2-r1.ebuild
new file mode 100644
index 000000000000..9fe9d04ef469
--- /dev/null
+++ b/x11-wm/herbstluftwm/herbstluftwm-0.7.2-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs bash-completion-r1
+
+if [[ ${PV} == 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/herbstluftwm/herbstluftwm.git"
+	BDEPEND="app-text/asciidoc"
+else
+	SRC_URI="https://herbstluftwm.org/tarballs/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	BDEPEND=""
+fi
+
+DESCRIPTION="A manual tiling window manager for X"
+HOMEPAGE="https://herbstluftwm.org/"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="examples xinerama zsh-completion"
+
+DEPEND=">=dev-libs/glib-2.24:2
+	x11-libs/libX11
+	x11-libs/libXext
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${DEPEND}
+	app-shells/bash
+	zsh-completion? ( app-shells/zsh )"
+BDEPEND+=" virtual/pkgconfig"
+
+src_compile() {
+	tc-export CC LD CXX
+
+	emake LDXX="$(tc-getCXX)" COLOR=0 VERBOSE= \
+		$(use xinerama || echo XINERAMAFLAGS= XINERAMALIBS= )
+}
+
+src_install() {
+	dobin herbstluftwm herbstclient
+	dodoc BUGS MIGRATION NEWS README.md
+
+	doman doc/{herbstluftwm,herbstclient}.1
+
+	exeinto /etc/xdg/herbstluftwm
+	doexe share/{autostart,panel.sh,restartpanels.sh}
+
+	insinto /usr/share/xsessions
+	doins share/herbstluftwm.desktop
+
+	newbashcomp share/herbstclient-completion herbstclient
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		doins share/_herbstclient
+	fi
+
+	if use examples ; then
+		exeinto /usr/share/doc/${PF}/examples
+		doexe scripts/*.sh
+		docinto examples
+		dodoc scripts/README
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
diff --git a/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild b/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
index 0cea06f49ee7..9fe9d04ef469 100644
--- a/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
+++ b/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
@@ -7,11 +7,11 @@ inherit toolchain-funcs bash-completion-r1
 if [[ ${PV} == 9999* ]] ; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/herbstluftwm/herbstluftwm.git"
-	EXTRA_DEPEND="app-text/asciidoc"
+	BDEPEND="app-text/asciidoc"
 else
 	SRC_URI="https://herbstluftwm.org/tarballs/${P}.tar.gz"
 	KEYWORDS="~amd64 ~x86"
-	EXTRA_DEPEND=""
+	BDEPEND=""
 fi
 
 DESCRIPTION="A manual tiling window manager for X"
@@ -21,16 +21,14 @@ LICENSE="BSD-2"
 SLOT="0"
 IUSE="examples xinerama zsh-completion"
 
-CDEPEND=">=dev-libs/glib-2.24:2
+DEPEND=">=dev-libs/glib-2.24:2
 	x11-libs/libX11
 	x11-libs/libXext
 	xinerama? ( x11-libs/libXinerama )"
-RDEPEND="${CDEPEND}
+RDEPEND="${DEPEND}
 	app-shells/bash
 	zsh-completion? ( app-shells/zsh )"
-DEPEND="${CDEPEND}
-	${EXTRA_DEPEND}
-	virtual/pkgconfig"
+BDEPEND+=" virtual/pkgconfig"
 
 src_compile() {
 	tc-export CC LD CXX
-- 
cgit v1.2.3-65-gdbad