Merge updates from master

5 files changed, 191 insertions, 7 deletions

diff --git a/net-irc/irker/files/irkerd.service b/net-irc/irker/files/irkerd.service
new file mode 100644
index 000000000000..232a8d5811a5
--- /dev/null
+++ b/net-irc/irker/files/irkerd.service
@@ -0,0 +1,21 @@
+# Copyright 2012 Wulf C. Krueger <philantrop@exherbo.org>
+# Copyright 2022 Arthur Zamarin <arthurzam@gentoo.org>
+# Distributed under the terms of the BSD LICENSE
+
+[Unit]
+Description=Internet Relay Chat (IRC) notification daemon
+Requires=network.target
+Documentation=man:irkerd(8) man:irkerhook(1) man:irk(1)
+
+[Service]
+ExecStart=@EPREFIX@/usr/bin/irkerd
+User=irker
+DynamicUser=yes
+NoNewPrivileges=yes
+CapabilityBoundingSet=
+PrivateDevices=yes
+ProtectHome=yes
+
+[Install]
+WantedBy=multi-user.target
+Alias=irker.service
diff --git a/net-irc/irker/irker-2.22-r1.ebuild b/net-irc/irker/irker-2.22-r2.ebuild
index e2bf844a14f6..085be79ae727 100644
--- a/net-irc/irker/irker-2.22-r1.ebuild
+++ b/net-irc/irker/irker-2.22-r2.ebuild
@@ -39,12 +39,10 @@ src_prepare() {
 	default
 
 	# Rely on systemd eclass for systemd service install
-	sed -i -e "/^SYSTEMDSYSTEMUNITDIR/d" Makefile \
-		|| die "sed failed"
+	sed -e "/^SYSTEMDSYSTEMUNITDIR/d" -i Makefile || die "sed failed"
 
 	# Prefix support
-	sed -i -e "/^ExecStart=/ s:=/:=${EPREFIX}/:" irkerd.service \
-		|| die "sed failed"
+	sed -e "s|@EPREFIX@|${EPREFIX}|" "${FILESDIR}"/irkerd.service > "${WORKDIR}"/irkerd.service || die "sed failed"
 }
 
 src_install() {
@@ -57,7 +55,7 @@ src_install() {
 	newinitd "${FILESDIR}"/irkerd.initd irkerd
 	newconfd "${FILESDIR}"/irkerd.confd irkerd
 
-	systemd_dounit irkerd.service
+	systemd_dounit "${WORKDIR}"/irkerd.service
 
 	docinto examples
 	dodoc filter-example.py filter-test.py
diff --git a/sys-apps/mawk/mawk-1.3.4_p20200120.ebuild b/sys-apps/mawk/mawk-1.3.4_p20200120.ebuild
index 01feeb83d1ce..94d7dc52ec1a 100644
--- a/sys-apps/mawk/mawk-1.3.4_p20200120.ebuild
+++ b/sys-apps/mawk/mawk-1.3.4_p20200120.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -12,7 +12,7 @@ SRC_URI="https://invisible-mirror.net/archives/${PN}/${MY_P}.tgz"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux"
 
 RDEPEND="app-eselect/eselect-awk"
 DEPEND="${RDEPEND}"
diff --git a/sys-apps/openrc/Manifest b/sys-apps/openrc/Manifest
index 8d4639b0a8ba..9cf5ccd34c33 100644
--- a/sys-apps/openrc/Manifest
+++ b/sys-apps/openrc/Manifest
@@ -1,2 +1,3 @@
 DIST openrc-0.44.10.tar.gz 254298 BLAKE2B 3cfecc27b560b8bb60d2104ab3dcf176b98677b65b829fa403ad2eb0e2e8bb0d586d374c336328a07c2f35e3abcb3f897cf5df142540a60fc09883aabd0ac79d SHA512 0e41f5268c6b8c325a6773511ca58c38ba52a1987aa47165794df8a99359bd1bfcb99d30e0d129b9242a2661663234f6f85c92c55c891dbb6c5b8a11d93edea4
 DIST openrc-0.45.1.tar.gz 246503 BLAKE2B 28ed668b1da7bc3d22de1f7b22b6d10ecd1c789eb5c017803754fa8f6197ee4a7b179728064fa31d4b9dd0d15e3332c4bb839bd56ac5abb39b5b772b53394e8a SHA512 340661c6f8fc60dd7fbbe4a84aaeb0a9a7337577e6d98698c34db3c160890780376587ca6f803563fec53e852593265a28c307fa38a5f71a3e48c62cd63611a1
+DIST openrc-0.45.2.tar.gz 246515 BLAKE2B bb7d52b183612eb8924a2d0f9ec63eea88253d8d83964d6341a4715a6cdc372b3fd99ad0f972f4f539da9d741548777dabf4ced86fd20be741a89a69ffe2ff01 SHA512 ca2958772240f6e5037e39db1ee62a81091a2efa654da967f68e03a721868c6c0a41d32a2bddf55c8eadbc9bf5837b710cc2e4564844a7fbc0e585366da4fdf9
diff --git a/sys-apps/openrc/openrc-0.45.2.ebuild b/sys-apps/openrc/openrc-0.45.2.ebuild
new file mode 100644
index 000000000000..c76771b7efea
--- /dev/null
+++ b/sys-apps/openrc/openrc-0.45.2.ebuild
@@ -0,0 +1,164 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson pam
+
+DESCRIPTION="OpenRC manages the services, startup and shutdown of a host"
+HOMEPAGE="https://github.com/openrc/openrc/"
+
+if [[ ${PV} =~ ^9{4,}$ ]]; then
+	EGIT_REPO_URI="https://github.com/OpenRC/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/OpenRC/openrc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="audit bash debug ncurses pam newnet +netifrc selinux sysv-utils unicode"
+
+COMMON_DEPEND="
+	ncurses? ( sys-libs/ncurses:0= )
+	pam? ( sys-libs/pam )
+	audit? ( sys-process/audit )
+	sys-process/psmisc
+	selinux? (
+		sys-apps/policycoreutils
+		>=sys-libs/libselinux-2.6
+	)"
+DEPEND="${COMMON_DEPEND}
+	virtual/os-headers
+	ncurses? ( virtual/pkgconfig )"
+RDEPEND="${COMMON_DEPEND}
+	bash? ( app-shells/bash )
+	!prefix? (
+		sysv-utils? (
+			!sys-apps/systemd[sysv-utils(-)]
+			!sys-apps/sysvinit
+		)
+		!sysv-utils? ( >=sys-apps/sysvinit-2.86-r6[selinux?] )
+		virtual/tmpfiles
+	)
+	selinux? (
+		>=sec-policy/selinux-base-policy-2.20170204-r4
+		>=sec-policy/selinux-openrc-2.20170204-r4
+	)
+"
+
+PDEPEND="netifrc? ( net-misc/netifrc )"
+
+src_configure() {
+	local emesonargs=(
+	$(meson_feature audit)
+	"-Dbranding=\"Gentoo Linux\""
+		$(meson_use newnet)
+		-Dos=Linux
+		$(meson_use pam)
+		$(meson_feature selinux)
+		-Drootprefix="${EPREFIX}"
+		-Dshell=$(usex bash /bin/bash /bin/sh)
+		$(meson_use sysv-utils sysvinit)
+		-Dtermcap=$(usev ncurses)
+	)
+	# export DEBUG=$(usev debug)
+	meson_src_configure
+}
+
+# set_config <file> <option name> <yes value> <no value> test
+# a value of "#" will just comment out the option
+set_config() {
+	local file="${ED}/$1" var=$2 val com
+	eval "${@:5}" && val=$3 || val=$4
+	[[ ${val} == "#" ]] && com="#" && val='\2'
+	sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
+}
+
+set_config_yes_no() {
+	set_config "$1" "$2" YES NO "${@:3}"
+}
+
+src_install() {
+	meson_install
+
+	keepdir /lib/rc/tmp
+
+	# Setup unicode defaults for silly unicode users
+	set_config_yes_no /etc/rc.conf unicode use unicode
+
+	# Cater to the norm
+	set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'
+
+	# On HPPA, do not run consolefont by default (bug #222889)
+	if use hppa; then
+		rm -f "${ED}"/etc/runlevels/boot/consolefont
+	fi
+
+	# Support for logfile rotation
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/openrc.logrotate openrc
+
+	if use pam; then
+		# install gentoo pam.d files
+		newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
+		newpamd "${FILESDIR}"/start-stop-daemon.pam supervise-daemon
+	fi
+
+	# install documentation
+	dodoc *.md
+}
+
+pkg_preinst() {
+	# avoid default thrashing in conf.d files when possible #295406
+	if [[ -e "${EROOT}"/etc/conf.d/hostname ]] ; then
+		(
+		unset hostname HOSTNAME
+		source "${EROOT}"/etc/conf.d/hostname
+		: ${hostname:=${HOSTNAME}}
+		[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
+		)
+	fi
+
+	# set default interactive shell to sulogin if it exists
+	set_config /etc/rc.conf rc_shell /sbin/sulogin "#" test -e /sbin/sulogin
+	return 0
+}
+
+pkg_postinst() {
+	if use hppa; then
+		elog "Setting the console font does not work on all HPPA consoles."
+		elog "You can still enable it by running:"
+		elog "# rc-update add consolefont boot"
+	fi
+
+	if ! use newnet && ! use netifrc; then
+		ewarn "You have emerged OpenRc without network support. This"
+		ewarn "means you need to SET UP a network manager such as"
+		ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/connman,"
+		ewarn " net-misc/NetworkManager, or net-vpn/badvpn."
+		ewarn "Or, you have the option of emerging openrc with the newnet"
+		ewarn "use flag and configuring /etc/conf.d/network and"
+		ewarn "/etc/conf.d/staticroute if you only use static interfaces."
+		ewarn
+	fi
+
+	if use newnet && [ ! -e "${EROOT}"/etc/runlevels/boot/network ]; then
+		ewarn "Please add the network service to your boot runlevel"
+		ewarn "as soon as possible. Not doing so could leave you with a system"
+		ewarn "without networking."
+		ewarn
+	fi
+
+	# added for 0.45 to handle seedrng/urandom switching (2022-06-07)
+	for v in ${REPLACING_VERSIONS}; do
+		[[ -x $(type rc-update) ]] || continue
+		if ver_test $v -lt 0.45; then
+			if rc-update show boot | grep -q urandom; then
+				rc-update del urandom boot
+				rc-update add seedrng boot
+		fi
+		fi
+	done
+}