net-im/openmittsu: Install icon and desktop file.

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 55 insertions, 0 deletions

diff --git a/net-im/openmittsu/openmittsu-0.9.2_p75-r1.ebuild b/net-im/openmittsu/openmittsu-0.9.2_p75-r1.ebuild
new file mode 100644
index 000000000000..da92298ceef7
--- /dev/null
+++ b/net-im/openmittsu/openmittsu-0.9.2_p75-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils eutils
+
+MY_PN="openMittsu"
+DESCRIPTION="An open source chat client for Threema-style end-to-end encrypted chat networks"
+HOMEPAGE="https://github.com/blizzard4591/openMittsu"
+# git-archive-all.sh snapshot of https://github.com/blizzard4591/${MY_PN}.git
+SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="GPL-2+ BitstreamVera OFL-1.1 Apache-2.0 CC0-1.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND=">=dev-libs/libsodium-1.0.11:=
+	>=dev-qt/qtcore-5.7.1:5=
+	>=dev-qt/qtgui-5.7.1:5=
+	>=dev-qt/qtmultimedia-5.7.1:5=
+	>=dev-qt/qtnetwork-5.7.1:5=
+	>=dev-qt/qtwidgets-5.7.1:5=
+	>=media-gfx/qrencode-3.4.4-r1"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+DOCS=(
+	README.md
+	Example-client-configuration-file.ini
+	Example-contacts-file.txt
+)
+
+src_prepare() {
+	# set version manually, since autodetection works only with git
+	sed -i "/git_describe_checkout/\
+		s/.*/set(OPENMITTSU_GIT_VERSION_STRING \"${PV/_p/-}-00000000\")/" \
+		CMakeLists.txt || die
+
+	eapply "${FILESDIR}"/${P}-libsodium-so.patch
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=("-DOPENMITTSU_DISABLE_VERSION_UPDATE_CHECK=ON")
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	newicon resources/icon.png ${MY_PN}.png
+	make_desktop_entry ${MY_PN} ${MY_PN} ${MY_PN}
+}