games-simulation/crashtest/crashtest-1.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6
inherit eutils flag-o-matic

DESCRIPTION="Educational car crash simulator"
HOMEPAGE="http://www.stolk.org/crashtest/"
SRC_URI="http://www.stolk.org/crashtest/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	dev-games/ode
	media-libs/alsa-lib
	media-libs/freeglut
	x11-libs/fltk:1[opengl]
	virtual/opengl
	virtual/glu"
DEPEND="${RDEPEND}
	>=media-libs/plib-1.8.4"

S=${WORKDIR}/${P}/src-${PN}

PATCHES=(
	"${FILESDIR}/${P}"-gentoo.patch
)

src_prepare() {
	default

	sed -i \
		-e "s:@GENTOO_DATADIR@:/usr/share/${PN}:" \
		-e "s:@GENTOO_BINDIR@:/usr/bin:" \
		Makefile ${PN}.cxx || die
	append-cppflags -DHAVE_ISNANF
}

src_install() {
	default
	make_desktop_entry ${PN} Crashtest
}