media-gfx/imagemagick: bump to v6.9.10-7 & v7.0.8-7

Package-Manager: Portage-2.3.43, Repoman-2.3.10

3 files changed, 374 insertions, 0 deletions

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index d0683a4eab2f..b550537e9aea 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,6 +1,7 @@
 DIST ImageMagick-6.9.10-3.tar.xz 8922536 BLAKE2B 36936b28aac025bd948d9925707877b6f6b5a9eb50f1afc2f318a0596c9096b7853f4db44c42994fe32b7ba0fe42eafb9d705ead0faf6f75eb9e7e07bc1c97e4 SHA512 760e8b003415fcf6c83e542346800f1f2d8834cd47ba343eead1f0fa228f2f44af7ca9b4379de52498a3da76aa35f25d0ec939cefa71718400702bc6801fffbe
 DIST ImageMagick-6.9.10-5.tar.xz 8921204 BLAKE2B b11c6dded5b42b797585e8253441fa6265de9f06241206b9ce29781df6c8896e9dd0ec967191ff28fcae445130d38e7e781728cbc27752b33b3422d971459952 SHA512 b6c068918a2c23bc86d84a1fd81bd8c0aea83fee0c33b5c686c7c6180231be2b27c1c43be111555017d2065fa97ba36c084e1479ff771846b73d500d67c7f85b
 DIST ImageMagick-6.9.10-6.tar.xz 8913200 BLAKE2B 7009454e8d1d3bb27ef143dd3d0810df1548ff66d36cb48d0a91aee11246e2c2c4908947b95058b8cd2a83a4d69318564e4881a45636dca666fdec95e418c26a SHA512 984acc4610c205ead3b32ae4c059470dc4361e48cee6d9314bd3f8beed6b88b4adc824d59f059ead840293afae5595bdc3161e57ac9b2d4d49b90d32df46e49a
+DIST ImageMagick-6.9.10-7.tar.xz 8916444 BLAKE2B 59211b1fe876226f53999706b7d992306f67687ab6170e3a1846e66806ef92b4eb2808eea8bcc69ffe7ad40bef36fcd4417124b784534d474647b413747dbb1e SHA512 3bda2478b79d9a35dd7b3dd1206d23e2b8ddb71a881e1d8f036fa3488d10245c11587ef7f8624febc758af65ce0d28d642d485deffc033e144f791977aac7beb
 DIST ImageMagick-6.9.9-31.tar.xz 8819864 BLAKE2B f6cdb19bff58a0b318a9af78f3fa429137cc4e79bbe075f9c6444204ce8a4324dde5792ab7232e6898a4993ad558c514a143c14469370de822038d1d669fdffa SHA512 85cbe4e4991a08a5c11c01b4276525fa1d63bcef9a9814fee1f8ede3a5ed432da8d3d84965ed75105723948d07ad879f7cf07d5121f0d624df9275dd4e41cb8f
 DIST ImageMagick-6.9.9-40.tar.xz 8919136 BLAKE2B 04b9585948194e6ba03efa549d9ef6a8b12fce141346ddd7dc1b40e72349dc603bc6154a3826496dae47ff8c0eb5b6a5b80ae51a60d0d8a632debcd9229cf3da SHA512 416c2e248e3d1c6d89b930b8179194a9e1dfd160b9de1a75f98ceeb4199dd1b5f3b1d0ce646c26429054e7970680c40b77e2bf0a97ca82bbe84aa66648393fb4
 DIST ImageMagick-6.9.9-47.tar.xz 8918196 BLAKE2B f28948d5728cbd2b011091ded2c12b507d1939ae5f2e0872c098ea488a3668d5f15782de023a6775a60790feeabcbab3ae62917f5f160bbc5ec59b65527775d5 SHA512 7bf7ae7fc276c2857f546370851ef7aaf1704c1b5bbad1a739d964e8e48a4ece9d9274e154a5aaa18c24f31e60e03d2df661cca922a3fff780cbcddd86524cb5
@@ -10,3 +11,4 @@ DIST ImageMagick-7.0.7-35.tar.xz 8614296 BLAKE2B 7c3c65d3fa630040febd40370fe93d3
 DIST ImageMagick-7.0.8-3.tar.xz 8613672 BLAKE2B c3ad7bb2d0917d2551b7c8ae0d80a8ab95e31d40cf18c26d7df363c3df209d7923a62a7fb90aec581fc4101139bc369a82289a96f51965f533b1956a9cfa4eed SHA512 0594de337c9eb1d116b15eeac0f1bceefeb86f13a41bc6721b120fa2e58f0ca5e2e1454b4e2b670c93545f13406f8bdbf54e5b3470e34841b5e9ac9d26821b70
 DIST ImageMagick-7.0.8-5.tar.xz 8611448 BLAKE2B 7a4f38ec458d010644d88cda605355d5871952b055ba9e088fe164448e2a0332e44e1545fc5929df455298ee56be65b66846faae4738912314177be050c683b0 SHA512 d760e630fd82b7636a031728e1f078efb8bb962e60cdc912cdfad29d3e6f74c1b5047941e711db89aa847d2e7c8c6ed44f451fa8ccff431c20d92ef49ef1915d
 DIST ImageMagick-7.0.8-6.tar.xz 8636756 BLAKE2B de30cbf334e47232c4f2addc789342a96da72f13f1f88d0db08462cf8ad80487d78dfae51f23a63c83100f78a60beb79781c44cff1b25f084badbb009fedf965 SHA512 4d498d2b7e9345b71e08a541aeaa1ee0ee62c781e92638cdd38a9a830b8fa291afece032b731ee79e1142d26cf94817356f0492cef257039beac33f865e9f588
+DIST ImageMagick-7.0.8-7.tar.xz 8634788 BLAKE2B dbb5103f314d83b4318b2cfd6dcb5931e4c20c7a2c8b8f57c52b85ea8a46ca27733a4828203723f337acbc5fb4dc2ae446b789a6d2ca46ad8e2e0d0f7973fc29 SHA512 b1db005899b7c55c1794be1edfb0596989d8e4b4e521a1dadf28b837ba16b337587ac0a0a17c1c441a0085df56cfc3386d9f750fa83fd5ea8e3eb2d1398e58cd
diff --git a/media-gfx/imagemagick/imagemagick-6.9.10.7.ebuild b/media-gfx/imagemagick/imagemagick-6.9.10.7.ebuild
new file mode 100644
index 000000000000..1d46b538e85c
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.9.10.7.ebuild
@@ -0,0 +1,186 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs eapi7-ver
+
+MY_P=ImageMagick-$(ver_rs 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="https://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-libs/libraw:= )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-base/xorg-proto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	local mesa_cards ati_cards nvidia_cards render_cards
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia** | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable hdri)
+		$(use_enable opencl)
+		--with-threads
+		--with-modules
+		--with-quantum-depth=${depth}
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options='INSTALLDIRS=vendor'
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		$(use_with bzip2 bzlib)
+		$(use_with X x)
+		$(use_with zlib)
+		--without-autotrace
+		$(use_with postscript dps)
+		$(use_with djvu)
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
+		$(use_with fftw)
+		$(use_with fpx)
+		$(use_with fontconfig)
+		$(use_with truetype freetype)
+		$(use_with postscript gslib)
+		$(use_with graphviz gvc)
+		$(use_with jbig)
+		$(use_with jpeg)
+		$(use_with jpeg2k openjp2)
+		$(use_with lcms)
+		$(use_with lqr)
+		$(use_with lzma)
+		$(use_with openexr)
+		$(use_with pango)
+		$(use_with png)
+		$(use_with raw)
+		$(use_with svg rsvg)
+		$(use_with tiff)
+		$(use_with webp)
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
+		$(use_with wmf)
+		$(use_with xml)
+		--${openmp}-openmp
+		--with-gcc-arch=no-automagic
+	)
+	CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED%/}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}
diff --git a/media-gfx/imagemagick/imagemagick-7.0.8.7.ebuild b/media-gfx/imagemagick/imagemagick-7.0.8.7.ebuild
new file mode 100644
index 000000000000..49b5b2b7bbd7
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.0.8.7.ebuild
@@ -0,0 +1,186 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs eapi7-ver
+
+MY_P=ImageMagick-$(ver_rs 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="https://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-libs/libraw:= )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-base/xorg-proto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	local ati_cards mesa_cards nvidia_cards render_cards
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia* | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable hdri)
+		$(use_enable opencl)
+		--with-threads
+		--with-modules
+		--with-quantum-depth=${depth}
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options='INSTALLDIRS=vendor'
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		$(use_with bzip2 bzlib)
+		$(use_with X x)
+		$(use_with zlib)
+		--without-autotrace
+		$(use_with postscript dps)
+		$(use_with djvu)
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
+		$(use_with fftw)
+		$(use_with fpx)
+		$(use_with fontconfig)
+		$(use_with truetype freetype)
+		$(use_with postscript gslib)
+		$(use_with graphviz gvc)
+		$(use_with jbig)
+		$(use_with jpeg)
+		$(use_with jpeg2k openjp2)
+		$(use_with lcms)
+		$(use_with lqr)
+		$(use_with lzma)
+		$(use_with openexr)
+		$(use_with pango)
+		$(use_with png)
+		$(use_with raw)
+		$(use_with svg rsvg)
+		$(use_with tiff)
+		$(use_with webp)
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
+		$(use_with wmf)
+		$(use_with xml)
+		--${openmp}-openmp
+		--with-gcc-arch=no-automagic
+	)
+	CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED%/}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}