summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2021-02-23 22:09:19 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2021-02-23 22:18:24 +0100
commit7276f8380a624a6e9e9817f8918d24b33451c938 (patch)
treed5f12f8a0373a189a2bf224c995fde916863eaf6 /kde-plasma
parentkde-plasma/plasma-browser-integration: 5.21.1 version bump (diff)
downloadgentoo-7276f8380a624a6e9e9817f8918d24b33451c938.tar.gz
gentoo-7276f8380a624a6e9e9817f8918d24b33451c938.tar.bz2
gentoo-7276f8380a624a6e9e9817f8918d24b33451c938.zip
kde-plasma/plasma-desktop: 5.21.1 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'kde-plasma')
-rw-r--r--kde-plasma/plasma-desktop/Manifest1
-rw-r--r--kde-plasma/plasma-desktop/plasma-desktop-5.21.1.ebuild168
2 files changed, 169 insertions, 0 deletions
diff --git a/kde-plasma/plasma-desktop/Manifest b/kde-plasma/plasma-desktop/Manifest
index 78326f66abb2..bd66f96f581d 100644
--- a/kde-plasma/plasma-desktop/Manifest
+++ b/kde-plasma/plasma-desktop/Manifest
@@ -1,3 +1,4 @@
DIST plasma-desktop-5.20.5.tar.xz 15899532 BLAKE2B 1ed7d6c1bbc8b368ed98c4f35bcfd10f8436909a8f66fbfdf2e4e5eb8b8dcd36903600a934512dac7a07d54ef830ed2604e1ee39df6e40156ef7cec1e96dd041 SHA512 a1af8d04dbf16e94777e018ff0f289b69928ccefeb31e6dc73a2425d6170a0a5a3fdc324d192b41664cd118eea9b15cb6e7bd3f49ee03095ede16a3fa53a6f2b
DIST plasma-desktop-5.21.0.tar.xz 15897396 BLAKE2B 0f7e312bf94ef54f4d6e38bf8ad2777588c6b4b69a277e9621356ccf588bafe6b02ca14502a8b4cdf447642d9b9b4b6cf27693a42097aad9df58c470dd41f815 SHA512 fea2e4626538fede72c75e995d73f82d4ec95914737e0e2ac1e90e71f8752d06bcbedb0b515fb3a47ea1c315d986f8f836efa39899d9f923c526b30aa244ada4
+DIST plasma-desktop-5.21.1.tar.xz 15900696 BLAKE2B 27a9de65d1a98b46d3be814c5c978c79bf11db7db043674d8f568088d9f8fe3f03d3758699cf289a0c462ebcc97fa605a0dbfe02632f87ccbeb4b9b4ce11402f SHA512 a82c7683d48739fdec3c7ef65a70be4dba265f4d8eff30494944dc704617c84a441cfc0e80c98802a3c8a1cdb2fa08de8b95f09ba816abc4ff3ad2a9acc0cf46
DIST plasma-desktop-override-include-dirs-0.tar.xz 7504 BLAKE2B 781a2f0f7ca5a45b966edfc79012e80c6826262a211d95b725590191a8828e0002fd924a49cc63c12090535077a24f3e719ca3277aac89aba3092e86f73d7f61 SHA512 d23dc203b8b645472c9c192a3d73ef9b46c66d9c64df1c90efa05c9968ec125e0a256bc9b654f05a1f22bce4b1d8aad436f581b42d579f4195a44f062fd444bb
diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.21.1.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.21.1.ebuild
new file mode 100644
index 000000000000..9c62103b0a89
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.21.1.ebuild
@@ -0,0 +1,168 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.78.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma desktop"
+XORGHDRS="${PN}-override-include-dirs-0"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="emoji ibus +kaccounts +policykit scim +semantic-desktop"
+
+BDEPEND="virtual/pkgconfig"
+COMMON_DEPEND="
+ >=dev-qt/qtconcurrent-${QTMIN}:5
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtdeclarative-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5
+ >=dev-qt/qtprintsupport-${QTMIN}:5
+ >=dev-qt/qtsql-${QTMIN}:5
+ >=dev-qt/qtsvg-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=dev-qt/qtx11extras-${QTMIN}:5
+ >=dev-qt/qtxml-${QTMIN}:5
+ >=kde-frameworks/attica-${KFMIN}:5
+ >=kde-frameworks/kactivities-${KFMIN}:5
+ >=kde-frameworks/kactivities-stats-${KFMIN}:5
+ >=kde-frameworks/karchive-${KFMIN}:5
+ >=kde-frameworks/kauth-${KFMIN}:5
+ >=kde-frameworks/kbookmarks-${KFMIN}:5
+ >=kde-frameworks/kcmutils-${KFMIN}:5
+ >=kde-frameworks/kcodecs-${KFMIN}:5
+ >=kde-frameworks/kcompletion-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kdbusaddons-${KFMIN}:5
+ >=kde-frameworks/kdeclarative-${KFMIN}:5
+ >=kde-frameworks/kded-${KFMIN}:5
+ >=kde-frameworks/kdelibs4support-${KFMIN}:5
+ >=kde-frameworks/kglobalaccel-${KFMIN}:5
+ >=kde-frameworks/kguiaddons-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/kiconthemes-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/kitemmodels-${KFMIN}:5
+ >=kde-frameworks/kitemviews-${KFMIN}:5
+ >=kde-frameworks/kjobwidgets-${KFMIN}:5
+ >=kde-frameworks/knewstuff-${KFMIN}:5
+ >=kde-frameworks/knotifications-${KFMIN}:5
+ >=kde-frameworks/knotifyconfig-${KFMIN}:5
+ >=kde-frameworks/kparts-${KFMIN}:5
+ >=kde-frameworks/krunner-${KFMIN}:5
+ >=kde-frameworks/kservice-${KFMIN}:5
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+ >=kde-frameworks/kwindowsystem-${KFMIN}:5
+ >=kde-frameworks/kxmlgui-${KFMIN}:5
+ >=kde-frameworks/plasma-${KFMIN}:5
+ >=kde-frameworks/solid-${KFMIN}:5
+ >=kde-frameworks/sonnet-${KFMIN}:5
+ >=kde-plasma/kwin-${PVCUT}:5
+ >=kde-plasma/libksysguard-${PVCUT}:5
+ >=kde-plasma/libkworkspace-${PVCUT}:5
+ >=kde-plasma/plasma-workspace-${PVCUT}:5
+ >=media-libs/phonon-4.11.0
+ x11-libs/libX11
+ x11-libs/libXfixes
+ x11-libs/libXi
+ x11-libs/libxcb[xkb]
+ x11-libs/libxkbfile
+ emoji? (
+ app-i18n/ibus[emoji]
+ dev-libs/glib:2
+ media-fonts/noto-emoji
+ )
+ ibus? (
+ app-i18n/ibus
+ dev-libs/glib:2
+ >=dev-qt/qtx11extras-${QTMIN}:5
+ x11-libs/libxcb
+ x11-libs/xcb-util-keysyms
+ )
+ kaccounts? (
+ kde-apps/kaccounts-integration:5
+ net-libs/accounts-qt
+ )
+ policykit? ( >=kde-frameworks/kwallet-${KFMIN}:5 )
+ scim? ( app-i18n/scim )
+ semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+ dev-libs/boost
+ x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+ !<kde-plasma/kdeplasma-addons-5.15.80
+ !kde-plasma/user-manager
+ >=dev-qt/qtgraphicaleffects-${QTMIN}:5
+ >=dev-qt/qtquickcontrols2-${QTMIN}:5
+ >=kde-frameworks/kirigami-${KFMIN}:5
+ >=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+ >=kde-plasma/kde-cli-tools-${PVCUT}:5
+ >=kde-plasma/oxygen-${PVCUT}:5
+ sys-apps/util-linux
+ x11-apps/setxkbmap
+ kaccounts? ( net-libs/signon-oauth2 )
+ policykit? ( sys-apps/accountsservice )
+"
+
+PATCHES=(
+ "${WORKDIR}/${XORGHDRS}/override-include-dirs.patch" # downstream patch
+)
+
+src_prepare() {
+ ecm_src_prepare
+
+ if ! use policykit; then
+ ecm_punt_bogus_dep KF5 Wallet
+ cmake_run_in kcms cmake_comment_add_subdirectory users
+ fi
+
+ if ! use ibus; then
+ sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
+ -i applets/kimpanel/backend/ibus/CMakeLists.txt || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON # not packaged
+ -DEvdev_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+ -DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+ -DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+ -DSynaptics_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+ $(cmake_use_find_package kaccounts AccountsQt5)
+ $(cmake_use_find_package kaccounts KAccounts)
+ $(cmake_use_find_package scim SCIM)
+ $(cmake_use_find_package semantic-desktop KF5Baloo)
+ )
+ if ! use emoji && ! use ibus; then
+ mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_IBus=ON )
+ fi
+
+ ecm_src_configure
+}
+
+src_test() {
+ # parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+ # test_kio_fonts needs D-Bus, bug #634166
+ # lookandfeel-kcmTest is unreliable for a long time, bug #607918
+ local myctestargs=(
+ -j1
+ -E "(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
+ )
+
+ ecm_src_test
+}