summaryrefslogtreecommitdiff
blob: db66c42003e7dc31fc93ba2dd18ba1fa421ce4fd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

KDE_HANDBOOK="optional"
#VIRTUALX_REQUIRED=test
RESTRICT=test
# test 2: parttest hangs

inherit kde4-base

DESCRIPTION="Universal document viewer based on KPDF"
HOMEPAGE="https://okular.kde.org https://www.kde.org/applications/graphics/okular"
KEYWORDS="amd64 ~arm x86"
IUSE="chm crypt debug djvu dpi ebook +jpeg mobi +postscript +pdf +tiff"

DEPEND="
	media-libs/freetype
	media-libs/qimageblitz
	sys-libs/zlib
	chm? ( dev-libs/chmlib )
	crypt? ( app-crypt/qca:2[qt4] )
	djvu? ( app-text/djvu )
	dpi? ( kde-plasma/libkscreen:4 )
	ebook? ( app-text/ebook-tools )
	jpeg? (
		$(add_kdeapps_dep libkexiv2)
		virtual/jpeg:0
	)
	mobi? ( $(add_kdeapps_dep kdegraphics-mobipocket) )
	pdf? ( >=app-text/poppler-0.20[qt4,-exceptions(-)] )
	postscript? ( app-text/libspectre )
	tiff? ( media-libs/tiff:0 )
"
RDEPEND="${DEPEND}"

src_configure() {
	local mycmakeargs=(
		-DWITH_KActivities=OFF
		-DWITH_CHM=$(usex chm)
		-DWITH_QCA2=$(usex crypt)
		-DWITH_DjVuLibre=$(usex djvu)
		-DWITH_LibKScreen=$(usex dpi)
		-DWITH_EPub=$(usex ebook)
		-DWITH_JPEG=$(usex jpeg)
		-DWITH_Kexiv2=$(usex jpeg)
		-DWITH_QMobipocket=$(usex mobi)
		-DWITH_LibSpectre=$(usex postscript)
		-DWITH_PopplerQt4=$(usex pdf)
		-DWITH_Poppler=$(usex pdf)
		-DWITH_TIFF=$(usex tiff)
	)

	kde4-base_src_configure
}