summaryrefslogtreecommitdiff
blob: a0d968b0c7d3358b35f23759ee589e135c36b423 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI="4"

inherit vim-plugin

MY_PN="DirDiff.vim"
DESCRIPTION="vim plugin: diff and merge two directories recursively"
HOMEPAGE="http://www.vim.org/scripts/script.php?script_id=102"
SRC_URI="https://github.com/vim-scripts/${MY_PN}/tarball/${PV} -> ${P}.tar.gz"
LICENSE="BSD"
KEYWORDS="amd64 x86"
IUSE=""

VIM_PLUGIN_HELPFILES="DirDiff.txt"

RDEPEND="sys-apps/diffutils"

src_unpack() {
	unpack ${A}
	mv *-${MY_PN}-* "${S}"
}

src_prepare() {
	# There's good documentation included with the script, but it's not
	# in a helpfile. Since there's rather too much information to include
	# in a VIM_PLUGIN_HELPTEXT, we'll sed ourselves a help doc.
	mkdir "${S}"/doc
	sed -e '0,/" -\*- vim -\*-$/d' -e '/"  0.7  Initial Release$/,9999d' -e 's/^" \?//' \
		-e 's/\(FILE: \)".\+\.vim"/\1*DirDiff.txt*/' \
		plugin/DirDiff.vim \
		> doc/DirDiff.txt

	rm -f README
}