Merge updates from master

14 files changed, 559 insertions, 14 deletions

diff --git a/dev-libs/libclc/libclc-16.0.0.9999.ebuild b/dev-libs/libclc/libclc-16.0.0.9999.ebuild
index 4ec05a0a963c..535092cda010 100644
--- a/dev-libs/libclc/libclc-16.0.0.9999.ebuild
+++ b/dev-libs/libclc/libclc-16.0.0.9999.ebuild
@@ -16,10 +16,11 @@ IUSE_VIDEO_CARDS="video_cards_nvidia video_cards_r600 video_cards_radeonsi"
 IUSE="${IUSE_VIDEO_CARDS}"
 REQUIRED_USE="|| ( ${IUSE_VIDEO_CARDS} )"
 
-LLVM_MAX_SLOT=15
+LLVM_MAX_SLOT=16
 BDEPEND="
 	${PYTHON_DEPS}
 	|| (
+		sys-devel/clang:16
 		sys-devel/clang:15
 		sys-devel/clang:14
 		sys-devel/clang:13
diff --git a/dev-python/pypy/metadata.xml b/dev-python/pypy/metadata.xml
index efd7c8c21836..786955f8b2f0 100644
--- a/dev-python/pypy/metadata.xml
+++ b/dev-python/pypy/metadata.xml
@@ -5,4 +5,13 @@
 		<email>python@gentoo.org</email>
 		<name>Python</name>
 	</maintainer>
+	<use>
+		<flag name="full-stdlib">
+			Install complete stdlib as necessary to use PyPy for general
+			purpose programs.  By default, only a limited subset that is
+			used when building <pkg>dev-python/pypy3-exe</pkg> is
+			installed.  Note that PyPy2.7's stdlib contains multiple
+			known vulnerabilities.
+		</flag>
+	</use>
 </pkgmetadata>
diff --git a/dev-python/pypy/pypy-7.3.9-r1.ebuild b/dev-python/pypy/pypy-7.3.9-r1.ebuild
new file mode 100644
index 000000000000..ae8f4222bb0c
--- /dev/null
+++ b/dev-python/pypy/pypy-7.3.9-r1.ebuild
@@ -0,0 +1,300 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pax-utils python-utils-r1
+
+PYPY_PV=${PV%_p*}
+MY_P=pypy2.7-v${PYPY_PV/_}
+PATCHSET="pypy2.7-gentoo-patches-${PV/_rc/rc}"
+
+DESCRIPTION="A fast, compliant alternative implementation of the Python language"
+HOMEPAGE="https://www.pypy.org/"
+SRC_URI="
+	https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
+"
+S="${WORKDIR}/${MY_P}-src"
+
+LICENSE="MIT"
+# pypy -c 'import sysconfig; print sysconfig.get_config_var("SOABI")'
+SLOT="0/73"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="bzip2 full-stdlib gdbm +jit ncurses sqlite tk"
+
+RDEPEND="
+	|| (
+		>=dev-python/pypy-exe-${PYPY_PV}:${PYPY_PV}[bzip2?,ncurses?]
+		>=dev-python/pypy-exe-bin-${PYPY_PV}:${PYPY_PV}
+	)
+	dev-libs/openssl:0=
+	gdbm? ( sys-libs/gdbm:0= )
+	sqlite? ( dev-db/sqlite:3= )
+	tk? (
+		dev-lang/tk:0=
+		dev-tcltk/tix:0=
+	)
+	!<dev-python/pypy-bin-7.3.0:0
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+	default
+}
+
+src_compile() {
+	# copy over to make sys.prefix happy
+	cp -p "${BROOT}"/usr/lib/pypy2.7/pypy-c-${PYPY_PV} pypy-c || die
+	cp -p "${BROOT}"/usr/lib/pypy2.7/include/${PYPY_PV}/* include/ || die
+	# (not installed by pypy)
+	rm pypy/module/cpyext/include/_numpypy/numpy/README || die
+	mv pypy/module/cpyext/include/* include/ || die
+	mv pypy/module/cpyext/parse/*.h include/ || die
+	pax-mark m pypy-c
+
+	# verify the subslot
+	local soabi=$(
+		./pypy-c - <<-EOF
+			import sysconfig
+			print sysconfig.get_config_var("SOABI")
+		EOF
+	)
+	[[ ${soabi#pypy-} == ${SLOT#*/} ]] || die "update subslot to ${soabi}"
+
+	einfo "Generating caches and CFFI modules ..."
+
+	if use full-stdlib; then
+		# Generate Grammar and PatternGrammar pickles.
+		./pypy-c - <<-EOF || die "Generation of Grammar and PatternGrammar pickles failed"
+			import lib2to3.pygram
+			import lib2to3.patcomp
+			lib2to3.patcomp.PatternCompiler()
+		EOF
+
+		# Generate cffi modules
+		# Please keep in sync with pypy/tool/build_cffi_imports.py!
+		cffi_targets=( pypy_util ssl audioop syslog pwdgrp resource )
+		use gdbm && cffi_targets+=( gdbm )
+		use ncurses && cffi_targets+=( curses )
+		use sqlite && cffi_targets+=( sqlite3 )
+		use tk && cffi_targets+=( tkinter/tklib )
+
+		local t
+		# all modules except tkinter output to .
+		# tkinter outputs to the correct dir ...
+		cd lib_pypy || die
+		for t in "${cffi_targets[@]}"; do
+			# tkinter doesn't work via -m
+			../pypy-c "_${t}_build.py" || die "Failed to build CFFI bindings for ${t}"
+		done
+
+		# Verify that CFFI module list is up-to-date
+		local expected_cksum=2d3acf18
+		local local_cksum=$(
+			../pypy-c - <<-EOF
+				import binascii
+				import json
+				from pypy_tools.build_cffi_imports import cffi_build_scripts as x
+				print("%08x" % (binascii.crc32(json.dumps(x)),))
+			EOF
+		)
+		if [[ ${local_cksum} != ${expected_cksum} ]]; then
+			die "Please verify cffi_targets and update checksum to ${local_cksum}"
+		fi
+
+		# Cleanup temporary objects
+		find -name "_cffi_*.[co]" -delete || die
+		find -type d -empty -delete || die
+	fi
+}
+
+src_test() {
+	# (unset)
+	local -x PYTHONDONTWRITEBYTECODE=
+	local -x COLUMNS=80
+
+	local ignored_tests=(
+		# network
+		--ignore=lib-python/2.7/test/test_urllibnet.py
+		--ignore=lib-python/2.7/test/test_urllib2net.py
+		# lots of free space
+		--ignore=lib-python/2.7/test/test_zipfile64.py
+
+		# broken by expat-2.4.5
+		--ignore=lib-python/2.7/test/test_minidom.py
+		--ignore=lib-python/2.7/test/test_xml_etree.py
+		--ignore=lib-python/2.7/test/test_xml_etree_c.py
+	)
+
+	./pypy-c ./pypy/test_all.py --pypy=./pypy-c -vv \
+		"${ignored_tests[@]}" lib-python || die
+}
+
+src_install() {
+	local dest=/usr/lib/pypy2.7
+	einfo "Installing PyPy ..."
+	dosym pypy-c-${PYPY_PV} "${dest}/pypy-c"
+	insinto "${dest}"
+	# preserve mtimes to avoid obsoleting caches
+	insopts -p
+	if use full-stdlib; then
+		doins -r include lib_pypy lib-python
+
+		# replace copied headers with symlinks
+		for x in "${BROOT}"/usr/lib/pypy2.7/include/${PYPY_PV}/*; do
+			dosym "${PYPY_PV}/${x##*/}" "${dest}/include/${x##*/}"
+		done
+
+		if ! use gdbm; then
+			rm -r "${ED}${dest}"/lib_pypy/gdbm.py \
+				"${ED}${dest}"/lib-python/*2.7/test/test_gdbm.py || die
+		fi
+		if ! use sqlite; then
+			rm -r "${ED}${dest}"/lib-python/*2.7/sqlite3 \
+				"${ED}${dest}"/lib_pypy/_sqlite3.py \
+				"${ED}${dest}"/lib-python/*2.7/test/test_sqlite.py || die
+		fi
+		if ! use tk; then
+			rm -r "${ED}${dest}"/lib-python/*2.7/{idlelib,lib-tk} \
+				"${ED}${dest}"/lib_pypy/_tkinter \
+				"${ED}${dest}"/lib-python/*2.7/test/test_{tcl,tk,ttk*}.py || die
+		fi
+	else
+		# install only the absolutely minimal subset of modules needed
+		# for pypy3 build
+		local lib_py_modules=(
+			# base modules needed to even start pypy (and import site)
+			codecs.py
+			copy_reg.py
+			encodings
+			genericpath.py
+			linecache.py
+			os.py
+			pkgutil.py
+			posixpath.py
+			re.py
+			runpy.py
+			site.py
+			sre_compile.py
+			sre_constants.py
+			sre_parse.py
+			stat.py
+			string.py
+			sysconfig.py
+			traceback.py
+			warnings.py
+			UserDict.py
+
+			# needed for python_optimize
+			compileall.py
+			getopt.py
+			py_compile.py
+			struct.py
+
+			# needed for rpython
+			argparse.py
+			atexit.py
+			base64.py
+			bdb.py
+			bisect.py
+			cmd.py
+			code.py
+			codeop.py
+			collections.py
+			colorsys.py
+			contextlib.py
+			copy.py
+			ctypes
+			dis.py
+			fnmatch.py
+			functools.py
+			gettext.py
+			hashlib.py
+			heapq.py
+			inspect.py
+			io.py
+			json
+			keyword.py
+			locale.py
+			logging
+			opcode.py
+			optparse.py
+			pdb.py
+			pickle.py
+			platform.py
+			pprint.py
+			random.py
+			repr.py
+			shlex.py
+			shutil.py
+			StringIO.py
+			subprocess.py
+			tempfile.py
+			textwrap.py
+			threading.py
+			tokenize.py
+			weakref.py
+			zipfile.py
+		)
+
+		local distutils_modules=(
+			# needed by site
+			__init__.py
+			errors.py
+			sysconfig.py
+			sysconfig_cpython.py
+			sysconfig_pypy.py
+		)
+
+		local lib_pypy_modules=(
+			# needed by site
+			_sysconfigdata.py
+
+			# needed by rpython
+			cffi
+			_ctypes
+			_ffi.py
+			_functools.py
+			_sha.py
+			_sha256.py
+			_sha512.py
+
+			# NB: we're deliberately skipping _hashlib to avoid some deps
+		)
+
+		cd lib-python/2.7 || die
+		insinto "${dest}/lib-python/2.7"
+		doins -r "${lib_py_modules[@]}"
+		cd - >/dev/null || die
+
+		cd lib-python/2.7/distutils || die
+		insinto "${dest}/lib-python/2.7/distutils"
+		doins -r "${distutils_modules[@]}"
+		cd - >/dev/null || die
+
+		cd lib_pypy || die
+		insinto "${dest}/lib_pypy"
+		doins -r "${lib_pypy_modules[@]}"
+		cd - >/dev/null || die
+	fi
+
+	dosym ../lib/pypy2.7/pypy-c /usr/bin/pypy
+	dodoc README.rst
+
+	local -x EPYTHON=pypy
+	local -x PYTHON=${ED}${dest}/pypy-c-${PYPY_PV}
+	# temporarily copy to build tree to facilitate module builds
+	cp -p "${BROOT}${dest}/pypy-c-${PYPY_PV}" "${PYTHON}" || die
+
+	einfo "Byte-compiling Python standard library..."
+	python_optimize "${ED}${dest}"
+
+	# remove to avoid collisions
+	rm "${PYTHON}" || die
+}
diff --git a/games-engines/stratagus/Manifest b/games-engines/stratagus/Manifest
index 2fa9105007a0..ed22436e14df 100644
--- a/games-engines/stratagus/Manifest
+++ b/games-engines/stratagus/Manifest
@@ -1,3 +1,4 @@
 DIST stratagus-3.2.0.tar.gz 1537172 BLAKE2B cd0ce92a1532cdf57245f6ef234ee1f55418f28f06bb34f358bd623b1e83d21b9a04cfa86e8129931043e480de5a9de0ef6458b75dcb2f8c40c3457d4ef31eef SHA512 7a1b4f99fa3a080905b976439435c62fa885c0895f3f9f7692404a207822520d6b71189f24627c31bec192503d6504bf98485cce393036950f6bac0a49cb17dc
 DIST stratagus-3.3.0.tar.gz 1582643 BLAKE2B 7307ac59dc4ff112f0be8f85165eb14e61b83cbd7fa2e1a58599e1422b025c42cb2527bbb08d3231a45b07b116712f020605b6ec0f79d3696acda8577e3c1e24 SHA512 9510bd85f8dff284d912b68e377041345cf141af32f98298cbd712f932cff88cbf91733f97396b1d0e9671eafddc36897383bc3f39c1497a65d270432dab0876
 DIST stratagus-3.3.1.tar.gz 1582605 BLAKE2B 375769346276c034efdef5fcb7282b89a33fd26266c1d8d56b78dfe33ad301ad85c113eedc7f23c79182da225bf6a4dc07704113f118e35e78db2502d291f466 SHA512 7ee3d31db6f30d1e927a87dd788c035b5cf69b44c914556412d18eb66bdfa252bd905bc341a3fd4c5100466b30e216a05fb678ecde690945a7fe0b1992c6b4f4
+DIST stratagus-3.3.2.tar.gz 1582937 BLAKE2B c39a9f009693c8c6dc7e62b885851a707a25c039b66765ce42dbd851643650b287bd45d0c0ea6fb03a2ddde01a41bf156a1d018ad4f06e0d39e9435a24c79672 SHA512 0e5d0127ba4e1025ceb7f46c91d90b82dc7c1b194030738abf95bd2c9cadc04d7431f333a514fc6d6b300ea3a1f5c7405bea735471f72fa547031634a23b01d1
diff --git a/games-engines/stratagus/stratagus-3.3.2.ebuild b/games-engines/stratagus/stratagus-3.3.2.ebuild
new file mode 100644
index 000000000000..c6eac6df2815
--- /dev/null
+++ b/games-engines/stratagus/stratagus-3.3.2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 )
+inherit cmake lua-single optfeature
+
+DESCRIPTION="A realtime strategy game engine"
+HOMEPAGE="
+	https://stratagus.com/stratagus.html
+	https://github.com/Wargus/stratagus/
+"
+SRC_URI="
+	https://github.com/Wargus/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0/3"
+KEYWORDS="~amd64 ~x86"
+IUSE="bzip2 debug doc mng theora vorbis"
+REQUIRED_USE="
+	${LUA_REQUIRED_USE}
+	theora? ( vorbis )
+"
+
+DEPEND="
+	${LUA_DEPS}
+	dev-db/sqlite:3
+	dev-lua/toluapp[${LUA_SINGLE_USEDEP}]
+	media-libs/libpng:0
+	x11-libs/libX11
+	media-libs/libsdl2[sound,opengl,video]
+	media-libs/sdl2-mixer[vorbis]
+	media-libs/sdl2-image[png]
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	mng? ( media-libs/libmng )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+		theora? ( media-libs/libtheora )
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}"-2.3.0-doc.patch
+)
+
+src_prepare() {
+	sed -i -e 's:-Werror::' CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	# there are in-source switches
+	use debug && CMAKE_BUILD_TYPE=Debug
+
+	local mycmakeargs=(
+		-DGAMEDIR="${EPREFIX}/usr/bin"
+		-DDOCDIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DWITH_BZIP2=$(usex bzip2)
+		-DWITH_MNG=$(usex mng)
+		-DWITH_OGGVORBIS=$(usex vorbis)
+		-DWITH_THEORA=$(usex theora)
+		-DENABLE_DOC=$(usex doc)
+		-DENABLE_DEV=ON
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	optfeature "MIDI music support" "media-libs/sdl2-mixer[midi]"
+}
diff --git a/games-strategy/war1gus/Manifest b/games-strategy/war1gus/Manifest
index bd71fbe515d7..959973a17810 100644
--- a/games-strategy/war1gus/Manifest
+++ b/games-strategy/war1gus/Manifest
@@ -1,3 +1,4 @@
 DIST war1gus-3.2.0.tar.gz 408417 BLAKE2B 8369d380813aa6a5c7484e7b668284ee3b59bd4a914b82b074640344af977c08727260efc284a5ffc7d5c52ef7ae0ab45b484d87d855a088198b02adf5240bac SHA512 2e3509792509730254e9292dce66491e848980a37171281dcd851aaa0662a3dd8911444d97c25486acb61fa5ad913da3bb397ddd599cd7ea1293b0afbfc88bc6
 DIST war1gus-3.3.0.tar.gz 486274 BLAKE2B 90675ce44cab26079c53ebd70377ea24bef3894d1f194f45496a0df6528e1bb63184f3c93f843ab9176ad02c542a9e51fbfa9f4af3bce6018fa7085d31494998 SHA512 9e17101954f7e953ba11cebd2f62eb9e3465217897bd55699846d6290fa5d249574d144f271e08485bc38ef7dd63e5efa05437faa5191148d1ea9341157834ea
 DIST war1gus-3.3.1.tar.gz 486322 BLAKE2B cdf3db536c6cae2327ba044da13f2743c299481503723d00fbfeb8103932a0065afb0771f1719264fa7ed298b876f2189bc9c1def2b4fcc6c1b4a45992d0d322 SHA512 947592a220aeae99840abc88c5086d681afb72971f25f3e42c475d416529bb0341ca409aa5459e049d1dbe4b937cf25c29c6445958c5c61e26a67c4a4dd7ccb0
+DIST war1gus-3.3.2.tar.gz 486326 BLAKE2B 2ea0506bc2dabf8a1a58f52fe3bb0b110f07100b6f6ade29f2273f7718c8ef8572c642e6fba5005894383100190f3b649faa1b06286f11d4b7718cb59833eeb4 SHA512 e4c0b297cf215618edf007d2b1584f7d812607a33587b5254e1620dff6aa7a282b67b464b39eed11cd7405cae34d11f1587f42893b2ccf4ca531dc4c37375d74
diff --git a/games-strategy/war1gus/war1gus-3.3.2.ebuild b/games-strategy/war1gus/war1gus-3.3.2.ebuild
new file mode 100644
index 000000000000..d61b049b1854
--- /dev/null
+++ b/games-strategy/war1gus/war1gus-3.3.2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="Warcraft: Orcs & Humans for the Stratagus game engine"
+HOMEPAGE="
+	https://stratagus.com/war1gus.html
+	https://github.com/Wargus/war1gus/
+"
+SRC_URI="
+	https://github.com/Wargus/war1gus/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	=games-engines/stratagus-${PV}*[theora]
+	media-libs/libpng:0=
+	sys-libs/zlib:=
+	x11-libs/gtk+:2
+	x11-libs/libX11
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DGAMEDIR="${EPREFIX}/usr/bin"
+		-DBINDIR="${EPREFIX}/usr/bin"
+		-DSTRATAGUS="${EPREFIX}/usr/bin/stratagus"
+		-DSHAREDIR="${EPREFIX}/usr/share/stratagus/war1gus"
+		-DICONDIR=/usr/share/icons/hicolor/64x64/apps
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "War1gus requires the data from the original game to run.  The game"
+	elog "will ask you for the location of the game data and extract/convert"
+	elog "it automatically on the first run."
+
+	if ! has_version media-video/ffmpeg ||
+		! has_version media-sound/timidity++
+	then
+		elog
+		elog "If you did not convert the game data yet, you may want to install"
+		elog "the following optional dependencies:"
+		elog
+		elog "media-video/ffmpeg -- to convert game videos"
+		elog "media-sound/timidity++ -- to convert game music"
+	fi
+
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/games-strategy/wargus/Manifest b/games-strategy/wargus/Manifest
index 256fed47430f..d6a3a56c6eaf 100644
--- a/games-strategy/wargus/Manifest
+++ b/games-strategy/wargus/Manifest
@@ -1,3 +1,4 @@
 DIST wargus-3.2.0.tar.gz 5062175 BLAKE2B e742c2dae21aa5a8a05ef8a4cefc7d1245707d401aa9e14dfc633aeac0e4e4e54459c0ce07cbd32aed842c3dcf57ea8df39fcfc34a9316211146a61ce71464dc SHA512 bc85304c0994abf778cf157d1013d9dea18e1d761a3b432018641211824bcdb2e424c938842848d8c7a670d8660289b5860342a99be7af259cf8eaf883af1285
 DIST wargus-3.3.0.tar.gz 5094634 BLAKE2B aa0b02d62dc8620ba9517e5c7d1e8193f2c4c0e20b9b96b91cd5aa57fefdfda7354c82d67507aea67704adc7c77d90b858f0f3fb78d2a1bf430b5c4c5251f432 SHA512 3a2bd04aed0ced18a11ab925ca3d4da98f8848b45a0716fe5164ee5e0f9c76a63d7783d9ba94f3de022622e841f0257cb59d507ea772b2cc42419cef01ea8cbc
 DIST wargus-3.3.1.tar.gz 5094251 BLAKE2B b5f3674db93a8973f166e6dd0dcd9adeee330aa3932b97218b10e3540f5bc6123c977f45463d77c1cf6cc8d5dcadf39d799551311e9a891ec91200e668febcd8 SHA512 33a642d87a9a0d407fd8591fbb19d5357b5d7ae2fa3319512776feb0b6dbdc4d403e82de907235a9614302b5b0af466da37af21f7f4093715d39fe7e7da30468
+DIST wargus-3.3.2.tar.gz 5110092 BLAKE2B bbde0931307f7a182086e898ff87e8d559ad0f239b04a019359a30fbca20b82745d598571d8d42353952aade4b96ded3de8e06b92dc947c7a7d9aee00c315c71 SHA512 111d7bc0889f86356226478834d515912b1221a131aa405acf75cbdd16cda4e83c4e900ea30e86c162301504a617755284a9656d6709aaa7ab2baf8f8591dcf8
diff --git a/games-strategy/wargus/wargus-3.3.2.ebuild b/games-strategy/wargus/wargus-3.3.2.ebuild
new file mode 100644
index 000000000000..fff6023fa177
--- /dev/null
+++ b/games-strategy/wargus/wargus-3.3.2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="Warcraft II for the Stratagus game engine"
+HOMEPAGE="
+	https://stratagus.com/
+	https://github.com/Wargus/wargus/
+"
+SRC_URI="
+	https://github.com/Wargus/wargus/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+bne"
+
+DEPEND="
+	=games-engines/stratagus-${PV}*[theora]
+	media-libs/libpng:0=
+	sys-libs/zlib:=
+	x11-libs/gtk+:2
+	x11-libs/libX11
+	bne? ( app-arch/stormlib:= )
+	!games-strategy/wargus-data
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+pkg_pretend() {
+	if has_version games-strategy/wargus-data; then
+		ewarn "The system-wide install of game data via games-strategy/wargus-data"
+		ewarn "no longer works.  The old data will be uninstalled after merging"
+		ewarn "this version of Wargus.  If you would like to preserve it, please"
+		ewarn "abort the process and back /usr/share/stratagus/wargus up."
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DGAMEDIR="${EPREFIX}/usr/bin"
+		-DBINDIR="${EPREFIX}/usr/bin"
+		-DSTRATAGUS="${EPREFIX}/usr/bin/stratagus"
+		-DSHAREDIR="${EPREFIX}/usr/share/stratagus/wargus"
+		-DICONDIR=/usr/share/icons/hicolor/64x64/apps
+		-DWITH_STORMLIB=$(usex bne)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "Wargus requires the data from the original game to run.  The game"
+	elog "will ask you for the location of the game data and extract/convert"
+	elog "it automatically on the first run."
+
+	if ! has_version media-video/ffmpeg ||
+		! has_version media-sound/cdparanoia
+	then
+		elog
+		elog "If you did not convert the game data yet, you may want to install"
+		elog "the following optional dependencies:"
+		elog
+		elog "media-video/ffmpeg -- to convert game videos"
+		elog "media-sound/cdparanoia -- to rip game music from the CD"
+	fi
+
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/net-im/discord-bin/Manifest b/net-im/discord-bin/Manifest
index 7db891be33a3..c161a9d4c0c6 100644
--- a/net-im/discord-bin/Manifest
+++ b/net-im/discord-bin/Manifest
@@ -1 +1 @@
-DIST discord-0.0.18.tar.gz 77398558 BLAKE2B e25ad448dd9f89e460a4380cde850506298a443be2b70fb243b92ab6a139815fea36260b879ece044c5c607561fde6adf36a188c186c48c34052ec105b23d732 SHA512 a9c5de48186542fa4385c5cf4ffb54484dee008cde5230a9f8a0e71a84e1e7ce680e170aca2018ad2217618ed2d4a4882836a408a5d0a5cab054c0954c1b55be
+DIST discord-0.0.19.tar.gz 77400663 BLAKE2B 2bfbc32739d7af69f437a54fe75140451cdac68453d8554ccf76b1e12e7118b163465742c8c4e8743d4c7de4e493fcbd313c7cff316514b78e8b7288d5fe3a8c SHA512 5b73f0f968ce61f5a844940e1525da80e7b2ce3779cf2050ca3c2b0b7dbee20f16e2bf203f0673d1e275d1e55075b83eb63700731be8324587b3c58c64d3a0e8
diff --git a/net-im/discord-bin/discord-bin-0.0.18.ebuild b/net-im/discord-bin/discord-bin-0.0.19.ebuild
index 7a89768866bb..7a89768866bb 100644
--- a/net-im/discord-bin/discord-bin-0.0.18.ebuild
+++ b/net-im/discord-bin/discord-bin-0.0.19.ebuild
diff --git a/sys-devel/binutils/binutils-2.38-r2.ebuild b/sys-devel/binutils/binutils-2.38-r2.ebuild
index 71cc495774c1..b4b21afc9d21 100644
--- a/sys-devel/binutils/binutils-2.38-r2.ebuild
+++ b/sys-devel/binutils/binutils-2.38-r2.ebuild
@@ -312,7 +312,7 @@ src_compile() {
 		emake V=1 info
 	fi
 
-	use emacs && elisp-compile "${S}"/binutils/dwarf-mode.el
+	! is_cross && use emacs && elisp-compile "${S}"/binutils/dwarf-mode.el
 
 	# we nuke the manpages when we're left with junk
 	# (like when we bootstrap, no perl -> no manpages)
@@ -406,7 +406,7 @@ src_install() {
 		dodoc opcodes/ChangeLog*
 	fi
 
-	if use emacs ; then
+	if ! is_cross && use emacs ; then
 		elisp-install ${PN} "${S}"/binutils/dwarf-mode.el{,c}
 		elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
 	fi
@@ -423,7 +423,7 @@ pkg_postinst() {
 	[[ -e ${EROOT}/etc/env.d/binutils/config-${CTARGET} ]] && return 0
 	binutils-config ${CTARGET}-${PV}
 
-	use emacs && elisp-site-regen
+	! is_cross && use emacs && elisp-site-regen
 }
 
 pkg_postrm() {
@@ -448,7 +448,7 @@ pkg_postrm() {
 		binutils-config ${CTARGET}-${PV}
 	fi
 
-	use emacs && elisp-site-regen
+	! is_cross && use emacs && elisp-site-regen
 }
 
 # Note [slotting support]
diff --git a/sys-devel/binutils/binutils-2.39.ebuild b/sys-devel/binutils/binutils-2.39.ebuild
index 3cc9c5cdcc87..22183040ab35 100644
--- a/sys-devel/binutils/binutils-2.39.ebuild
+++ b/sys-devel/binutils/binutils-2.39.ebuild
@@ -317,7 +317,7 @@ src_compile() {
 		emake V=1 info
 	fi
 
-	use emacs && elisp-compile "${S}"/binutils/dwarf-mode.el
+	! is_cross && use emacs && elisp-compile "${S}"/binutils/dwarf-mode.el
 
 	# we nuke the manpages when we're left with junk
 	# (like when we bootstrap, no perl -> no manpages)
@@ -420,7 +420,7 @@ src_install() {
 		dodoc opcodes/ChangeLog*
 	fi
 
-	if use emacs ; then
+	if ! is_cross && use emacs ; then
 		elisp-install ${PN} "${S}"/binutils/dwarf-mode.el{,c}
 		elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
 	fi
@@ -437,7 +437,7 @@ pkg_postinst() {
 	[[ -e ${EROOT}/etc/env.d/binutils/config-${CTARGET} ]] && return 0
 	binutils-config ${CTARGET}-${PV}
 
-	use emacs && elisp-site-regen
+	! is_cross && use emacs && elisp-site-regen
 }
 
 pkg_postrm() {
@@ -462,7 +462,7 @@ pkg_postrm() {
 		binutils-config ${CTARGET}-${PV}
 	fi
 
-	use emacs && elisp-site-regen
+	! is_cross && use emacs && elisp-site-regen
 }
 
 # Note [slotting support]
diff --git a/sys-devel/binutils/binutils-9999.ebuild b/sys-devel/binutils/binutils-9999.ebuild
index c3d9de773f3a..c2ab796642a4 100644
--- a/sys-devel/binutils/binutils-9999.ebuild
+++ b/sys-devel/binutils/binutils-9999.ebuild
@@ -316,7 +316,7 @@ src_compile() {
 		emake V=1 info
 	fi
 
-	use emacs && elisp-compile "${S}"/binutils/dwarf-mode.el
+	! is_cross && use emacs && elisp-compile "${S}"/binutils/dwarf-mode.el
 
 	# we nuke the manpages when we're left with junk
 	# (like when we bootstrap, no perl -> no manpages)
@@ -419,7 +419,7 @@ src_install() {
 		dodoc opcodes/ChangeLog*
 	fi
 
-	if use emacs ; then
+	if ! is_cross && use emacs ; then
 		elisp-install ${PN} "${S}"/binutils/dwarf-mode.el{,c}
 		elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
 	fi
@@ -436,7 +436,7 @@ pkg_postinst() {
 	[[ -e ${EROOT}/etc/env.d/binutils/config-${CTARGET} ]] && return 0
 	binutils-config ${CTARGET}-${PV}
 
-	use emacs && elisp-site-regen
+	! is_cross && use emacs && elisp-site-regen
 }
 
 pkg_postrm() {
@@ -461,7 +461,7 @@ pkg_postrm() {
 		binutils-config ${CTARGET}-${PV}
 	fi
 
-	use emacs && elisp-site-regen
+	! is_cross && use emacs && elisp-site-regen
 }
 
 # Note [slotting support]