summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJohannes Huber <johu@gentoo.org>2017-02-28 20:06:11 +0100
committerJohannes Huber <johu@gentoo.org>2017-02-28 20:29:35 +0100
commit5f87254116bbae60df086b5659c7fe3fe05475a5 (patch)
tree891efbc864a894bd5baed0fcf33f9645f08f8eb5 /kde-plasma/oxygen/oxygen-5.9.3.ebuild
parentx11-misc/evolvotron: fix build with gcc6, bug #597266 (diff)
downloadgentoo-5f87254116bbae60df086b5659c7fe3fe05475a5.tar.gz
gentoo-5f87254116bbae60df086b5659c7fe3fe05475a5.tar.bz2
gentoo-5f87254116bbae60df086b5659c7fe3fe05475a5.zip
kde-plasma: Version bump KDE Plasma 5.9.3
Package-Manager: Portage-2.3.3, Repoman-2.3.1
Diffstat (limited to 'kde-plasma/oxygen/oxygen-5.9.3.ebuild')
-rw-r--r--kde-plasma/oxygen/oxygen-5.9.3.ebuild84
1 files changed, 84 insertions, 0 deletions
diff --git a/kde-plasma/oxygen/oxygen-5.9.3.ebuild b/kde-plasma/oxygen/oxygen-5.9.3.ebuild
new file mode 100644
index 000000000000..9278b31d0487
--- /dev/null
+++ b/kde-plasma/oxygen/oxygen-5.9.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit kde5 multibuild
+
+DESCRIPTION="Oxygen visual style for the Plasma desktop"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/oxygen"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="qt4 wayland"
+
+COMMON_DEPEND="
+ $(add_frameworks_dep frameworkintegration)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kguiaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_plasma_dep kdecoration)
+ $(add_qt_dep qtdbus)
+ $(add_qt_dep qtdeclarative)
+ $(add_qt_dep qtgui)
+ $(add_qt_dep qtwidgets)
+ $(add_qt_dep qtx11extras)
+ x11-libs/libxcb
+ qt4? (
+ kde-frameworks/kdelibs:4
+ x11-libs/libX11
+ )
+ wayland? ( $(add_frameworks_dep kwayland) )
+"
+DEPEND="${COMMON_DEPEND}
+ $(add_frameworks_dep kservice)
+ qt4? (
+ dev-util/automoc:0
+ virtual/pkgconfig
+ )
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ qt4? (
+ !kde-plasma/kstyles:4
+ !kde-plasma/liboxygenstyle:4
+ )
+ !kde-plasma/kdebase-cursors:4
+"
+
+pkg_setup() {
+ kde5_pkg_setup
+ MULTIBUILD_VARIANTS=( kf5 $(usev qt4) )
+}
+
+src_configure() {
+ myconfigure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package wayland KF5Wayland)
+ )
+
+ if [[ ${MULTIBUILD_VARIANT} = qt4 ]] ; then
+ mycmakeargs+=( -DUSE_KDE4=true )
+ fi
+
+ kde5_src_configure
+ }
+
+ multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+ multibuild_foreach_variant kde5_src_compile
+}
+
+src_test() {
+ multibuild_foreach_variant kde5_src_test
+}
+
+src_install() {
+ multibuild_foreach_variant kde5_src_install
+}