summaryrefslogtreecommitdiff
blob: 003704713e9f8445a6d11059c44fee2dd0da323b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit desktop toolchain-funcs

MY_PN="7kaa"
MY_PV="$(ver_rs 3- '')"
MY_P="${MY_PN}-${MY_PV}"

DESCRIPTION="Seven Kingdoms: Ancient Adversaries"
HOMEPAGE="https://7kfans.com/"
SRC_URI="https://github.com/the3dfxdude/${MY_PN}/releases/download/v${MY_PV}/${MY_P}.tar.xz
	https://dev.gentoo.org/~pinkbyte/distfiles/${MY_PN}.png"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"

DEPEND="net-libs/enet:1.3=
	media-libs/libsdl2[X,video]
	media-libs/openal
	net-misc/curl"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${MY_P}.tar.xz
}

src_compile() {
	emake AR="$(tc-getAR)"
}

src_install() {
	default

	doicon "${DISTDIR}/${MY_PN}.png"
	make_desktop_entry "${MY_PN}" "Seven Kingdoms: Ancient Adversaries" "${MY_PN}" "Game;StrategyGame"
}