summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas K. Hüttel <dilfridge@gentoo.org>2019-07-07 18:18:05 +0200
committerAndreas K. Hüttel <dilfridge@gentoo.org>2019-07-07 18:19:14 +0200
commit104e31cfb68b3d9a03b150b56ec06d29bc7c21af (patch)
treed4b92db71129e69b19935de8e58cd9c7cdffbaf0 /app-office/libreoffice-bin-debug/libreoffice-bin-debug-6.2.5.2.ebuild
parentapp-office/libreoffice-bin: Version bump (diff)
downloadgentoo-104e31cfb68b3d9a03b150b56ec06d29bc7c21af.tar.gz
gentoo-104e31cfb68b3d9a03b150b56ec06d29bc7c21af.tar.bz2
gentoo-104e31cfb68b3d9a03b150b56ec06d29bc7c21af.zip
app-office/libreoffice-bin-debug: Version bump
Package-Manager: Portage-2.3.67, Repoman-2.3.16 Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>
Diffstat (limited to 'app-office/libreoffice-bin-debug/libreoffice-bin-debug-6.2.5.2.ebuild')
-rw-r--r--app-office/libreoffice-bin-debug/libreoffice-bin-debug-6.2.5.2.ebuild87
1 files changed, 87 insertions, 0 deletions
diff --git a/app-office/libreoffice-bin-debug/libreoffice-bin-debug-6.2.5.2.ebuild b/app-office/libreoffice-bin-debug/libreoffice-bin-debug-6.2.5.2.ebuild
new file mode 100644
index 000000000000..435287d3932b
--- /dev/null
+++ b/app-office/libreoffice-bin-debug/libreoffice-bin-debug-6.2.5.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+BASE_PACKAGENAME="debug"
+BASE_AMD64_URI="https://tamiko.kyomu.43-1.org/distfiles/amd64-${BASE_PACKAGENAME}-"
+BASE_X86_URI="https://tamiko.kyomu.43-1.org/distfiles/x86-${BASE_PACKAGENAME}-"
+
+DESCRIPTION="LibreOffice, a full office productivity suite. Binary package, debug info"
+HOMEPAGE="https://www.libreoffice.org"
+SRC_URI_AMD64="
+ ${BASE_AMD64_URI}libreoffice-${PVR}.tar.xz
+ kde? (
+ !java? ( ${BASE_AMD64_URI}libreoffice-kde-${PVR}.xd3 )
+ java? ( ${BASE_AMD64_URI}libreoffice-kde-java-${PVR}.xd3 )
+ )
+ gnome? (
+ !java? ( ${BASE_AMD64_URI}libreoffice-gnome-${PVR}.xd3 )
+ java? ( ${BASE_AMD64_URI}libreoffice-gnome-java-${PVR}.xd3 )
+ )
+ !kde? ( !gnome? (
+ java? ( ${BASE_AMD64_URI}libreoffice-java-${PVR}.xd3 )
+ ) )
+"
+SRC_URI_X86="
+ ${BASE_X86_URI}libreoffice-${PVR}.tar.xz
+ kde? (
+ !java? ( ${BASE_X86_URI}libreoffice-kde-${PVR}.xd3 )
+ java? ( ${BASE_X86_URI}libreoffice-kde-java-${PVR}.xd3 )
+ )
+ gnome? (
+ !java? ( ${BASE_X86_URI}libreoffice-gnome-${PVR}.xd3 )
+ java? ( ${BASE_X86_URI}libreoffice-gnome-java-${PVR}.xd3 )
+ )
+ !kde? ( !gnome? (
+ java? ( ${BASE_X86_URI}libreoffice-java-${PVR}.xd3 )
+ ) )
+"
+
+SRC_URI="
+ amd64? ( ${SRC_URI_AMD64} )
+ x86? ( ${SRC_URI_X86} )
+"
+
+IUSE="gnome java kde"
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+
+RDEPEND="=app-office/${PN/-debug}-${PVR}[gnome=,java=,kde=]"
+
+DEPEND="dev-util/xdelta:3"
+
+RESTRICT="test strip"
+
+S="${WORKDIR}"
+
+QA_PREBUILT="/usr/*"
+
+src_unpack() {
+ einfo "Uncompressing distfile ${ARCH}-${BASE_PACKAGENAME}-libreoffice-${PVR}.tar.xz"
+ xz -cd "${DISTDIR}/${ARCH}-${BASE_PACKAGENAME}-libreoffice-${PVR}.tar.xz" > "${WORKDIR}/${ARCH}-${BASE_PACKAGENAME}-libreoffice-${PVR}.tar" || die
+
+ local patchname
+ use kde && patchname="-kde"
+ use gnome && patchname="-gnome"
+ use java && patchname="${patchname}-java"
+
+ if [ -n "${patchname}" ]; then
+ einfo "Patching distfile ${ARCH}-${BASE_PACKAGENAME}-libreoffice-${PVR}.tar using ${ARCH}-${BASE_PACKAGENAME}-libreoffice${patchname}-${PVR}.xd3"
+ xdelta3 -d -s "${WORKDIR}/${ARCH}-${BASE_PACKAGENAME}-libreoffice-${PVR}.tar" "${DISTDIR}/${ARCH}-${BASE_PACKAGENAME}-libreoffice${patchname}-${PVR}.xd3" "${WORKDIR}/tmpdist.tar" || die
+ mv "${WORKDIR}/tmpdist.tar" "${WORKDIR}/${ARCH}-${BASE_PACKAGENAME}-libreoffice-${PVR}.tar" || die
+ fi
+
+ einfo "Unpacking new ${ARCH}-${BASE_PACKAGENAME}-libreoffice-${PVR}.tar"
+ unpack "./${ARCH}-${BASE_PACKAGENAME}-libreoffice-${PVR}.tar"
+}
+
+src_configure() { :; }
+
+src_compile() { :; }
+
+src_install() {
+ dodir /usr
+ cp -aR "${S}"/usr/* "${ED}"/usr/ || die
+}