summaryrefslogtreecommitdiff
blob: 45e361cd14c15efabbd8ba1b1a1fbe4f04387886 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit elisp-common eutils fdo-mime gnome2-utils

DESCRIPTION="Common files needed by all GNU Emacs versions"
HOMEPAGE="http://www.gentoo.org/proj/en/lisp/emacs/"
SRC_URI="mirror://gentoo/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="X"

PDEPEND="virtual/emacs"

pkg_setup() {
	if [ -e "${ROOT}${SITELISP}/subdirs.el" ] \
		&& ! has_version ">=${CATEGORY}/${PN}-1"
	then
		ewarn "Removing orphan subdirs.el (installed by old Emacs ebuilds)"
		rm -f "${ROOT}${SITELISP}/subdirs.el"
	fi
}

src_install() {
	elisp-install . subdirs.el "${FILESDIR}/site-start.el" || die

	echo "CONFIG_PROTECT=\"${SITELISP}/site-start.el\"" >"${T}/50${PN}" || die
	doenvd "${T}/50${PN}" || die

	if use X; then
		local i
		domenu emacs.desktop emacsclient.desktop || die
		newicon emacs_48.png emacs.png || die
		for i in 16 24 32 48; do
			insinto /usr/share/icons/hicolor/${i}x${i}/apps
			newins emacs_${i}.png emacs.png || die
		done
	fi
}

pkg_postinst() {
	local line

	if use X; then
		fdo-mime_desktop_database_update
		gnome2_icon_cache_update
	fi

	# make sure that site-gentoo.el exists since site-start.el requires it
	elisp-site-regen

	echo
	while read line; do elog "${line:- }"; done <<-EOF
	All site initialisation for Gentoo-installed packages is added to
	/usr/share/emacs/site-lisp/site-gentoo.el. In order for this site
	initialisation to be loaded for all users automatically, a default
	site-start.el is created in the same directory. You are responsible
	for all further maintenance of this file.

	Alternatively, individual users can add the following command:

	(require 'site-gentoo)

	to their ~/.emacs initialisation files, or, for greater flexibility,
	users may load single package-specific initialisation files from
	/usr/share/emacs/site-lisp/site-gentoo.d/.
	EOF
	echo
}

pkg_postrm() {
	if use X; then
		fdo-mime_desktop_database_update
		gnome2_icon_cache_update
	fi
}