summaryrefslogtreecommitdiff
blob: 5a7eba008ee4aa64cbe49737a1e328f8b064dedd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

PYTHON_COMPAT=( python2_7 )

inherit eutils python-r1

DESCRIPTION="GUI to configure, run or daemonize xplanet with HQ capabilities"
HOMEPAGE="http://mein-neues-blog.de/xplanetFX/"
SRC_URI="http://repository.mein-neues-blog.de:9000/archive/${P/FX/fx}_all.tar.gz"

LICENSE="WTFPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="libnotify"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

DEPEND="${PYTHON_DEPS}"
RDEPEND="${DEPEND}
	dev-python/pygtk[${PYTHON_USEDEP}]
	media-gfx/imagemagick
	sys-devel/bc
	x11-misc/xplanet
	libnotify? ( x11-libs/libnotify )"
#python

S="${WORKDIR}/usr"

src_prepare() {
	default

	eapply "${FILESDIR}"/${PN}-2.6.4-gentoo-path.patch
	sed -e "s/Application;//" -i share/applications/*desktop || die

	# These will be installed separately
	mkdir gentoo || die
	mv share/${PN}/{autostart,flipview.py,stars/catalog.py,xplanetFX_gtk,xplanetFX_tray} \
		gentoo || die
}

src_install() {
	dobin bin/${PN}
	insinto /usr/share/applications
	doins share/applications/${PN}.desktop
	insinto /usr/share/pixmaps
	doins share/pixmaps/*
	insinto /usr/share/${PN}
	doins -r share/${PN}/*

	exeinto /usr/share/${PN}
	doexe gentoo/autostart

	dodoc share/doc/${PN}/{changelog,README}

	python_scriptinto /usr/share/${PN}/stars
	python_foreach_impl python_doscript gentoo/catalog.py
	python_scriptinto /usr/share/${PN}
	python_foreach_impl python_doscript gentoo/{xplanetFX_gtk,xplanetFX_tray}
	python_foreach_impl python_domodule gentoo/flipview.py
}