media-libs/libkate/libkate-0.3.7-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

PYTHON_COMPAT=( python2_7 )
inherit python-single-r1

DESCRIPTION="Codec for karaoke and text encapsulation for Ogg"
HOMEPAGE="https://code.google.com/p/libkate/"
SRC_URI="https://libkate.googlecode.com/files/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd"
IUSE="doc wxwidgets"

COMMON_DEPEND="media-libs/libogg:=
	media-libs/libpng:0="
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig
	sys-devel/flex
	sys-devel/bison
	doc? ( app-doc/doxygen )"
RDEPEND="${COMMON_DEPEND}
	wxwidgets? (
		${PYTHON_DEPS}
		=dev-python/wxpython-2.8*[${PYTHON_USEDEP}]
		media-libs/liboggz )"

REQUIRED_USE="wxwidgets? ( ${PYTHON_REQUIRED_USE} )"

PATCHES=(
	"${FILESDIR}"/${P}-libpng14.patch
)

pkg_setup() {
	use wxwidgets && python-single-r1_pkg_setup
}

src_configure() {
	if ! use wxwidgets; then
		sed -i -e "s/HAVE_PYTHON=yes/HAVE_PYTHON=no/" configure || die
	fi

	econf $(use_enable doc)
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS ChangeLog README
	use wxwidgets && python_fix_shebang "${D}"
}