kde-misc/kdiff3: Drop USE=debug,handbook,kde,qt4

kde-frameworks/kdelibs is deprecated and going to be removed.
Plasma users are served well by the kf5-based snapshot, everyone else
probably does not care about USE=kde in this version of kdiff3 anymore.

- Remove obsolete REQUIRED_USE
- Bump to EAPI 6
- Drop kde4-base.eclass
- sed in place and add missing || die

KDE_LINGUAS and USE=handbook only ever worked with USE=kde enabled.
The remaining bits and pieces install exactly as USE=-kde did before.

Gentoo-bug: 629018
Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 18 insertions, 71 deletions

diff --git a/kde-misc/kdiff3/kdiff3-0.9.98-r1.ebuild b/kde-misc/kdiff3/kdiff3-0.9.98-r1.ebuild
index 56c3427c41e3..3490fd344f06 100644
--- a/kde-misc/kdiff3/kdiff3-0.9.98-r1.ebuild
+++ b/kde-misc/kdiff3/kdiff3-0.9.98-r1.ebuild
@@ -1,101 +1,48 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 
-if [[ ${PV} != *9999* ]]; then
-	KDE_LINGUAS="ar bg br bs ca ca@valencia cs cy da de el en_GB eo es et fr ga
-	gl hi hne hr hu is it ja ka lt mai ml nb nds nl nn pl pt pt_BR ro ru rw sk
-	sv ta tg tr ug uk zh_CN zh_TW"
-	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
-	KEYWORDS="amd64 x86 ~amd64-linux"
-	KDE_HANDBOOK="optional"
-else
-	KEYWORDS=""
-fi
-
-KDE_REQUIRED="optional"
-inherit kde4-base qmake-utils
+inherit qmake-utils
 
 DESCRIPTION="Qt/KDE based frontend to diff3"
 HOMEPAGE="http://kdiff3.sourceforge.net/"
-EGIT_REPO_URI=( "git://git.code.sf.net/p/kdiff3/code" )
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="4"
-IUSE="debug kde +qt4 qt5"
-
-REQUIRED_USE="kde? ( qt4 )
-	^^ ( qt4 qt5 )"
+KEYWORDS="amd64 x86 ~amd64-linux"
+IUSE="qt5"
 
-CDEPEND="
-	qt4? ( dev-qt/qtcore:4
+DEPEND="
+	!qt5? ( dev-qt/qtcore:4
 		dev-qt/qtgui:4 )
 	qt5? ( dev-qt/qtcore:5
 		dev-qt/qtgui:5
 		dev-qt/qtprintsupport:5
 		dev-qt/qtwidgets:5 )
-	kde? ( kde-frameworks/kdelibs:4 )
-"
-DEPEND="${CDEPEND}
-	sys-devel/gettext
 "
-RDEPEND="${CDEPEND}
+RDEPEND="${DEPEND}
 	sys-apps/diffutils
 "
 
-RESTRICT="!kde? ( test )"
-
-PATCHES=( "${FILESDIR}/${P}-kdelibs-4.14.11.patch" )
-
-src_unpack(){
-	if [[ ${PV} == *9999* ]]; then
-		git-r3_src_unpack
-		mv "${S}"/${PN}/* "${S}" || die
-	else
-		default
-	fi
-}
+RESTRICT="test"
 
 src_prepare() {
-	if ! use kde; then
-		# adapt to Gentoo paths
-		sed -e s,documentation.path.*$,documentation.path\ =\ "${EPREFIX}"/usr/share/doc/"${PF}", \
-		-e s,target.path.*$,target.path\ =\ "${EPREFIX}"/usr/bin, \
-		"${S}"/src-QT4/kdiff3.pro > "${S}"/src-QT4/kdiff3_fixed.pro
-	else
-		kde4-base_src_prepare
-	fi
+	default
+	# adapt to Gentoo paths
+	sed -e s,documentation.path.*$,documentation.path\ =\ "${EPREFIX}"/usr/share/doc/"${PF}", \
+		-e s,target.path.*$,target.path\ =\ "${EPREFIX}"/usr/bin, -i src-QT4/kdiff3.pro || die
 }
 
 src_configure() {
-	if use kde; then
-		kde4-base_src_configure
-	elif use qt4; then
-		eqmake4 "${S}"/src-QT4/kdiff3_fixed.pro
+	if ! use qt5; then
+		eqmake4 "${S}"/src-QT4/kdiff3.pro
 	else
-		eqmake5 "${S}"/src-QT4/kdiff3_fixed.pro
-	fi
-}
-
-src_compile() {
-	if use kde; then
-		kde4-base_src_compile
-	else
-		default
+		eqmake5 "${S}"/src-QT4/kdiff3.pro
 	fi
 }
 
 src_install() {
-	if use kde; then
-		kde4-base_src_install
-	else
-		emake INSTALL_ROOT="${D}" install
-	fi
-}
-
-src_test() {
-	if use kde; then
-		kde4-base_src_test
-	fi
+	emake INSTALL_ROOT="${D}" install
 }