From 380e8fc9c854b0de68974d66c3f0dc18fc2c383f Mon Sep 17 00:00:00 2001
From: Ulrich Müller <ulm@gentoo.org>
Date: Wed, 7 Apr 2021 17:14:21 +0200
Subject: app-xemacs/ebuild-mode: Initial import
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---
 app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild | 42 ++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild

(limited to 'app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild')

diff --git a/app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild b/app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild
new file mode 100644
index 0000000..ed3a18b
--- /dev/null
+++ b/app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/ebuild-mode.git"
+EGIT_BRANCH="master"
+EGIT_CHECKOUT_DIR="${WORKDIR}/${PN}"
+
+inherit git-r3
+
+DESCRIPTION="Emacs modes for editing ebuilds and other Gentoo specific files"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+RDEPEND=">=app-editors/xemacs-21.4.20-r5
+	app-xemacs/sh-script"
+BDEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	local XEMACS="${EPREFIX}/usr/bin/xemacs"
+
+	"${XEMACS}" -batch -q --no-site-file \
+		-eval "(add-to-list 'load-path \".\")" \
+		-f batch-byte-compile \
+		ebuild-mode.el gentoo-newsitem-mode.el || die
+
+	"${XEMACS}" -batch -q --no-site-file \
+		-eval "(setq autoload-package-name \"${PN}\")" \
+		-eval "(setq generated-autoload-file \"${S}/auto-autoloads.el\")" \
+		-l autoload -f batch-update-autoloads \
+		ebuild-mode.el gentoo-newsitem-mode.el || die
+}
+
+src_install() {
+	insinto /usr/share/xemacs/site-packages/lisp/${PN}
+	doins *.el *.elc
+}
-- 
cgit v1.2.3-65-gdbad