summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorFabio Rossi <rossi.f@inwind.it>2017-03-04 16:43:25 +1100
committerMichael Palimaka <kensington@gentoo.org>2017-03-04 16:44:46 +1100
commit41b48133d6c301cd411b3637689a3abfdf5e43a0 (patch)
treeaedd3e05c00397779628736e56b6ffa09fbd317a /dev-util/eric/eric-17.03.ebuild
parentnet-libs/libbtbb: wireshark-plugins are in wireshark now, undefault the use flag (diff)
downloadgentoo-41b48133d6c301cd411b3637689a3abfdf5e43a0.tar.gz
gentoo-41b48133d6c301cd411b3637689a3abfdf5e43a0.tar.bz2
gentoo-41b48133d6c301cd411b3637689a3abfdf5e43a0.zip
dev-util/eric: version bump 17.03
Gentoo-bug: 610380 Package-Manager: Portage-2.3.4, Repoman-2.3.2
Diffstat (limited to 'dev-util/eric/eric-17.03.ebuild')
-rw-r--r--dev-util/eric/eric-17.03.ebuild66
1 files changed, 66 insertions, 0 deletions
diff --git a/dev-util/eric/eric-17.03.ebuild b/dev-util/eric/eric-17.03.ebuild
new file mode 100644
index 000000000000..1f995f8098a4
--- /dev/null
+++ b/dev-util/eric/eric-17.03.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_REQ_USE="sqlite,xml"
+
+inherit python-single-r1
+
+DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
+HOMEPAGE="http://eric-ide.python-projects.org/"
+LICENSE="GPL-3"
+SLOT="6"
+
+MY_P=${PN}${SLOT}-${PV}
+SRC_URI="mirror://sourceforge/eric-ide/${PN}${SLOT}/stable/${PV}/${MY_P}.tar.gz"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+ ${PYTHON_DEPS}
+ >=dev-python/sip-4.14.3[${PYTHON_USEDEP}]
+ >=dev-python/PyQt5-5.5.1[${PYTHON_USEDEP},gui,help,network,printsupport,sql,svg,webkit]
+ >=dev-python/qscintilla-python-2.8[qt5,${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+ >=dev-python/chardet-2.3.0[${PYTHON_USEDEP}]
+ >=dev-python/coverage-4.1.0[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.1.3[${PYTHON_USEDEP}]
+ !dev-util/eric:4
+ !dev-util/eric:5
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=(changelog README.rst THANKS)
+
+src_prepare() {
+ default
+
+ # Delete internal copies of dev-python/chardet and dev-python/pygments
+ rm -fr eric/ThirdParty/{CharDet,Pygments} || die
+
+ # Delete internal copy of dev-python/coverage
+ rm -fr eric/DebugClients/Python{,3}/coverage || die
+ sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
+ $(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
+
+ # Fix desktop files (bug 458092)
+ sed -i -re '/^Categories=/s:(Python|QtWeb):X-&:g' eric/eric6{,_{,web}browser}.desktop || die
+}
+
+src_install() {
+ "${PYTHON}" install.py \
+ -b "${EPREFIX}/usr/bin" \
+ -d "$(python_get_sitedir)" \
+ -i "${D}" \
+ -c \
+ -z \
+ || die
+
+ python_optimize
+ einstalldocs
+}