proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

4 files changed, 187 insertions, 0 deletions

diff --git a/app-emulation/winetricks/Manifest b/app-emulation/winetricks/Manifest
new file mode 100644
index 000000000000..4ff65142ce81
--- /dev/null
+++ b/app-emulation/winetricks/Manifest
@@ -0,0 +1,2 @@
+DIST winetricks-20150706.tar.gz 171118 SHA256 989290d0a6b2a51da69b348e986ec67de48c625ca461b2da928884f17d834c4e SHA512 8cb021463c0fbf5f96bab98d61fbe6fe630ddb2b72d97aee30eb14ea617b0214f196025e2b854d6a3d0de53f84ea66ed8b05cf16d46496376b4109b686cc029c WHIRLPOOL 650250025efbf1a8fb3ac6319eb164dfe60530626911628bd4c829a76c7994336f8080fa1b40f50ae3da22b0698ef0944fa37bb222087fde17ae14dc913efa3a
+DIST winetricks-gentoo-2012.11.24.tar.bz2 6398 SHA256 dded8c294cc5c2e71e4a5d1531ab165178cf3d2d1d890d0656368c2e499bfeb9 SHA512 59c93b73f3a7b2d11aefcde2ff66659ff1de21ad4b5f232f4b60572f3a48b15a6c49f369b1696862bf1b33fde190bf5598945e9536fb41ddec42d8def4d2be2a WHIRLPOOL 268da9e06712a678fbbcfff8eac1fca364b5e46f0a9c48a591eb88f03260b1a55f203eb2908bfe1f0a534b77c866127ff6f7049b0e43fe8abeaaa26fe55de75b
diff --git a/app-emulation/winetricks/metadata.xml b/app-emulation/winetricks/metadata.xml
new file mode 100644
index 000000000000..6cb30b92d9a2
--- /dev/null
+++ b/app-emulation/winetricks/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>wine</herd>
+	<herd>proxy-maintainers</herd>
+	<maintainer>
+		<email>np.hardass@gmail.com</email>
+		<name>NP-Hardass</name>
+		<description>Proxied co-maintainer</description>
+	</maintainer>
+	<upstream>
+		<remote-id type="google-code">winetricks</remote-id>
+		<remote-id type="github">Winetricks/winetricks</remote-id>
+	</upstream>
+	<use>
+		<flag name="rar">Pull in <pkg>app-arch/unrar</pkg> for extraction of
+		rar-compressed game files</flag>
+	</use>
+</pkgmetadata>
diff --git a/app-emulation/winetricks/winetricks-20150706.ebuild b/app-emulation/winetricks/winetricks-20150706.ebuild
new file mode 100644
index 000000000000..e5bd6ebf1843
--- /dev/null
+++ b/app-emulation/winetricks/winetricks-20150706.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit gnome2-utils eutils
+
+if [[ ${PV} == "99999999" ]] ; then
+	EGIT_REPO_URI="git://github.com/Winetricks/${PN}.git"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/Winetricks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+wtg=winetricks-gentoo-2012.11.24
+SRC_URI="${SRC_URI}
+	gtk? ( http://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )
+	kde? ( http://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )"
+
+DESCRIPTION="Easy way to install DLLs needed to work around problems in Wine"
+HOMEPAGE="http://winetricks.org http://wiki.winehq.org/winetricks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk kde rar"
+
+DEPEND=""
+RDEPEND="app-arch/cabextract
+	app-arch/p7zip
+	app-arch/unzip
+	app-emulation/wine
+	net-misc/wget
+	x11-misc/xdg-utils
+	gtk? ( gnome-extra/zenity )
+	kde? ( kde-apps/kdialog )
+	rar? ( app-arch/unrar )"
+
+# Uses non-standard "Wine" category, which is provided by app-emulation/wine; #451552
+QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"
+
+# Tests require network access and run wine, which is unreliable from a portage environment
+RESTRICT="test"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]] ; then
+		git-r3_src_unpack
+		if use gtk || use kde; then
+			unpack ${wtg}.tar.bz2
+		fi
+	else
+		default
+	fi
+}
+
+src_install() {
+	default
+	if use gtk || use kde; then
+		cd "${WORKDIR}/${wtg}" || die
+		domenu winetricks.desktop
+		insinto /usr/share/icons/hicolor/scalable/apps
+		doins wine-winetricks.svg
+	fi
+}
+
+pkg_preinst() {
+	if use gtk || use kde; then
+		gnome2_icon_savelist
+	fi
+}
+
+pkg_postinst() {
+	if use gtk || use kde; then
+		gnome2_icon_cache_update
+	fi
+}
+
+pkg_postrm() {
+	if use gtk || use kde; then
+		gnome2_icon_cache_update
+	fi
+}
diff --git a/app-emulation/winetricks/winetricks-99999999.ebuild b/app-emulation/winetricks/winetricks-99999999.ebuild
new file mode 100644
index 000000000000..e5bd6ebf1843
--- /dev/null
+++ b/app-emulation/winetricks/winetricks-99999999.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit gnome2-utils eutils
+
+if [[ ${PV} == "99999999" ]] ; then
+	EGIT_REPO_URI="git://github.com/Winetricks/${PN}.git"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/Winetricks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+wtg=winetricks-gentoo-2012.11.24
+SRC_URI="${SRC_URI}
+	gtk? ( http://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )
+	kde? ( http://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )"
+
+DESCRIPTION="Easy way to install DLLs needed to work around problems in Wine"
+HOMEPAGE="http://winetricks.org http://wiki.winehq.org/winetricks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk kde rar"
+
+DEPEND=""
+RDEPEND="app-arch/cabextract
+	app-arch/p7zip
+	app-arch/unzip
+	app-emulation/wine
+	net-misc/wget
+	x11-misc/xdg-utils
+	gtk? ( gnome-extra/zenity )
+	kde? ( kde-apps/kdialog )
+	rar? ( app-arch/unrar )"
+
+# Uses non-standard "Wine" category, which is provided by app-emulation/wine; #451552
+QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"
+
+# Tests require network access and run wine, which is unreliable from a portage environment
+RESTRICT="test"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]] ; then
+		git-r3_src_unpack
+		if use gtk || use kde; then
+			unpack ${wtg}.tar.bz2
+		fi
+	else
+		default
+	fi
+}
+
+src_install() {
+	default
+	if use gtk || use kde; then
+		cd "${WORKDIR}/${wtg}" || die
+		domenu winetricks.desktop
+		insinto /usr/share/icons/hicolor/scalable/apps
+		doins wine-winetricks.svg
+	fi
+}
+
+pkg_preinst() {
+	if use gtk || use kde; then
+		gnome2_icon_savelist
+	fi
+}
+
+pkg_postinst() {
+	if use gtk || use kde; then
+		gnome2_icon_cache_update
+	fi
+}
+
+pkg_postrm() {
+	if use gtk || use kde; then
+		gnome2_icon_cache_update
+	fi
+}