app-editors/uemacs-lt/uemacs-lt-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
EGIT_REPO_URI="git://git.kernel.org/pub/scm/editors/uemacs/uemacs.git"

inherit git-2 toolchain-funcs

DESCRIPTION="Linus Torvalds' Microemacs, a fork of uEmacs/PK"
HOMEPAGE="http://git.kernel.org/?p=editors/uemacs/uemacs.git;a=summary"
SRC_URI=""

LICENSE="free-noncomm"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="sys-libs/ncurses"
RDEPEND="${DEPEND}"

src_prepare() {
	sed -i -e "s:/usr/lib/:/usr/share/${PN}/:" epath.h || die
	# Respect LDFLAGS when linking
	sed -i -e 's/\(\$(CC) \$(DEFINES)\) \(-o \$@\)/\1 $(LDFLAGS) \2/' \
		Makefile || die
}

src_compile() {
	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
}

src_install() {
	dobin em
	insinto /usr/share/${PN}
	doins emacs.hlp
	newins emacs.rc .emacsrc
	dodoc README readme.39e emacs.ps UTF-8-demo.txt
}