blob: 44a68ef6ba8275f31a3b24389dada84cde29c73b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit flag-o-matic toolchain-funcs user
DESCRIPTION="A Tool for network monitoring and data acquisition"
HOMEPAGE="http://www.tcpdump.org/"
SRC_URI="
https://github.com/the-${PN}-group/${PN}/archive/${P}.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux"
IUSE="+drop-root libressl smi ssl samba suid test"
RDEPEND="
drop-root? ( sys-libs/libcap-ng )
net-libs/libpcap
smi? ( net-libs/libsmi )
ssl? (
!libressl? ( >=dev-libs/openssl-0.9.6m:0 )
libressl? ( dev-libs/libressl )
)
"
DEPEND="
${RDEPEND}
drop-root? ( virtual/pkgconfig )
test? (
|| ( app-arch/sharutils sys-freebsd/freebsd-ubin )
dev-lang/perl
)
"
S=${WORKDIR}/${PN}-${P}
pkg_setup() {
if use drop-root || use suid; then
enewgroup tcpdump
enewuser tcpdump -1 -1 -1 tcpdump
fi
}
src_configure() {
# tcpdump needs some optimization. see bug #108391
# but do not replace -Os
filter-flags -O[0-9]
has -O? ${CFLAGS} || append-cflags -O2
filter-flags -finline-functions
if use drop-root; then
append-cppflags -DHAVE_CAP_NG_H
export LIBS=$( $(tc-getPKG_CONFIG) --libs libcap-ng )
fi
econf \
$(use_enable samba smb) \
$(use_with drop-root chroot '') \
$(use_with smi) \
$(use_with ssl crypto "${EPREFIX}/usr") \
$(usex drop-root "--with-user=tcpdump" "")
}
src_test() {
if [[ ${EUID} -ne 0 ]] || ! use drop-root; then
sed -i -e '/^\(espudp1\|eapon1\)/d;' tests/TESTLIST || die
emake check
else
ewarn "If you want to run the test suite, make sure you either"
ewarn "set FEATURES=userpriv or set USE=-drop-root"
fi
}
src_install() {
dosbin tcpdump
doman tcpdump.1
dodoc *.awk
dodoc CHANGES CREDITS README.md
if use suid; then
fowners root:tcpdump /usr/sbin/tcpdump
fperms 4110 /usr/sbin/tcpdump
fi
}
pkg_preinst() {
if use drop-root || use suid; then
enewgroup tcpdump
enewuser tcpdump -1 -1 -1 tcpdump
fi
}
pkg_postinst() {
use suid && elog "To let normal users run tcpdump add them into tcpdump group."
}
|
GitWeb