summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMart Raudsepp <leio@gentoo.org>2018-09-30 01:25:00 +0300
committerMart Raudsepp <leio@gentoo.org>2018-09-30 03:08:18 +0300
commit0d2c1d0b668fbc06279aadc50c309fd343207164 (patch)
tree1b72b8a2d980182db5a5ec560676b7109d997014 /dev-libs/gjs/gjs-1.50.4.ebuild
parentapp-arch/lz4: Version bump (v1.8.3) (diff)
downloadgentoo-0d2c1d0b668fbc06279aadc50c309fd343207164.tar.gz
gentoo-0d2c1d0b668fbc06279aadc50c309fd343207164.tar.bz2
gentoo-0d2c1d0b668fbc06279aadc50c309fd343207164.zip
dev-libs/gjs: bump to 1.50.4
Signed-off-by: Mart Raudsepp <leio@gentoo.org> Package-Manager: Portage-2.3.49, Repoman-2.3.11
Diffstat (limited to 'dev-libs/gjs/gjs-1.50.4.ebuild')
-rw-r--r--dev-libs/gjs/gjs-1.50.4.ebuild57
1 files changed, 57 insertions, 0 deletions
diff --git a/dev-libs/gjs/gjs-1.50.4.ebuild b/dev-libs/gjs/gjs-1.50.4.ebuild
new file mode 100644
index 000000000000..c4457cc28600
--- /dev/null
+++ b/dev-libs/gjs/gjs-1.50.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2 pax-utils virtualx
+
+DESCRIPTION="Javascript bindings for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Projects/Gjs"
+
+LICENSE="MIT || ( MPL-1.1 LGPL-2+ GPL-2+ )"
+SLOT="0"
+IUSE="+cairo examples gtk test"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+ >=dev-libs/glib-2.52.1
+ >=dev-libs/gobject-introspection-1.53.4:=
+
+ sys-libs/readline:0=
+ dev-lang/spidermonkey:52
+ virtual/libffi
+ cairo? ( x11-libs/cairo[X] )
+ gtk? ( >=x11-libs/gtk+-3.20:3 )
+"
+DEPEND="${RDEPEND}
+ gnome-base/gnome-common
+ sys-devel/gettext
+ virtual/pkgconfig
+ test? ( sys-apps/dbus )
+"
+
+src_configure() {
+ # FIXME: add systemtap/dtrace support, like in glib:2
+ # FIXME: --enable-systemtap installs files in ${D}/${D} for some reason
+ # XXX: Do NOT enable coverage, completely useless for portage installs
+ gnome2_src_configure \
+ --disable-systemtap \
+ --disable-dtrace \
+ --disable-code-coverage \
+ $(use_with cairo cairo) \
+ $(use_with gtk) \
+ $(use_with test dbus-tests) \
+ $(use_with test xvfb-tests)
+}
+
+src_install() {
+ # installation sometimes fails in parallel, bug #???
+ gnome2_src_install -j1
+
+ if use examples; then
+ insinto /usr/share/doc/"${PF}"/examples
+ doins "${S}"/examples/*
+ fi
+
+ # Required for gjs-console to run correctly on PaX systems
+ pax-mark mr "${ED}/usr/bin/gjs-console"
+}