From 18ab365f10b9e6d7b3b86331ef78b28100f3bf5b Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Fri, 15 Dec 2017 20:21:22 +0100
Subject: xfce-base/libxfce4ui: Bump to 4.13.4, add vala support

---
 xfce-base/libxfce4ui/libxfce4ui-4.13.4.ebuild | 72 +++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 xfce-base/libxfce4ui/libxfce4ui-4.13.4.ebuild

(limited to 'xfce-base/libxfce4ui/libxfce4ui-4.13.4.ebuild')

diff --git a/xfce-base/libxfce4ui/libxfce4ui-4.13.4.ebuild b/xfce-base/libxfce4ui/libxfce4ui-4.13.4.ebuild
new file mode 100644
index 000000000000..85f4830a8e84
--- /dev/null
+++ b/xfce-base/libxfce4ui/libxfce4ui-4.13.4.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils vala
+
+DESCRIPTION="Unified widget and session management libs for Xfce"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug glade introspection startup-notification vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND=">=dev-libs/glib-2.42:2=
+	>=x11-libs/gtk+-2.24:2=
+	>=x11-libs/gtk+-3.18:3=[introspection?]
+	x11-libs/libX11:=
+	x11-libs/libICE:=
+	x11-libs/libSM:=
+	>=xfce-base/libxfce4util-4.12:=[introspection?]
+	>=xfce-base/xfconf-4.12:=
+	glade? ( dev-util/glade:3.10= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	startup-notification? ( x11-libs/startup-notification:= )
+	vala? ( $(vala_depend) )
+	!xfce-base/xfce-utils"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable startup-notification)
+		$(use_enable vala)
+		# TODO: check revdeps and make it optional one day
+		--enable-gtk2
+		# requires deprecated glade:3 (gladeui-1.0), bug #551296
+		--disable-gladeui
+		# this one's for :3.10
+		$(use_enable glade gladeui2)
+		--with-vendor-info=Gentoo
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
-- 
cgit v1.2.3-65-gdbad