summaryrefslogtreecommitdiff
blob: 64cd5158d18e2561e53e4e6fd6a4952a685191be (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit autotools multilib-minimal

DESCRIPTION="Open source PAM library"
HOMEPAGE="https://www.openpam.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64-fbsd"
IUSE=""

RDEPEND="!sys-libs/pam"
DEPEND="
	sys-devel/make
	dev-lang/perl"

PDEPEND="
	sys-auth/pambase"

PATCHES=(
	"${FILESDIR}/${PN}-20130907-gentoo.patch"
	"${FILESDIR}/${PN}-20130907-nbsd.patch"
	"${FILESDIR}/${PN}-20130907-module-dir.patch"
)

src_prepare() {
	sed -i -e 's:-Werror::' "${S}/configure.ac"
	default
	eautoreconf
}

multilib_src_configure() {
	local myconf=(
		--with-modules-dir=/$(get_libdir)/security
	)
	ECONF_SOURCE=${S} \
	econf "${myconf[@]}"
}

multilib_src_install_all() {
	dodoc CREDITS HISTORY RELNOTES README
	find "${D}" -name '*.la' -delete || die
}