proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

5 files changed, 143 insertions, 0 deletions

diff --git a/media-sound/mp3blaster/Manifest b/media-sound/mp3blaster/Manifest
new file mode 100644
index 000000000000..08092964609a
--- /dev/null
+++ b/media-sound/mp3blaster/Manifest
@@ -0,0 +1,2 @@
+DIST mp3blaster-3.2.5.tar.gz 329407 SHA256 129115742c77362cc3508eb7782702cfb44af2463a5453e8d19ea68abccedc29 SHA512 53f623340b7a8e4be6cd973474fd5f23c623b6d1c667478dc0d4c7a1ef5758f4bbc09d9d0698d1539d8d1c3ef45301b447f3ed74f68586070a07a7f9fa8c353e WHIRLPOOL 96cdc3b6436dec282a5836c00e2151dd04f218175fdd2451fcfd45f70bced05dea0c8915cf1a817d24a9961fc8ab3d9c5b568a5ae67e23e2b1915604b2d7806e
+DIST mp3blaster_3.2.5-3.debian.tar.gz 11000 SHA256 e4d424aeccde6ccd219270f4e4f0bf8f70b97e13075447b6d6d069110ed092c9 SHA512 1d899c85c2a2e1326fac0f87c61ead82273a08c672aeab0929479d9aa10c6ae703bb63c1a6aec14c8f5b6a139089fa5228cf09db72ea5b114efb60a196bd4788 WHIRLPOOL 9c1c99d5a4f4e5060a9eae4e681f0df841d6932f34a12102a82d2e1f795d4db41fd3f15d6aa6a34d04d42259d73ba67f775b24a51df30779d4f4466ded40f69f
diff --git a/media-sound/mp3blaster/files/mp3blaster-3.2.5-gcc44.patch b/media-sound/mp3blaster/files/mp3blaster-3.2.5-gcc44.patch
new file mode 100644
index 000000000000..fc1a6c8d053e
--- /dev/null
+++ b/media-sound/mp3blaster/files/mp3blaster-3.2.5-gcc44.patch
@@ -0,0 +1,13 @@
+http://bugs.gentoo.org/362347
+
+--- src/global.cc
++++ src/global.cc
+@@ -371,7 +371,7 @@
+ is_sid(const char *filename)
+ {
+ #ifdef HAVE_SIDPLAYER
+-	char *ext = strrchr(filename, '.');
++	const char *ext = strrchr(filename, '.');
+ 	if (ext) {
+ 		if (!strcasecmp(ext, ".psid")) return 1;
+ 		if (!strcasecmp(ext, ".sid")) return 1;
diff --git a/media-sound/mp3blaster/metadata.xml b/media-sound/mp3blaster/metadata.xml
new file mode 100644
index 000000000000..dbdb14e66904
--- /dev/null
+++ b/media-sound/mp3blaster/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>sound</herd>
+  <use>
+    <flag name="sid">Build with SID (Commodore 64 Audio) support</flag>
+  </use>
+  <upstream>
+    <remote-id type="sourceforge">mp3blaster</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/media-sound/mp3blaster/mp3blaster-3.2.5-r1.ebuild b/media-sound/mp3blaster/mp3blaster-3.2.5-r1.ebuild
new file mode 100644
index 000000000000..540a74a99eff
--- /dev/null
+++ b/media-sound/mp3blaster/mp3blaster-3.2.5-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit eutils
+
+DESCRIPTION="Text console based program for playing audio files"
+HOMEPAGE="http://mp3blaster.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	mirror://debian/pool/main/m/${PN}/${PN}_${PV}-3.debian.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ppc ppc64 sparc x86 ~x86-fbsd"
+IUSE="lirc oss sdl sid vorbis"
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7
+	lirc? ( app-misc/lirc )
+	sdl? ( media-libs/libsdl )
+	sid? ( =media-libs/libsidplay-1* )
+	vorbis? ( >=media-libs/libvorbis-1 )"
+DEPEND="${RDEPEND}
+	x11-misc/imake
+	oss? ( virtual/os-headers )"
+
+REQUIRED_USE="|| ( oss sdl )"
+
+DOCS="AUTHORS BUGS ChangeLog CREDITS FAQ NEWS README TODO"
+
+src_prepare() {
+	EPATCH_SOURCE=${WORKDIR}/debian/patches EPATCH_SUFFIX=patch EPATCH_FORCE=yes epatch
+	# file collision with media-sound/splay
+	sed -i -e 's:splay.1:splay_mp3blaster.1:' Makefile.in || die
+	mv -vf splay{,_mp3blaster}.1 || die
+}
+
+src_configure() {
+	# libpth and newthreads support are both broken
+	econf \
+		--disable-newthreads \
+		--without-pth \
+		--without-nas \
+		$(use_with lirc) \
+		$(use_with vorbis oggvorbis) \
+		$(use_with sid sidplay) \
+		--without-esd \
+		$(use_with sdl) \
+		$(use_with oss)
+}
+
+src_install() {
+	default
+
+	doman "${WORKDIR}"/debian/manpages/mp3tag.1
+
+	# relocate everything except commands.txt because it's used by src/main.cc
+	mv -vf "${ED}"usr/share/${PN}/{charmap,sample.*} "${ED}"usr/share/doc/${PF} || die
+
+	# file collision with media-sound/splay
+	mv -vf "${ED}"usr/bin/splay{,_mp3blaster} || die
+}
diff --git a/media-sound/mp3blaster/mp3blaster-3.2.5.ebuild b/media-sound/mp3blaster/mp3blaster-3.2.5.ebuild
new file mode 100644
index 000000000000..f7625e100048
--- /dev/null
+++ b/media-sound/mp3blaster/mp3blaster-3.2.5.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit eutils
+
+DESCRIPTION="Text console based program for playing audio files"
+HOMEPAGE="http://mp3blaster.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ppc ppc64 sparc x86 ~x86-fbsd"
+IUSE="lirc oss sdl sid vorbis"
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7
+	lirc? ( app-misc/lirc )
+	sdl? ( media-libs/libsdl )
+	sid? ( =media-libs/libsidplay-1* )
+	vorbis? ( >=media-libs/libvorbis-1 )"
+DEPEND="${RDEPEND}
+	x11-misc/imake
+	oss? ( virtual/os-headers )"
+
+REQUIRED_USE="|| ( oss sdl )"
+
+DOCS="AUTHORS BUGS ChangeLog CREDITS FAQ NEWS README TODO"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-gcc44.patch
+	# file collision with media-sound/splay
+	sed -i -e 's:splay.1:splay_mp3blaster.1:' Makefile.in || die
+	mv -vf splay{,_mp3blaster}.1 || die
+}
+
+src_configure() {
+	# libpth and newthreads support are both broken
+	econf \
+		--disable-newthreads \
+		--without-pth \
+		--without-nas \
+		$(use_with lirc) \
+		$(use_with vorbis oggvorbis) \
+		$(use_with sid sidplay) \
+		--without-esd \
+		$(use_with sdl) \
+		$(use_with oss)
+}
+
+src_install() {
+	default
+	# file collision with media-sound/splay
+	mv -vf "${ED}"usr/bin/splay{,_mp3blaster} || die
+}