proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

6 files changed, 220 insertions, 0 deletions

diff --git a/net-im/centerim/Manifest b/net-im/centerim/Manifest
new file mode 100644
index 000000000000..a9ab1d42b91c
--- /dev/null
+++ b/net-im/centerim/Manifest
@@ -0,0 +1,3 @@
+DIST centerim-4.22.10.tar.gz 2287832 SHA256 93ce15eb9c834a4939b5aa0846d5c6023ec2953214daf8dc26c85ceaa4413f6e SHA512 1cabb6d455e2c1d2bb70a4330f78a34b54dabbc9a7d77d93ef7a08cfae73958670e86dee06b1fb7cb393c248d9682a491edb19a81cb43e7b0f44513c24759116 WHIRLPOOL 58a615cb171221b916c1cea61388659fe2dd6b09ebfe4bf8442109289e1ed89c47ee5e9cd093a05a276d08f33e6f4e7cb951153a6cdf6eed439a9c20b8d3ff78
+DIST centerim5-5.0.0beta1.tar.gz 640277 SHA256 d8dd989a0e6a29247dd56b11ad444ebcc4f0b07fa95879f0f86f8a7ab69ead7c SHA512 581acff42ba768ee564b5c1e817e1287e9889c3e837474de9a3342b10b6035ffa3430de62299c334376c5a61136dbf3eb776a35d7f5f7bb4dd2571296b3441ac WHIRLPOOL 178ff8814aaf204c557e6274a65eeea98e72956969a408eb02e02cebcc89f9c36462298e7fc5235f910299e1be51358eaac6c3bec24b23e6ba144727ba4e305f
+DIST centerim5-5.0.0beta2.tar.gz 689578 SHA256 5f4ad8d4ad8ec785f928ad06b42a184a9785a2cce31da5d908963643b0c522c7 SHA512 5057186ddb354c76740ea38d10678a18a716085566630e3338911f2d3931d60925406fe78c25de8ffe9bdbb7a307e7a230d0da6863c2d81ebb63ba2f6b962d0c WHIRLPOOL 089b5cf1e773712379154df9f74a006763d93472103f6a1f18f767701fa8248e76e0b309d7731dfb3d8e072905ddfe05212bfb69cd4a10215ced3553281c59f9
diff --git a/net-im/centerim/centerim-4.22.10.ebuild b/net-im/centerim/centerim-4.22.10.ebuild
new file mode 100644
index 000000000000..556665ccd6ae
--- /dev/null
+++ b/net-im/centerim/centerim-4.22.10.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="2"
+
+inherit eutils
+
+PROTOCOL_IUSE="+aim gadu +icq +irc +xmpp lj +msn rss +yahoo"
+IUSE="${PROTOCOL_IUSE} bidi nls ssl crypt jpeg otr"
+
+DESCRIPTION="CenterIM is a ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
+if [[ ${PV} = *_p* ]] # is this a snaphot?
+then
+	SRC_URI="http://www.centerim.org/download/snapshots/${PN}-${PV/*_p/}.tar.gz"
+elif [[ ${PV} = *.*.*.* ]] # is this a mobshot?
+then
+	SRC_URI="http://www.centerim.org/download/mobshots/${P}.tar.gz"
+else
+	SRC_URI="http://www.centerim.org/download/releases/${P}.tar.gz"
+fi
+HOMEPAGE="http://www.centerim.org/"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="amd64 x86 ~x86-fbsd"
+
+DEPEND=">=sys-libs/ncurses-5.2
+	bidi? ( dev-libs/fribidi )
+	ssl? ( >=dev-libs/openssl-0.9.6g )
+	jpeg? ( virtual/jpeg )
+	xmpp? (
+		otr? ( <net-libs/libotr-4 )
+		crypt? ( >=app-crypt/gpgme-1.0.2 )
+	)
+	msn? ( >=net-misc/curl-7.25.0-r1[ssl] )
+	yahoo? ( >=net-misc/curl-7.25.0-r1[ssl] )"
+
+RDEPEND="${DEPEND}
+	nls? ( sys-devel/gettext )"
+
+S="${WORKDIR}"/${P/_p*}
+
+check_protocol_iuse() {
+	local flag
+
+	for flag in ${PROTOCOL_IUSE}
+	do
+		use ${flag#+} && return 0
+	done
+
+	return 1
+}
+
+pkg_setup() {
+	if ! check_protocol_iuse
+	then
+		eerror
+		eerror "Please activate at least one of the following protocol USE flags:"
+		eerror "${PROTOCOL_IUSE//+}"
+		eerror
+		die "Please activate at least one protocol USE flag!"
+	fi
+
+	if use otr && ! use xmpp
+	then
+		ewarn
+		ewarn "Support for OTR is only supported with Jabber!"
+		ewarn
+	fi
+
+	if use gadu && ! use jpeg
+	then
+		ewarn
+		ewarn "You need jpeg support to be able to register Gadu-Gadu accounts!"
+		ewarn
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-gcc46.patch
+
+	# Don't execute git commands, bug #228151
+	cat >"${S}"/misc/git-version-gen <<-EOF
+		#!/bin/sh
+		echo -n "${PVR}"
+	EOF
+}
+
+src_configure() {
+	econf \
+		$(use_with ssl) \
+		$(use_enable aim) \
+		$(use_with bidi fribidi) \
+		$(use_with jpeg libjpeg) \
+		$(use_with otr libotr) \
+		$(use_enable gadu gg) \
+		$(use_enable icq) \
+		$(use_enable irc) \
+		$(use_enable xmpp jabber) \
+		$(use_enable lj) \
+		$(use_enable msn) \
+		$(use_enable nls locales-fix) \
+		$(use_enable nls) \
+		$(use_enable rss) \
+		$(use_enable yahoo) \
+		|| die "econf failed"
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS ChangeLog FAQ README THANKS TODO
+}
diff --git a/net-im/centerim/centerim-5.0.0_beta1.ebuild b/net-im/centerim/centerim-5.0.0_beta1.ebuild
new file mode 100644
index 000000000000..c327469fb026
--- /dev/null
+++ b/net-im/centerim/centerim-5.0.0_beta1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+MY_P="${PN}5-${PV/_}"
+
+DESCRIPTION="CenterIM is a ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
+SRC_URI="http://www.centerim.org/download/cim5/${MY_P}.tar.gz"
+HOMEPAGE="http://www.centerim.org/"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="debug nls"
+
+DEPEND=">=sys-libs/ncurses-5.2
+	>=net-im/pidgin-2.7.0
+	>=dev-libs/glib-2.16.0
+	>=dev-libs/libsigc++-2.2.0"
+RDEPEND="${DEPEND}
+	nls? ( sys-devel/gettext )"
+DEPEND="${DEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}"/${MY_P}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	rm -f "${D}"/usr/lib*/libcppconsui.{a,la}
+
+	dodoc AUTHORS HACKING NEWS README TODO
+}
diff --git a/net-im/centerim/centerim-5.0.0_beta2.ebuild b/net-im/centerim/centerim-5.0.0_beta2.ebuild
new file mode 100644
index 000000000000..eafd6aed3ff6
--- /dev/null
+++ b/net-im/centerim/centerim-5.0.0_beta2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+MY_P="${PN}5-${PV/_}"
+
+DESCRIPTION="CenterIM is a ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
+SRC_URI="http://www.centerim.org/download/cim5/${MY_P}.tar.gz"
+HOMEPAGE="http://www.centerim.org/"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="debug nls"
+
+DEPEND=">=sys-libs/ncurses-5.2
+	>=net-im/pidgin-2.7.0
+	>=dev-libs/glib-2.16.0
+	>=dev-libs/libsigc++-2.2.0"
+RDEPEND="${DEPEND}
+	nls? ( sys-devel/gettext )"
+DEPEND="${DEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}"/${MY_P}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	rm -f "${D}"/usr/lib*/libcppconsui.{a,la}
+
+	dodoc AUTHORS HACKING NEWS README TODO
+}
diff --git a/net-im/centerim/files/centerim-4.22.10-gcc46.patch b/net-im/centerim/files/centerim-4.22.10-gcc46.patch
new file mode 100644
index 000000000000..a03e9eabd13f
--- /dev/null
+++ b/net-im/centerim/files/centerim-4.22.10-gcc46.patch
@@ -0,0 +1,12 @@
+https://bugs.gentoo.org/show_bug.cgi?id=363017
+
+--- a/libicq2000/libicq2000/sigslot.h
++++ b/libicq2000/libicq2000/sigslot.h
+@@ -82,6 +82,7 @@
+ #ifndef SIGSLOT_H__
+ #define SIGSLOT_H__
+ 
++#include <cstddef>
+ #include <set>
+ #include <list>
+ 
diff --git a/net-im/centerim/metadata.xml b/net-im/centerim/metadata.xml
new file mode 100644
index 000000000000..2efcddf1f657
--- /dev/null
+++ b/net-im/centerim/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer>
+	<email>swegener@gentoo.org</email>
+	<description>Primary Maintainer</description>
+</maintainer>
+<use>
+	<flag name='gadu'>Enable support for the Gadu-Gadu protocol</flag>
+	<flag name='irc'>Enable support for the IRC protocol</flag>
+	<flag name='lj'>Enable support for the LiveJournal weblog system</flag>
+	<flag name='otr'>Enable encrypted conversations</flag>
+</use>
+</pkgmetadata>