summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMoritz Schlarb <moschlar@metalabs.de>2018-01-08 15:31:23 +0100
committerCraig Andrews <candrews@gentoo.org>2018-01-10 18:40:44 -0500
commit017f28bdbf1cc8767c359a32f0e030aafd0e7257 (patch)
tree835f6ae8dad17ba11e827e79888c8af1d06a5215 /net-im/corebird/corebird-1.7.3.ebuild
parentdev-python/httpstat: New package (diff)
downloadgentoo-017f28bdbf1cc8767c359a32f0e030aafd0e7257.tar.gz
gentoo-017f28bdbf1cc8767c359a32f0e030aafd0e7257.tar.bz2
gentoo-017f28bdbf1cc8767c359a32f0e030aafd0e7257.zip
net-im/corebird: Version bump to 1.7.3
Diffstat (limited to 'net-im/corebird/corebird-1.7.3.ebuild')
-rw-r--r--net-im/corebird/corebird-1.7.3.ebuild55
1 files changed, 55 insertions, 0 deletions
diff --git a/net-im/corebird/corebird-1.7.3.ebuild b/net-im/corebird/corebird-1.7.3.ebuild
new file mode 100644
index 000000000000..8eaeec3531d2
--- /dev/null
+++ b/net-im/corebird/corebird-1.7.3.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+VALA_MIN_API_VERSION=0.34
+
+inherit autotools gnome2 vala virtualx
+
+DESCRIPTION="Native GTK+3 Twitter client"
+HOMEPAGE="https://corebird.baedert.org/"
+SRC_URI="https://github.com/baedert/corebird/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug gstreamer spellcheck"
+
+RDEPEND="dev-db/sqlite:3
+ >=dev-libs/glib-2.44:2
+ dev-libs/json-glib
+ gstreamer? ( >=media-libs/gst-plugins-bad-1.6:1.0[X,gtk]
+ media-libs/gst-plugins-base:1.0[X]
+ media-libs/gst-plugins-good:1.0
+ media-plugins/gst-plugins-hls:1.0
+ media-plugins/gst-plugins-libav:1.0
+ media-plugins/gst-plugins-meta:1.0[X]
+ media-plugins/gst-plugins-soup:1.0 )
+ spellcheck? ( >=app-text/gspell-1.0[vala] )
+ >=net-libs/libsoup-2.42.3.1
+ >=x11-libs/gtk+-3.20:3"
+DEPEND="${RDEPEND}
+ $(vala_depend)
+ >=dev-util/intltool-0.40
+ sys-apps/sed
+ virtual/pkgconfig"
+
+src_prepare() {
+ eautoreconf
+ gnome2_src_prepare
+ vala_src_prepare
+}
+
+src_configure() {
+ local myeconfargs=(
+ $(use_enable gstreamer video)
+ --disable-gst-check
+ $(use_enable spellcheck)
+ )
+ gnome2_src_configure "${myeconfargs[@]}"
+}
+
+src_test() {
+ virtx emake check
+}