summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJohannes Huber <johu@gentoo.org>2017-02-07 19:28:35 +0100
committerJohannes Huber <johu@gentoo.org>2017-02-07 19:30:35 +0100
commit1a442e7816b99589e145656e21d3a41c679b917a (patch)
treec3163b27808cd7a056c3ab7653f8f11fb4df3544 /kde-plasma/breeze/breeze-5.9.1.ebuild
parentx11-wm/musca: Fix toolong DESCRIPTION (diff)
downloadgentoo-1a442e7816b99589e145656e21d3a41c679b917a.tar.gz
gentoo-1a442e7816b99589e145656e21d3a41c679b917a.tar.bz2
gentoo-1a442e7816b99589e145656e21d3a41c679b917a.zip
kde-plasma: Version bump KDE Plasma 5.9.1
Package-Manager: Portage-2.3.3, Repoman-2.3.1
Diffstat (limited to 'kde-plasma/breeze/breeze-5.9.1.ebuild')
-rw-r--r--kde-plasma/breeze/breeze-5.9.1.ebuild76
1 files changed, 76 insertions, 0 deletions
diff --git a/kde-plasma/breeze/breeze-5.9.1.ebuild b/kde-plasma/breeze/breeze-5.9.1.ebuild
new file mode 100644
index 000000000000..32a1b33673f1
--- /dev/null
+++ b/kde-plasma/breeze/breeze-5.9.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit kde5 multibuild
+
+DESCRIPTION="Breeze visual style for the Plasma desktop"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/breeze"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="qt4 wayland"
+
+COMMON_DEPEND="
+ $(add_frameworks_dep frameworkintegration)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kguiaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_plasma_dep kdecoration)
+ $(add_qt_dep qtdbus)
+ $(add_qt_dep qtdeclarative)
+ $(add_qt_dep qtgui)
+ $(add_qt_dep qtwidgets)
+ $(add_qt_dep qtx11extras)
+ x11-libs/libxcb
+ qt4? (
+ kde-frameworks/kdelibs:4
+ x11-libs/libX11
+ )
+ wayland? ( $(add_frameworks_dep kwayland) )
+"
+DEPEND="${COMMON_DEPEND}
+ $(add_frameworks_dep kpackage)
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_frameworks_dep breeze-icons)
+ $(add_plasma_dep kde-cli-tools)
+"
+
+pkg_setup() {
+ kde5_pkg_setup
+ MULTIBUILD_VARIANTS=( kf5 $(usev qt4) )
+}
+
+src_configure() {
+ myconfigure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package wayland KF5Wayland)
+ )
+
+ if [[ ${MULTIBUILD_VARIANT} = qt4 ]] ; then
+ mycmakeargs+=( -DUSE_KDE4=true )
+ fi
+
+ kde5_src_configure
+ }
+
+ multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+ multibuild_foreach_variant kde5_src_compile
+}
+
+src_test() {
+ multibuild_foreach_variant kde5_src_test
+}
+
+src_install() {
+ multibuild_foreach_variant kde5_src_install
+}