app-editors/focuswriter: version bump 1.6.16

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/app-editors/focuswriter/focuswriter-1.6.16.ebuild b/app-editors/focuswriter/focuswriter-1.6.16.ebuild
new file mode 100644
index 000000000000..ea35e3d513fa
--- /dev/null
+++ b/app-editors/focuswriter/focuswriter-1.6.16.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils qmake-utils xdg-utils
+
+DESCRIPTION="A fullscreen and distraction-free word processor"
+HOMEPAGE="https://gottcode.org/focuswriter/"
+SRC_URI="https://gottcode.org/${PN}/${P}-src.tar.bz2"
+
+LICENSE="LGPL-3 GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	app-text/hunspell:=
+	>=dev-qt/qtcore-5.11:5
+	>=dev-qt/qtgui-5.11:5
+	>=dev-qt/qtmultimedia-5.11:5
+	>=dev-qt/qtprintsupport-5.11:5
+	dev-qt/qtsingleapplication[qt5(+),X]
+	>=dev-qt/qtwidgets-5.11:5
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	dev-qt/qtconcurrent:5
+	virtual/pkgconfig
+"
+
+DOCS=( ChangeLog CREDITS README )
+
+PATCHES=( "${FILESDIR}/${PN}-1.6.0-unbundle-qtsingleapplication.patch" )
+
+src_configure() {
+	eqmake5 PREFIX="${EPREFIX}/usr"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}