kde-apps: Add KDE Applications 17.04.1

Package-Manager: Portage-2.3.5, Repoman-2.3.1

2 files changed, 116 insertions, 0 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index 503fe57075f8..fc52a404ed44 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1,2 +1,3 @@
 DIST k3b-17.04.0.tar.xz 10573620 SHA256 832b7a94769b4b0c33c0935adeb36e47c297eeb4801650da9b7ab1668b464a73 SHA512 451f5f1bf917b7c56304adacbe1bc1c49fc8e29c6ae49c52092f5fbbb95d93478e106de287e7fa8228aa5a80d5a1e4a28657a71def4e9e759299ae5da4d0ae9d WHIRLPOOL c99ac43e84474f44777c9ffedf20da27b77c93b905e97464c7efac89e5aecea33c955cce9ec4afc281f2fff6d888baf76e6147b6313a3fa586837bcb9a5d2a46
+DIST k3b-17.04.1.tar.xz 10573004 SHA256 3bd80f7bf99b758964277d5af5dbf7d94dabde7dfced8397e8a5cce68092bc57 SHA512 7d99872198662faff7a247d21eab7ba7191be71e223a2d5edfe2c109a321c949db884faaf23229beeeb36632c72f992fcdb3451e2d319575d81e044ec1fce2d6 WHIRLPOOL ab9fb42f18313300ba227f835429f2b16fc42f6cbb88b4505d0322240971c06bb266b0a7323f1bd1a102f974b29da3560f2a8a07fb41d69b73b8aa27611e30f6
 DIST k3b-2.0.3a.tar.xz 9864468 SHA256 2d0bb2746802c1d3ad7ddd10e29234cf2053074f376feb200306a5570c39c081 SHA512 008d69f3d60dfcd39c787c8fb0b50cdf7b29f1cf551c2c0aa0b6e995ec9d67b26edcb0670d5cd428afcc4e2a60c9e6170a9316b90978dfcc3693d27db98e7472 WHIRLPOOL 5cc63f7355ead8585295c6be8909a07fb0f34df77c8feff14c42daffc52679e27fbb28f1b1912c1bdf22e9c79b4369b2af6f3f8592f25af0f401a59e2b3a2c50
diff --git a/kde-apps/k3b/k3b-17.04.1.ebuild b/kde-apps/k3b/k3b-17.04.1.ebuild
new file mode 100644
index 000000000000..87ad4691873a
--- /dev/null
+++ b/kde-apps/k3b/k3b-17.04.1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="http://www.k3b.org/"
+LICENSE="GPL-2 FDL-1.2"
+KEYWORDS="~amd64 ~x86"
+IUSE="dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis webkit"
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kfilemetadata)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_kdeapps_dep libkcddb)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread )
+	ffmpeg? (
+		libav? ( media-video/libav:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( >=media-libs/flac-1.2[cxx] )
+	mp3? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? ( media-libs/libvorbis )
+	webkit? ( $(add_qt_dep qtwebkit) )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	media-sound/cdparanoia
+	virtual/cdrtools
+	dvd? (
+		>=app-cdr/dvd+rw-tools-7
+		encode? ( media-video/transcode[dvd] )
+	)
+	emovix? ( media-video/emovix )
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+REQUIRED_USE="
+	mp3? ( encode )
+	sox? ( encode )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+		$(cmake-utils_use_find_package webkit Qt5WebKitWidgets)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	echo
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}