summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorThomas Beierlein <tomjbe@gentoo.org>2020-05-24 18:11:39 +0200
committerThomas Beierlein <tomjbe@gentoo.org>2020-05-24 18:11:39 +0200
commitc10ff690d4a6519d56337697c669a5044df99be8 (patch)
tree44165135cb2933550f72289f3acf4f5cf52abe6d /media-radio
parentmedia-video/gaupol: remove old (diff)
downloadgentoo-c10ff690d4a6519d56337697c669a5044df99be8.tar.gz
gentoo-c10ff690d4a6519d56337697c669a5044df99be8.tar.bz2
gentoo-c10ff690d4a6519d56337697c669a5044df99be8.zip
media-radio/unixcw: Drop install of static lib (bug #724654)
Bump EAPI Closes: https://bugs.gentoo.org/724654 Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>
Diffstat (limited to 'media-radio')
-rw-r--r--media-radio/unixcw/unixcw-3.5.1-r1.ebuild75
1 files changed, 75 insertions, 0 deletions
diff --git a/media-radio/unixcw/unixcw-3.5.1-r1.ebuild b/media-radio/unixcw/unixcw-3.5.1-r1.ebuild
new file mode 100644
index 000000000000..a905c627ddf7
--- /dev/null
+++ b/media-radio/unixcw/unixcw-3.5.1-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic multilib
+
+DESCRIPTION="A package of programs that fit together to form a morse code tutor program"
+HOMEPAGE="http://unixcw.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~x86"
+IUSE="alsa ncurses pulseaudio suid test qt5"
+RESTRICT="!test? ( test )"
+
+RDEPEND="ncurses? ( sys-libs/ncurses:= )
+ qt5? ( dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5 )
+ alsa? ( media-libs/alsa-lib )
+ pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ sys-devel/libtool"
+
+src_prepare() {
+ append-cflags -std=gnu11
+ append-cxxflags -std=gnu++11
+ eapply -p0 "${FILESDIR}"/$PN-3.5-tinfo.patch \
+ "${FILESDIR}"/$PN-tests.patch
+ eapply_user
+ eautoreconf
+}
+
+src_configure() {
+ econf --libdir=/usr/$(get_libdir) \
+ $(use_enable pulseaudio ) \
+ $(use_enable alsa ) \
+ $(use_enable ncurses cwcp ) \
+ $(use_enable qt5 xcwcp ) \
+ --disable-static
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+ find "${D}" -name '*.la' -type f -delete || die
+ dodoc ChangeLog NEWS README
+ if ! use suid ; then
+ fperms 711 /usr/bin/cw
+ if use ncurses ; then
+ fperms 711 /usr/bin/cwcp
+ fi
+ if use qt5 ; then
+ fperms 711 /usr/bin/xcwcp
+ fi
+ fi
+}
+
+pkg_postinst() {
+ if use suid ; then
+ ewarn "You have choosen to install 'cw', 'cwcp' and 'xcwcp' setuid"
+ ewarn "by setting USE=suid."
+ ewarn "Be aware that this is a security risk and not recommended."
+ ewarn ""
+ ewarn "These files do only need root access if you want to use the"
+ ewarn "PC speaker for morse sidetone output. You can alternativly"
+ ewarn "drop USE=suid and use sudo."
+ else
+ elog "Be aware that 'cw', 'cwcp' and 'xcwcp' needs root access if"
+ elog "you want to use the PC speaker for morse sidetone output."
+ elog "You can call the programs via sudo for that (see 'man sudo')."
+ fi
+}