From 45a6d830fb44980db4f9c03b7285d3a19fde42f5 Mon Sep 17 00:00:00 2001
From: Alice Ferrazzi <alicef@gentoo.org>
Date: Fri, 2 Nov 2018 07:20:57 +0000
Subject: Initial commit of kernel related packages

Signed-off-by: Alice Ferrazzi <alicef@gentoo.org>
---
 sys-kernel/ck-sources/ck-sources-4.9.124.ebuild | 59 +++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 sys-kernel/ck-sources/ck-sources-4.9.124.ebuild

(limited to 'sys-kernel/ck-sources/ck-sources-4.9.124.ebuild')

diff --git a/sys-kernel/ck-sources/ck-sources-4.9.124.ebuild b/sys-kernel/ck-sources/ck-sources-4.9.124.ebuild
new file mode 100644
index 0000000..b4e180d
--- /dev/null
+++ b/sys-kernel/ck-sources/ck-sources-4.9.124.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+ETYPE="sources"
+KEYWORDS="~amd64 ~x86"
+
+HOMEPAGE="https://dev.gentoo.org/~mpagano/genpatches/
+	http://kernel.kolivas.org/"
+
+IUSE="experimental"
+
+K_WANT_GENPATCHES="base extras experimental"
+K_GENPATCHES_VER="128"
+K_SECURITY_UNSUPPORTED="1"
+K_DEBLOB_AVAILABLE="1"
+
+PYTHON_COMPAT=( python2_7 )
+inherit python-any-r1 kernel-2
+detect_version
+detect_arch
+
+DEPEND="deblob? ( ${PYTHON_DEPS} )"
+
+K_BRANCH_ID="${KV_MAJOR}.${KV_MINOR}"
+
+DESCRIPTION="Gentoo's genpatches for Linux ${K_BRANCH_ID}, with Con Kolivas' MuQSS process scheduler."
+
+MUQSS_VERSION="150"
+MUQSS_FILE="${K_BRANCH_ID}-sched-MuQSS_${MUQSS_VERSION}.patch"
+MUQSS_BASE_URL="http://ck.kolivas.org/patches/muqss/4.0"
+
+# clearly identify package name in distrdir
+MUQSS_DISTNAME="${PN}-${K_BRANCH_ID}-muqss.patch"
+
+CK_LVER_URL="${MUQSS_BASE_URL}/${K_BRANCH_ID}"
+CK_URI="${CK_LVER_URL}/${MUQSS_FILE} -> ${MUQSS_DISTNAME}"
+
+# solves bug #606866 (Fix build for CONFIG_FREEZER disabled.x)
+FRZR_HASH="7de569950716147ed436b27936628ee3ab5b45cc"
+FRZR_FILE="${PN}-4.9-freezer-fix.patch"
+FRZR_URI="https://github.com/ckolivas/linux/commit/${FRZR_HASH}.patch -> ${FRZR_FILE}"
+
+SRC_URI="${KERNEL_URI} ${GENPATCHES_URI} ${ARCH_URI} ${CK_URI} ${FRZR_URI}"
+
+UNIPATCH_LIST="${DISTDIR}/${MUQSS_DISTNAME} ${DISTDIR}/${FRZR_FILE}"
+UNIPATCH_STRICTORDER="yes"
+
+pkg_setup() {
+	use deblob && python-any-r1_pkg_setup
+	kernel-2_pkg_setup
+}
+
+pkg_postinst() {
+	elog "CPU optimizations patch (from genpatches) is off by default."
+	elog "Set USE=\"experimental\" if you need this patch / feature."
+	elog "This can be set in /etc/portage/package.use (or make.conf)"
+	elog "make menuconfig as usual to edit .config for this feature."
+}
-- 
cgit v1.2.3-65-gdbad